Relace v Pythonu: třída Session

Obsah
Rejstřík 🔎︎

# Získávání informací o relaci

Cesty k souborům modulů v uživatelském profilu LibreOffice a ke sdíleným modulům je možné zjistit pomocí jazyků Python nebo Basic. Z takto získaných informací lze odvodit umístění skriptů pro jazyky BeanShell, Java, JavaScript a Python.

## Příklady:

Pomocí shellu Pythonu:

>>> from <the_module> import Session

>>> print(Session.SharedPythonScripts()) # statická metoda

>>> print(Session().UserName) # vlastnost objektu

>>> input(Session().UserProfile) # vlastnost objektu

### Z nabídky Nástroje – Makra - Spustit makro

            from <the_module> import Session

            def demo_session():
                import screen_io as ui
                ui.MsgBox(Session.Share(),title='Sdílené skripty')  # statická metoda
                ui.Print(Session.SharedPythonScripts())  # statická metoda
                s = Session()  # vytvoření instance
                ui.MsgBox(s.UserName,title='Uživatelské skripty')  # vlastnost objektu
                ui.Print(s.UserPythonScripts)  # vlastnost objektu

            g_exportedScripts = (demo_session,)  # veřejná makra

### Pomocí jazyka LibreOffice Basic

            Sub Session_example()
                Dim s As New Session ' instance of Session class
                Print "Umístění sdílených skriptů:", s.SharedScripts
                MsgBox s.UserName,,"Uživatel"
                Print s.UserScripts, Chr(13), s.UserPythonScripts
            End Sub ' Session_example

### Pomocí COM/OLE a skriptovacího jazyka Visual Basic

            ' Vstupním bodem je vždy správce služeb
            ' Případně se spustí vše potřebné
            Set sm = WScript.CreateObject("com.sun.star.ServiceManager")
            ' Služba PathSubstitution přináší informace pro odvození
            ' umístění <UživatelskýProfil|Sdílené>/Scripts/python
            Set obj = sm.createInstance("com.sun.star.util.PathSubstitution")

            MsgBox CreateObject("WScript.Network").UserName,, "Hello"
            user = obj.getSubstituteVariableValue("$(user)")
            MsgBox user & "/Scripts",, "User scripts location"
            libO = Replace(obj.getSubstituteVariableValue("$(inst)"), "program/..", "Share")
            MsgBox libO & "/Scripts",, "Shared scripts location"

## Třída Pythonu Session:

            import getpass, os, os.path, uno

            class Session():
                @staticmethod
                def substitute(var_name):
                    ctx = uno.getComponentContext()
                    ps = ctx.getServiceManager().createInstanceWithContext(
                        'com.sun.star.util.PathSubstitution', ctx)
                    return ps.getSubstituteVariableValue(var_name)
                @staticmethod
                def Share():
                    inst = uno.fileUrlToSystemPath(Session.substitute("$(prog)"))
                    return os.path.normpath(inst.replace('program', "Share"))
                @staticmethod
                def SharedScripts():
                    return ''.join([Session.Share(), os.sep, "Scripts"])
                @staticmethod
                def SharedPythonScripts():
                    return ''.join([Session.SharedScripts(), os.sep, 'python'])
                @property  # alternativa proměnné '$(username)'
                def UserName(self): return getpass.getuser()
                @property
                def UserProfile(self):
                    return uno.fileUrlToSystemPath(Session.substitute("$(user)"))
                @property
                def UserScripts(self):
                    return ''.join([self.UserProfile, os.sep, 'Scripts'])
                @property
                def UserPythonScripts(self):
                    return ''.join([self.UserScripts, os.sep, "python"])

Na rozdíl od Basicu je název cesty v rámci třídy Pythonu Session normalizován.

## Třída Basicu Session:

            Option Explicit
            Option Compatible
            Option ClassModule

            Private _ps As Object ' Soukromý člen

            Private Sub Class_Initialize()
                GlobalScope.BasicLibraries.LoadLibrary("Tools")
                Set _ps = CreateUnoService("com.sun.star.util.PathSubstitution")
            End Sub ' Konstruktor

            Private Sub Class_Terminate()
                _ps = Nothing
            End Sub ' Destruktor

            Public Property Get SharedScripts() As String
                Dim inst As String, shr As String
                inst = ConvertFromURL(_ps.getSubstituteVariableValue("$(prog)"))
                shr = Tools.Strings.ReplaceString(inst,"Share","program")
                SharedScripts = shr & GetPathSeparator() &"Scripts"
            End Property ' Session.sharedScripts

            Public Property Get SharedPythonScripts() As String
                sharedPythonScripts = sharedScripts() & GetPathSeparator() &"python"
            End Property ' Session.sharedPythonScripts

            Public Property Get UserName() As String ' Název uživatelského účtu
                userName = _ps.getSubstituteVariableValue("$(username)")
            End Property ' Session.userName

            Public Property Get UserProfile() As String ' Cesta systému k uživatelskému profilu
                userProfile = ConvertFromURL(_ps.getSubstituteVariableValue("$(user)"))
            End Property ' Session.userProfile

            Public Property Get UserScripts() As String ' Cesta systému k uživatelským skriptům
                userScripts = userProfile() & GetPathSeparator() &"Scripts"
            End Property ' Session.userScripts

            Public Property Get UserPythonScripts() As String ' Cesta systému k uživatelským skriptům Pythonu
                userPythonScripts = userScripts() & GetPathSeparator() &"python"
            End Property ' Session.userPythonScripts

Související témata

Uspořádání a umístění skriptů Pythonu

Import modulů Pythonu

Vstup a výstup na obrazovku

Příklady programování v Pythonu