Spis treści
Indeks 🔎︎

# Funkcje tekstowe

Niniejsza sekcja zawiera opisy funkcji tekstowych.

Aby wykonać tę operację...

Wstaw - Funkcja - Kategoria Tekst

## Using double quotation marks in formulas

To include a text string in a formula, place the text string between two double quotation marks (") and Calc takes the characters in the string without attempting to interpret them. For example, the formula ="Hello world!" displays the text string Hello world! in the cell, with no surrounding double quotation marks.

The more complex formula =CONCATENATE("Life is really simple, "; "but we insist on making it complicated "; "(Confucius).") concatenates three individual strings in double quotation marks, outputting Life is really simple, but we insist on making it complicated (Confucius).

To place a literal double quotation mark within a string inside a formula, two methods can be used:

1. You can "escape" the double quotation mark with an additional double quotation mark, and Calc treats the escaped double quotation mark as a literal value. For example, the formula ="My name is ""John Doe""." outputs the string My name is "John Doe". Another simple example is the formula =UNICODE("""") which returns 34, the decimal value of the Unicode quotation mark character (U+0022) — here the first and fourth double quotation marks indicate the beginning and end of the string, while the second double quotation mark escapes the third.

2. You can use the CHAR function or the UNICHAR function to insert a double quotation mark. For example, the formula =UNICHAR(34) & "The Catcher in the Rye" & UNICHAR(34) & " is a famous book by J. D. Salinger." displays the string "The Catcher in the Rye" is a famous book by J. D. Salinger.

Beware that Calc's AutoCorrect function may modify double quotation marks. AutoCorrect should not change the double quotation marks within formula cells but may change those used in non-formula cells containing text. For example, if you copy a string that is surrounded by some other form of typographical double quotation marks, such as the left double quotation mark (U+201C) and the right double quotation mark (U+201D), and then paste into a formula cell, an error may result. Open the Double Quotes area of the Tools - AutoCorrect Options - Localized Options dialog to set the characters used to automatically correct the start and end typographical double quotation marks. Uncheck the Replace toggle button to disable the feature.

## ARABIC

Returns the numeric value corresponding to a Roman number expressed as text.

## ASC

Converts double-byte (full-width) characters to single-byte (half-width) ASCII and katakana characters.

## JIS

Converts single-byte (half-width) ASCII or katakana characters to double-byte (full-width) characters.

## REGEX

Matches and extracts or optionally replaces text using regular expressions.

## ROMAN

Converts a number into a Roman numeral. The value range must be between 0 and 3999. A simplification mode can be specified in the range from 0 to 4.

## VALUE

Converts the string representation of a number to numeric form. If the supplied string is a valid date, time, or date-time, the corresponding date-time serial number is returned.

### WEBSERVICE

Pobiera zawartość internetową z URI.

### FILTERXML

Zastosuj wyrażenie XPath do dokumentu XML.

### ENCODEURL

Zwraca ciąg znaków zakodowany w standardzie URL.

## BAT.TEKST

Zamienia liczbę na tekst tajski łącznie z nazwami waluty tajlandzkiej.

#### Składnia

BAT.TEKST(Liczba)

Liczba to dowolna liczba. Wartość "Baht" jest dołączana do części całkowitej liczby, a "Satang" do części ułamkowej.

#### Przykład

=BAT.TEKST(12,65) zwraca ciąg tekstowy zapisany w znakach alfabetu tajskiego, który oznacza "12 batów i 65 satangów".

#### Technical information

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.BAHTTEXT

## DŁ

Zwraca długość ciągu wraz ze spacjami.

#### Składnia

DŁ("tekst")

Tekst to wartość tekstowa, dla której należy określić znak.

#### Przykład

=DŁ("Dzień dobry") zwraca wartość 11.

=DŁ(12345,67) zwraca wartość 8.

## FRAGMENT.TEKSTU

Zwraca fragment podanego ciągu znaków. Parametry określają pozycję początkową i liczbę znaków.

#### Składnia

FRAGMENT.TEKSTU("tekst"; liczba_początkowa; liczba)

Tekst jest ciągiem zawierającym znaki, które należy pobrać.

Start to pozycja pierwszego znaku w tekście do pobrania.

Liczba określa liczbę znaków części tekstu.

#### Przykład

=FRAGMENT.TEKSTU("office";2;2) zwraca wartość ff.

## KOD

Zwraca kod numeryczny pierwszego znaku łańcucha znakowego.

#### Składnia

KOD("Tekst")

Tekst to wartość tekstowa, dla której należy znaleźć kod pierwszego znaku.

Kody zawierające więcej niż 127 znaków mogą być zależne od sposobu mapowania znaków w systemie (np. iso-8859-1, iso-8859-2, Windows-1252 czy Windows-1250), w związku z czym nie zawsze można ich używać na różnych platformach.

#### Przykład

=KOD("Hieronymus") zwraca wartość 72, =KOD("hieroglyphic") zwraca wartość 104.

Kod numeryczny nie musi odpowiadać tabeli ASCII, lecz tabeli znaków aktualnie używanej.

## KWOTA

Converts a number to a string representing the amount in the currency format, rounded to a specified decimal places, using the decimal separator that corresponds to the current locale setting. In the Value field enter the number to be converted. Optionally, you may enter the number of decimal places in the Decimals field. If no value is specified, all numbers in currency format will be displayed with two decimal places.

Format waluty definiuje się w ustawieniach systemowych.

#### Składnia

DOLLAR(Value [; Decimals])

Wartość jest liczbą, odwołaniem do komórki zawierającej liczbę lub formułą zwracającą liczbę.

Dziesiętne to parametr opcjonalny, który określa liczbę miejsc dziesiętnych.

#### Przykład

=DOLLAR(255) returns $255.00 for the English (USA) locale and USD (dollar) currency; ￥255.00 for the Japanese locale and JPY (yen) currency; or 255,00 € for the German (Germany) locale and EUR (euro) currency.

=DOLLAR(367.456;2) returns $367.46.

## LEFTB

Zwraca początkowe znaki tekstu DBCS.

This function is available since LibreOffice 4.2.

#### Składnia

LEFTB("Text" [; Number_bytes])

Tekst to wartość tekstowa, dla której należy określić początkowe słowa cząstkowe.

Liczba_bajtów (opcjonalny) oznacza liczbę znaków, którą LEWYB ma wyodrębnić na podstawie bajtów. Jeśli ten parametr nie został zdefiniowany, zwracany jest jeden znak.

#### Przykład

=LEFTB("中国";1) returns " " (1 byte is only half a DBCS character and a space character is returned instead).

=LEFTB("中国";2) returns "中" (2 bytes constitute one complete DBCS character).

=LEFTB("中国";3) returns "中 " (3 bytes constitute one DBCS character and a half; the last character returned is therefore a space character).

=LEFTB("中国";4) returns "中国" (4 bytes constitute two complete DBCS characters).

=LEFTB("office";3) returns "off" (3 non-DBCS characters each consisting of 1 byte).

## LENB

Dla dwubajtowych zestawów znaków języków (DBCS), zwracana jest liczba bajtów użytych do reprezentacji znaków w ciągu tekstowym.

This function is available since LibreOffice 4.2.

#### Składnia

DŁ.B("Tekst")

Tekst to wartość tekstowa, dla której należy określić znak.

#### Przykład

DŁ.B("中") zwraca 2 (1 znak DBCS składający się z 2 bajtów).

DŁ.B("中国") zwraca 4 (2 znaki DBCS każdy składający się z 2 bajtów).

DŁ.B("office") zwraca 6 (6 znaków nie DBCS każdy składający się z 1 bajtu)

=DŁ.B("Dzień dobry") zwraca wartość 11.

=DŁ.B(12345,67) zwraca wartość 8.

## LEWY

Zwraca początkowe znaki w ciągu tekstowym.

#### Składnia

LEFT("Text" [; Number])

Tekst to wartość tekstowa, dla której należy określić początkowe słowa cząstkowe.

Liczba (parametr opcjonalny) oznacza liczbę znaków w początkowej części tekstu. Jeśli ten parametr nie został zdefiniowany, zwracany jest jeden znak.

#### Przykład

=LEWY("wyjście";3) zwraca wartość “wyj”.

## LITERY.MAŁE

Przekształca wszystkie wielkie litery ciągu tekstowego na małe.

#### Składnia

LITERY.MAŁE("tekst")

Tekst oznacza ciąg, który należy przekształcić.

#### Przykład

=LITERY.MAŁE("Słońce") zwraca wartość słońce.

## LITERY.WIELKIE

Zamienia litery ciągu określonego w polu Tekst na wielkie.

#### Składnia

LITERY.WIELKIE("tekst")

Tekst oznacza ciąg zawierający małe litery, które mają zostać zamienione na wielkie.

#### Przykład

=LITERY.WIELKIE("Dzień dobry") zwraca wartość DZIEŃ DOBRY.

## M.DZIESIĘTNE

Converts text that represents a number in a numeral system with the given base radix to a positive integer. The radix must be in the range 2 to 36. Spaces and tabs are ignored. The Text field is not case-sensitive.

If the radix is 16, a leading x or X or 0x or 0X, and an appended h or H, are disregarded. If the radix is 2, an appended b or B is disregarded. Other characters that do not belong to the numeral system generate an error.

#### Składnia

M.DZIESIĘTNE("tekst"; podstawa)

Text is the text to be converted.

Radix indicates the base of the numeral system. It may be any positive integer between 2 and 36.

#### Przykład

=M.DZIESIĘTNE("17";10) zwraca wartość 17.

=M.DZIESIĘTNE("FACE";16) zwraca wartość 64206.

=M.DZIESIĘTNE("0101";2) zwraca wartość 5.

#### See also

BASE

## MIDB

Zwraca fragment podanego ciągu znaków. Parametry określają pozycję początkową i liczbę znaków.

This function is available since LibreOffice 4.2.

#### Składnia

FRAGMENT.TEKSTU.B("Tekst"; Liczba_początkowa; Liczba_bajtów)

Tekst jest ciągiem zawierającym znaki, które należy pobrać.

Liczba_początkowa to pozycja pierwszego znaku w tekście do pobrania.

Liczba_bajtów określa liczbę znaków, którą FRAGMENT.TEKSTU.B zwróci z tekstu, w bajtach.

#### Przykład

=MIDB("中国";1;0) returns "" (0 bytes is always an empty string).

=MIDB("中国";1;1) returns " " (1 byte is only half a DBCS character and therefore the result is a space character).

=MIDB("中国";1;2) returns "中" (2 bytes constitute one complete DBCS character).

=MIDB("中国";1;3) returns "中 " (3 bytes constitute one and a half DBCS character; the last byte results in a space character).

=MIDB("中国";1;4) returns "中国" (4 bytes constitute two complete DBCS characters).

=MIDB("中国";2;1) returns " " (byte position 2 is not at the beginning of a character in a DBCS string; 1 space character is returned).

=MIDB("中国";2;2) returns " " (byte position 2 points to the last half of the first character in the DBCS string; the 2 bytes asked for therefore constitutes the last half of the first character and the first half of the second character in the string; 2 space characters are therefore returned).

=MIDB("中国";2;3) returns " 国" (byte position 2 is not at the beginning of a character in a DBCS string; a space character is returned for byte position 2).

=MIDB("中国";3;1) returns " " (byte position 3 is at the beginning of a character in a DBCS string, but 1 byte is only half a DBCS character and a space character is therefore returned instead).

=MIDB("中国";3;2) returns "国" (byte position 3 is at the beginning of a character in a DBCS string, and 2 bytes constitute one DBCS character).

=MIDB("office";2;3) returns "ffi" (byte position 2 is at the beginning of a character in a non-DBCS string, and 3 bytes of a non-DBCS string constitute 3 characters).

## OCZYŚĆ

Funkcja usuwa z łańcucha wszystkie znaki niedrukowalne.

#### Składnia

OCZYŚĆ("tekst")

Tekst oznacza wartość tekstową, z której zostaną usunięte wszystkie znaki niedrukowalne.

#### Przykład

=LEN(CLEAN(CHAR(7) & "LibreOffice Calc" & CHAR(8))) returns 16, showing that the CLEAN function removes the non-printable Unicode U+0007 ("BEL") and U+0008 ("BS") characters at the beginning and end of the string argument. CLEAN does not remove spaces.

## PODSTAW

Podstawia nowy tekst w miejsce starego we wskazanym ciągu znaków.

#### Składnia

SUBSTITUTE("Text"; "SearchText"; "NewText" [; Occurrence])

Tekst jest tekstem, w którym segmenty zostaną zastąpione.

Szukany_tekst to segment tekstu, który ma być zastąpiony (określoną liczbę razy).

Nowy_tekst jest tekstem, który ma zastąpić segment.

Wystąpienie (parametr opcjonalny) wskazuje na numer wystąpienia wyszukiwanego tekstu, które ma być zamienione. Przy braku tego parametru zamienione zostaną wszystkie wystąpienia.

#### Przykład

=PODSTAW("123123123";"3";"abc") zwraca 12abc12abc12abc.

=PODSTAW("123123123";"3";"abc";2) zwraca wartość 12abc12abc12abc.

## PODSTAWA

Converts a positive integer to a specified base into a text from the numbering system. The digits 0-9 and the letters A-Z are used.

#### Składnia

BASE(Number; Radix [; MinimumLength])

Liczba to dodatnia liczba całkowita do konwersji.

Radix indicates the base of the numeral system. It may be any positive integer between 2 and 36.

Minimalna_długość (parametr opcjonalny) oznacza minimalną długość utworzonej sekwencji znaków. Jeśli długość tekstu jest mniejsza niż określona długość minimalna, zostanie on uzupełniony zerami z lewej strony.

#### Przykład

=PODSTAWA(17;10;4) zwraca wartość 0017 w systemie dziesiętnym.

=PODSTAWA(17;2) zwraca wartość 10001 w systemie dwójkowym.

=PODSTAWA(255;16;4) zwraca wartość 00FF w systemie szesnastkowym.

#### See also

DECIMAL

## PORÓWNAJ

Porównuje dwa ciągi tekstowe i zwraca wartość PRAWDA, jeśli są identyczne. Funkcja rozróżnia wielkość liter.

#### Składnia

PORÓWNAJ("tekst_1";"tekst_2")

Tekst_1 oznacza pierwszy tekst do porównania.

Tekst_2 to druga porównywana wartość tekstowa.

#### Przykład

=PORÓWNAJ(" microsystems";" Microsystems") zwraca wartość FAŁSZ.

## POWT

Powtarza łańcuch znakowy określoną ilość razy.

#### Składnia

POWT("tekst"; ilość)

Tekst to wartość tekstowa, która ma być powtarzana.

Liczba oznacza liczbę powtórzeń.

#### Przykład

=POWT("Dzień dobry";2) zwraca wartość Dzień dobryDzień dobry.

Refer to the REPT wiki page for more details about this function.

## PRAWY

Zwraca ostatnie znaki w ciągu tekstowym.

#### Składnia

RIGHT("Text" [; Number])

Tekst jest tekstem, dla którego należy określić część po prawej stronie.

Number (optional) is the number of characters from the right part of the text. If this parameter is not defined, one character is returned.

#### Przykład

=PRAWY("Słońce";2) zwraca wartość ce.

## RIGHTB

Zwraca ostatni znak lub znaki tekstu z dwubajtowych zestawów znaków (DBCS).

This function is available since LibreOffice 4.2.

#### Składnia

RIGHTB("Text" [; Number_bytes])

Tekst jest tekstem, dla którego należy określić część po prawej stronie.

Number_bytes (optional) specifies the number of characters you want RIGHTB to extract, based on bytes. If this parameter is not defined, one byte is returned.

#### Przykład

PRAWY.B("中国";1) zwraca " " (1 bajt jest tylko połową znaku DBCS i zwracany jest znak spacji).

PRAWY.B("中国";2) zwraca "国" (2 bajty stanowią jeden kompletny znak DBCS).

PRAWY.B("中国";3) zwraca " 国" (3 bajty stanowią połowę jednego znaku DBCS i jeden cały znak DBCS, spacja zwracana jest dla pierwszej połowy).

PRAWY.B("中国";4) zwraca "中国" (4 bajty stanowią dwa kompletne znaki DBCS).

PRAWY.B("office";3) zwraca "ice" (3 znaki nie DBCS każdy składający się z 1 bajtu).

## SZUKAJ.TEKST

Returns the position of a text segment within a character string. You can set the start of the search as an option. The search text can be a number or any sequence of characters. The search is not case-sensitive. If the text is not found, returns error 519 (#VALUE).

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

#### Składnia

SEARCH("FindText"; "Text" [; Position])

Znajdź_tekst oznacza szukany tekst.

Tekst jest tekstem, w którym będzie prowadzone wyszukiwanie.

Pozycja (parametr opcjonalny) oznacza pozycję w tekście, od której rozpocznie się wyszukiwanie.

#### Przykład

=SZUKAJ.TEKST(54;998877665544) zwraca wartość 10.

## T

Funkcja zwraca tekst docelowy lub tekst pusty, jeżeli ciąg docelowy nie jest sformatowany jako tekst.

#### Składnia

T(wartość)

Wartość jest wartością, którą należy przekształcić. Jako parametru można także użyć odwołania. Jeśli komórka odwołania zawiera liczbę lub formułę zwracającą wynik numeryczny, wynikiem tej funkcji będzie ciąg pusty.

#### Przykład

=T(12345) zwraca pusty ciąg.

=T("12345") zwraca wartość tekstową 12345.

## TEKST

Converts a value into text according to a given format.

#### Składnia

TEXT(Value; Format)

Value is the value (numerical or textual) to be converted.

Format to wartość tekstowa, która definiuje format. Przecinek dziesiętny i separator tysięcy muszą być zgodne z formatem komórki dla danego języka.

#### Przykład

=TEKST(12,34567;"###.##") zwraca wartość tekstową 12,35

=TEKST(12,34567;"000,00") zwraca wartość tekstową 012,35

=TEXT("xyz";"=== @ ===") returns the text === xyz ===

See also Number format codes: custom format codes defined by the user.

## UNICHAR

Konwertuje kod liczbowy na znak lub literę Unicode.

#### Składnia

UNICHAR(numer)

#### Przykład

=UNICHAR(169) zwraca znak praw autorskich ©.

Zobacz także funkcję UNICODE ()

## UNICODE

Zwraca kod liczbowy pierwszego znaku Unicode w ciągu tekstowym.

#### Składnia

UNICODE("Text")

#### Przykład

=UNICODE("©") zwraca numer kodu Unicode (169) dla znaku praw autorskich.

Zobacz także funkcję UNICHAR().

## USUŃ.ZBĘDNE.ODSTĘPY

Usuwa spacje na początku ciągu lub wyrównuje zawartość komórki do lewej.

#### Składnia

USUŃ.ZBĘDNE.ODSTĘPY("tekst")

Tekst oznacza tekst, z którego mają być usunięte spacje.

#### Przykład

=USUŃ.ZBĘDNE.ODSTĘPY(" wita świecie ") zwraca "witaj świecie" z pojedynczą spacją między wyrazami i bez spacji początkowej oraz końcowej.

## ZAOKR.DO.TEKST

Returns a number as text with a specified number of decimal places and optional thousands separators.

#### Składnia

FIXED(Number; [Decimals = 2 [; NoThousandsSeparators = FALSE]])

Number is rounded to Decimals places (after the decimal separator) and the result formatted as text, using locale-specific settings.

Decimals (optional) refers to the number of decimal places to be displayed. If Decimals is negative, Number is rounded to ABS(Decimals) places to the left from the decimal point. If Decimals is a fraction, it is truncated actually ignoring what is the closest integer.

NoThousandsSeparators (optional) determines whether the thousands separator is used. If it is TRUE or non-zero, then group separators are omitted from the resulting string. If the parameter is equal to 0 or if it is missing altogether, the thousands separators of your current locale setting are displayed.

#### Przykład

=ZAOKR.DO.TEKST(1234567,89;3) zwraca 1 234 567,890 w postaci ciągu tekstowego.

=FIXED(123456.789;;TRUE) returns 123456.79 as a text string.

=FIXED(12345.6789;-2) returns 12,300 as a text string.

=FIXED(12134567.89;-3;1) returns 12135000 as a text string.

=FIXED(12345.789;3/4) returns 12,346 as a text string.

=FIXED(12345.789;8/5) returns 12,345.8 as a text string.

## ZASTĄP

Zamienia część łańcucha tekstowego innym łańcuchem tekstowym. Ta funkcja może być użyta zarówno do znaków jak i liczb (które są automatycznie konwertowane na tekst). Wynik działania tej funkcji zawsze jest tekstem. Jeśli masz zamiar dokonywać obliczeń z użyciem liczb, które zostały zamienione na tekst musisz przeprowadzić ponownie konwersję na liczbę przy użyciu funkcji WARTOŚĆ.

Jeżeli nie chcesz, by tekst zawierający liczby był interpretowany jako liczba i automatycznie konwertowany na tekst, musisz zawrzeć go w cudzysłów.

#### Składnia

ZASTĄP("tekst"; pozycja; długość; "nowy tekst")

Tekst jest to łańcuch znakowy, którego część chcesz zamienić.

Pozycja oznacza pozycję w tekście, od której rozpocznie się zastępowanie.

Długość to liczba znaków w wartości Tekst, którą należy zastąpić.

Nowy_tekst oznacza tekst, który ma zastąpić wartość Tekst.

#### Przykład

=ZASTĄP("1234567";1;1;"444") zwraca wartość "444234567". Jeden znak w pozycji 1 jest zastępowany przez całe wyrażenie Nowy_tekst.

## ZŁĄCZ.TEKSTY

Łączy wiele łańcuchów znakowych w jeden.

#### Składnia

CONCATENATE(String 1 [; String 2 [; … [; String 255]]])

String 1[; String 2][; … ;[String 255]] are strings or references to cells containing strings.

#### Przykład

=ZŁĄCZ.TEKSTY("Dzień";"dobry";"panie";"Kowalski") zwraca: Dzień dobry panie Kowalski.

## ZNAJDŹ

Poszukuje ciągu tekstowego w innym ciągu. Funkcja pozwala także zdefiniować początek wyszukiwania. Wyszukiwany ciąg może być liczbą lub dowolnym ciągiem znakowym. Funkcja rozróżnia wielkość liter.

#### Składnia

FIND("FindText"; "Text" [; Position])

Znajdź_tekst oznacza szukany tekst.

Tekst jest tekstem, w którym będzie prowadzone wyszukiwanie.

Pozycja (parametr opcjonalny) oznacza pozycję w tekście, od której rozpocznie się wyszukiwanie.

#### Przykład

=ZNAJDŹ(76;998877665544) zwraca wartość 6.

## ZNAK

Zamienia liczbę na znak zgodnie z tabelą kodową. Liczba może być dwucyfrową lub trzycyfrową liczbą całkowitą.

Kody zawierające więcej niż 127 znaków mogą być zależne od sposobu mapowania znaków w systemie (np. iso-8859-1, iso-8859-2, Windows-1252 czy Windows-1250), w związku z czym nie zawsze można ich używać na różnych platformach.

#### Składnia

ZNAK(liczba)

Liczba to wartość liczbowa z zakresu od 1 do 255, która odpowiada wartości kodu danego znaku.

#### Przykład

=ZNAK(100) zwraca znak d.

="abc" & ZNAK(10) & "def" wstawia do ciągu tekstowego znak nowej linii.

## Z.WIELKIEJ.LITERY

Zamienia pierwszą literę na wielką w każdym wyrazie w tekście.

#### Składnia

Z.WIELKIEJ.LITERY("tekst")

Tekst oznacza ciąg, który należy przekształcić.

#### Przykład

=PROPER("the document foundation") returns The Document Foundation.

Tematy pokrewne

Funkcje według kategorii