funkcja ŚREDNIA.JEŻELI

Spis treści
Indeks 🔎︎

## ŚREDNIA.JEŻELI function

Zwraca średnią arytmetyczną wszystkich komórek w zakresie spełniające dany warunek. Funkcja ŚREDNIA.JEŻELI sumuje wszystkie wyniki które pasują do logicznego test i dzieli tę sumę przez ilość wybranych wartości.

Ta funkcja jest dostępna od wersji 4.0 LibreOffice.

#### Składnia

ŚREDNIA.JEŻELI(Zakres; Kryterium [; Zakres_średniej ])

Zakres – argument wymagany. Tablica, nazwa nazwanego zakresu, etykieta kolumny lub wiersz zawierający liczby do uśrednienia, lub liczby, lub tekst dla warunku.

Criterion: A criterion is a single cell Reference, Number or Text. It is used in comparisons with cell contents.

A reference to an empty cell is interpreted as the numeric value 0.

A matching expression can be:

- A Number or Logical value. A matching cell content equals the Number or Logical value.

- A value beginning with a comparator (<, <=, =, >, >=, <>).

  For =, if the value is empty it matches empty cells.

  For <>, if the value is empty it matches non-empty cells.

  For <>, if the value is not empty it matches any cell content except the value, including empty cells.

  Note: "=0" does not match empty cells.

  For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes and the property Search criteria = and <> must apply to whole cells is checked, comparison is against the entire cell contents, if unchecked, comparison is against any subpart of the field that matches the criteria. For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes applies.

- Other Text value. If the property Search criteria = and <> must apply to whole cells is true, the comparison is against the entire cell contents, if false, comparison is against any subpart of the field that matches the criteria. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

Wyszukiwanie obsługuje symbole wieloznaczne lub wyrażenia regularne. Przy włączonych wyrażeniach regularnych możesz wpisać „all.*”, na przykład, aby znaleźć pierwszą lokalizację „all”, po której następuje dowolny znak. Jeśli chcesz wyszukać tekst, który jest również wyrażeniem regularnym, musisz poprzedzić każdy metaznak lub operator wyrażenia regularnego znakiem „\” albo umieścić tekst w \Q...\E. Możesz włączać i wyłączać automatyczną ocenę symboli wieloznacznych lub wyrażeń regularnych w LibreOffice - PreferencjeNarzędzia - Opcje - LibreOffice Calc - Oblicz .

W przypadku korzystania z funkcji, w których jeden lub więcej argumentów to ciągi kryteriów wyszukiwania reprezentujące wyrażenie regularne, pierwszą próbą jest przekonwertowanie kryteriów ciągu na liczby. Na przykład „.0” zostanie przekonwertowane na 0,0 i tak dalej. Jeśli się powiedzie, dopasowanie nie będzie dopasowaniem wyrażenia regularnego, ale dopasowaniem liczbowym. Jednak po przełączeniu na ustawienia regionalne, w których separatorem dziesiętnym nie jest kropka, konwersja wyrażeń regularnych działa. Aby wymusić ocenę wyrażenia regularnego zamiast wyrażenia liczbowego, użyj wyrażenia, którego nie można błędnie odczytać jako liczbowego, takiego jak „.[0]”, „.\0” lub „(?i).0”.

Zakres_średniej – opcjonalne. Zakres wartości do obliczenia średniej.

If the Average_Range is not specified, Range is used for both, the calculation of the mean and the search according to the condition. If Average_Range is specified, the Range is used only for the condition test, while Average_Range is used for the average calculation.

Funkcja ta jest częścią standardu Open Document Format for Office Applications (OpenDocument) w wersji 1.2. (ISO/IEC 26300:2-2015)

Jeśli komórka w zakresie wartości do obliczenia średniej jest pusta lub zawiera tekst, funkcja ŚREDNIA.JEŻELI zignoruje tę komórkę.
Jeśli cały zakres jest pusty, zawiera tylko tekst lub wszystkie wartości zakresu nie spełniają warunku (lub dowolna ich kombinacja), funkcja zwraca błąd #DZIEL/0!

#### Przykład

Poniżej opisano działanie tego pola na tabeli

| A | B | C
1 | Nazwa produktu | Sprzedaże | Przychód
2 | ołówek | 20 | 65
3 | ołów | 35 | 85
4 | notes | 20 | 190
5 | książka | 17 | 180
6 | piórnik | nie | nie

We wszystkich przykładach poniżej, zakresy dla sumy obliczeń zawierają wiersz #6, który jest ignorowany, ponieważ zawiera tekst.

#### Proste użycie

=ŚREDNIA.JEŻELI(B2:B6;"<35")

Oblicza średnią wartości z zakresu B2:B6, która jest mniejsza niż 35. Zwraca 19, ponieważ drugi wiersz nie bierze udziału w obliczeniach.

=ŚREDNIA.JEŻELI(B2:B6;"<"&MAKS(B2:B6))

Oblicza średnią wartości z tego samego zakresu, która jest mniejsza niż maksymalna wartość tego zakresu. Zwraca 19, ponieważ największa wartość (drugi wiersz) nie bierze udziału w obliczeniach.

=ŚREDNIA.JEŻELI(B2:B6;">"&MIN.K(B2:B6;1))

Oblicza średnią wartości z tego samego zakresu, która jest większa niż pierwsza, najmniejsza wartość tego zakresu. Zwraca 25, ponieważ pierwsza, najmniejsza wartość (czwarty wiersz) nie bierze udziału w obliczeniach.

#### Użycie Zakres_średniej

=ŚREDNIA.JEŻELI(B2:B6;"<35";C2:C6)

Funkcja przeszukuje jakie wartości są mniej niż 35 w zakresie B2:B6 i oblicza średnią odpowiadającą wartościom z zakresu C2:C6. Zwraca 145, ponieważ drugi wiersz nie bierze udziału w obliczeniach.

=ŚREDNIA.JEŻELI(B2:B6;">"&MIN(B2:B6);C2:C6)

Funkcja przeszukuje jakie wartości z zakresu B2:B6 są większe niż ostatnie wartości w zakresie B2:B6 i oblicza średnią odpowiadającą wartościom z C2:C6. Zwraca 113,31 ponieważ czwarty wiersz (w którym znajduje się co najmniej wartość w zakresie B2: B6) nie bierze udziału w obliczeniach.

=ŚREDNIA.JEŻELI(B2:B6;"<"&MAKS.K(B2:B6;2);C2:C6)

Funkcja przeszukuje jakie wartości z zakresu B2:B6 są mniejsze niż druga, duża wartość w zakresie B2:B6 i oblicza średnią odpowiadającą wartościom z zakresu C2:C6. Zwraca 180, ponieważ tylko czwarty wiersz bierze udział w obliczeniach.

#### Użycie wyrażeń regularnych

=ŚREDNIA.JEŻELI(A2:A6;"ołów";B2:B6)

Funkcja przeszukuje jakie komórki z zakresu A2:A6 zawierają tylko słowo "ołów" i oblicza średnią odpowiadającą wartościom z zakresu B2:B6. Zwraca 35, ponieważ tylko drugi wiersz bierze udział w obliczeniach. Wyszukiwanie wykonane jest w zakresie A2:A6, lecz wartości są zwracane z zakresu B2:B6.

=ŚREDNIA.JEŻELI(A2:A6;"ołów.*";B2:B6)

Funkcja przeszukuje jakie komórki z zakresu A2:A6 zaczynają się od słowa "ołów", a na końcu zawierają dowolną ilość innych symboli i oblicza średnią odpowiadającą wartościom z zakresu B2:B6. Zwraca 27,5, ponieważ teraz także słowo "ołówek" spełnia warunek i oba, pierwszy oraz drugi wiersz, biorą udział w obliczeniach.

=ŚREDNIA.JEŻELI(A2:A6;".*książka.*";B2:B6)

Funkcja przeszukuje jakie komórki z zakresu A2:A6 zawierają słowo "książka", a na początku i na końcu zawierają dowolną ilość innych symboli i oblicza średnią odpowiadającą wartościom z zakresu B2: B6. Zwraca 18,5, ponieważ tylko trzeci i czwarty wiersz bierze udział w obliczeniach.

#### Odwołanie do komórki jako kryterium

Jeśli chcesz łatwo zmienić kryterium, możesz określić je w osobnej komórce i użyć odwołań do tej komórki w warunku funkcji ŚREDNIA.JEŻELI.

=ŚREDNIA.JEŻELI(A2:A6;".*"&E2&".*";B2:B6)

Funkcja przeszukuje jakie komórki z zakresu A2:A6 zawierają kombinację znaków określonych w komórce E2, a na początku i na końcu zawierają dowolną ilością innych znaków i oblicza średnią odpowiadającą wartościom z zakresu B2:B6. Jeśli komórka E2 = książka, funkcja zwraca 18,5.

=ŚREDNIA.JEŻELI(B2:B6;"<"&E2;C2:C6)

Funkcja przeszukuje jakie komórki z zakresu A2:A6 są mniejsze niż wartość określona w E2 i oblicza średnią odpowiadającą wartościom z zakresu C2:C6. Jeśli komórka E2 = 35, funkcja zwraca 145.

Tematy pokrewne

ŚREDNIA, ŚREDNIA.A, ODCH.ŚREDNIE

COUNTIFS, MIN.WARUNKÓW, MAKS.WARUNKÓW, ŚREDNIA.JEŻELI, SUMIFS

Lista wyrażeń regularnych