Sumário
Índice 🔎︎

# Serviço SFDialogs.Dialog

O serviço Dialog auxilia na gestão de caixas de diálogo criadas com o Editor de Diálogos Basic. Cada instância desta classe representa uma caixa de diálogo única apresentada ao usuário.

Uma caixa de diálogo pode ser apresentada de forma modal ou não modal.

No modo modal, a caixa de diálogo é apresentada e a execução da macro é suspensa até que o botão OK ou Cancelar sejam pressionados. Enquanto isso, ações do usuário executadas na caixa de diálogo podem disparar ações específicas.

No modo não-modal a caixa de diálogo está "flutuando" no desktop do usuário e a execução do processo da macro continua normalmente. Um diálogo não-modal é fechado quando for finalizado com o método Terminate() ou quando a sessão LibreOffice é encerrada. O botão de fechar a janela é inativo em diálogos não-modais.

Caixas de diálogo desaparecem da memória após serem explicitamente encerradas.

O serviço SFDialogs.Dialog está intimamente relacionado ao serviço SFDialogs.DialogControl.

## Invocação e Uso do Serviço

Antes de utilizar o serviço Dialog, a biblioteca ScriptForge deve ser carregada ou importada:

• Macros BASIC precisam carregar a biblioteca ScriptForge usando a seguinte instrução:
GlobalScope.BasicLibraries.loadLibrary("ScriptForge")
• Scripts Python exigem uma importação do módulo scriptforge:
from scriptforge import CreateScriptService

O serviço Dialog é invocado através do método CreateScriptService. O método requer três argumentos posicionais para especificar a caixa de diálogo ser ativada:

Container: "GlobalScope" para bibliotecas pré-instalados o um nome de janela definido pelo serviço ScriptForge.UI. O valor padrão é uma String vazia "", o que indica o documento atual.

Library: Nome da biblioteca contida no "Container" como uma string sensível à caixa. O valor padrão é "Standard".

DialogName: String sensível à caixa designando a caixa de diálogo.

Os exemplos abaixo em Basic e Python mostram o diálogo dlgConsole que pertence à biblioteca compartilhada ScriptForge:

          Dim oDlg As Object, lButton As Long
          Dim Container As String, Library As String, DialogName As String
          Set oDlg = CreateScriptService("SFDialogs.Dialog", "GlobalScope", "ScriptForge", "dlgConsole")
          '... Inicialização dos controles vêm aqui...
          lButton = oDlg.Execute()
          'Modo padrão = Modal
          If lButton = oDlg.OKBUTTON Then
          '...Processa os controles e faz o que é necessário aqui...
          End If
          oDlg.Terminate()

Ou usando Python:

        dlg = CreateScriptService('SFDialogs.Dialog', 'GlobalScope', 'ScriptForge', 'dlgConsole')
        # ... Inicialização dos controles vem aqui...
        rc = dlg.Execute()
        # Modo padrão = Modal
        if rc == dlg.OKBUTTON:
            # ...Processa os controles e faz o que é necessário aqui...
        dlg.Terminate()

Use a string "GlobalScope" como o argumento container quando a caixa de diálogo estiver armazenada em Minhas macros e caixas de diálogo ou em Macros e diálogos da aplicação.

## Recuperando a instância Dialog que disparou um evento de diálogo

Uma instância do serviço Dialog pode ser obtida usando o serviço SFDialogs.DialogEvent, desde que o diálogo tenha sido inicializado usando o serviço Dialog. No exemplo abaixo, oDlg contém a instância Dialog que disparou o evento de diálogo.

        Sub aDialogEventHander(ByRef poEvent As Object)
            Dim oDlg As Object
            Set oDlg = CreateScriptService("SFDialogs.DialogEvent", poEvent)
            ' ...
        End Sub

Ou usando Python:

        def control_event_handler(event: uno):
            dlg = CreateScriptService("SFDialogs.DialogEvent", event)
            # ...

Note que nos exemplos anteriores o prefixo "SFDialogs." pode ser omitido quando for considerado apropriado.

## Lidando com exceções em manipuladores de eventos

Ao criar um manipulador de evento para eventos de diálogo, considera-se boa prática tratar erros dentro da própria sub rotina. Por exemplo, suponha que o manipulador de eventos abaixo seja chamado quando o botão do mouse é pressionado na janela da caixa de diálogo.

        Sub OnMouseButtonPressed(ByRef oEvent As Object)
        On Local Error GoTo Catch
            Dim oDialog As Object
            oDialog = CreateScriptService("DialogEvent", oEvent)
            ' Processa o evento
            Exit Sub
        Catch:
            MsgBox SF_Exception.Description
            SF_Exception.Clear
        End Sub

Chame SF_Exception.Clear se você não quiser que o erro seja propagado após o término da execução do diálogo.

Em Python use blocos try/except nativos para tratar exceções conforme mostrado abaixo:

        def on_mouse_button_pressed(event=None):
            try:
                dlg = CreateScriptService("DialogEvent", event)
                # Processa o evento
            except Exception as e:
                # O objeto "bas" é uma instância do serviço Basic
                bas.MsgBox(str(e))

## Propriedades

Nome | Somente leitura | Tipo | Descrição
--- | --- | --- | ---
OKBUTTON | Sim | Integer | Valor = 1. Um botão OK foi pressionado.
CANCELBUTTON | Sim | Integer | Valor = 0. Um botão Cancelar foi pressionado.
Caption | Não | String | Especifica o título da caixa de diálogo.
Height | Não | Long | Especifica a altura da caixa de diálogo.
Modal | Sim | Boolean | Especifica se a caixa de diálogo está em execução no formato "modal".
Name | Sim | String | Nome da caixa de diálogo
Page | Não | Integer | Uma caixa de diálogo pode ter várias páginas que podem ser percorridas pelo usuário uma a uma. A propriedade "Page" do objeto "Dialog" define qual página está ativa no diálogo.
Visible | Não | Boolean | Especifica se a caixa de diálogo está visível na área de trabalho. Por padrão, ela não é visível até que o método "Execute" seja invocado. Após isso, a caixa de diálogo passa a ser visível.
XDialogModel | Sim | UNO object | Objeto UNO representando o modelo do diálogo. Consulte XControlModel e UnoControlDialogModel na documentação da API para mais detalhes.
XDialogView | Sim | UNO object | Objeto UNO representando a visualização do diálogo. Consulte XControl e UnoControlDialog na documentação da API para mais detalhes.
Width | Não | Long | Especifica a largura da caixa de diálogo.

## Propriedades de Evento

Retorna uma String URI com a referência para o script disparado pelo evento. Leia sua especificação na página Scripting Framework.

Nome | Somente leitura | Descrição da IDE Basic
--- | --- | ---
OnFocusGained | Sim | Quando receber o foco
OnFocusLost | Sim | Quando perder o foco
OnKeyPressed | Sim | Tecla pressionada
OnKeyReleased | Sim | Ao soltar uma tecla
OnMouseDragged | Sim | Quando mover o mouse com tecla pressionada
OnMouseEntered | Sim | Quando o mouse estiver dentro
OnMouseExited | Sim | Quando o mouse estiver fora
OnMouseMoved | Sim | Ao mover o mouse
OnMousePressed | Sim | Ao pressionar o botão do mouse
OnMouseReleased | Sim | Ao soltar o botão do mouse

Lista de métodos do serviço Dialog
Activate Center Controls | EndExecute Execute GetTextsFromL10N | Resize SetPageManager Terminate

## Activate

Coloca o foco na instância Dialog atual. Retorna True se a focalização foi bem-sucedida.

Este método é chamado a partir de uma caixa de diálogo ou evento de controle, o quando um diálogo é apresentado no modo "não modal".

### Sintaxe:

svc.Activate(): bool

### Exemplo:

          Dim oDlg As Object
          Set oDlg = CreateScriptService(,, "myDialog")
          oDlg.Execute()
          ' ...
          oDlg.Activate()

Exemplos em LibreOffice Basic e Python assume que o diálogo é armazenado na biblioteca Standard do documento corrente.

         dlg = CreateScriptService(,,'myDialog')
         dlg.Execute()
         # ...
         dlg.Activate()

## Center

Centraliza a caixa de diálogo atual no centro de sua janela pai. Sem argumentos, o método centraliza a caixa de diálogo no meio da janela atual.

Retorna True se bem-sucedida.

### Sintaxe:

svc.Center(opt Parent: obj): bool

### Parâmetros:

Parent: Um objeto opcional que pode ser:

- um objeto de diálogo do tipo Dialog do ScriptForge

- um objeto ScriptForge com referência a um documento (Calc, Base, etc)

### Exemplo:

##### Em Basic

         Sub TriggerEvent(oEvent As Object)
             Dim oDialog1 As Object, oDialog2 As Object, lExec As Long
             Set oDialog1 = CreateScriptService("DialogEvent", oEvent) ' Caixa de diálogo que causou o evento
             Set oDialog2 = CreateScriptService("Dialog", ...) ' Abre uma segunda caixa de diálogo
             oDialog2.Center(oDialog1)
             lExec = oDialog2.Execute()
             Select Case lExec
                 ...
         End Sub

##### Em Python

         def triggerEvent(event: uno):
           dlg1 = CreateScriptService('DialogEvent.Dialog', event) # Caixa de diálogo que disparou o evento
           dlg2 = CreateScriptService('Dialog', ...) # Abre uma segunda caixa de diálogo
           dlg2.Center(dlg1)
           rc = dlg2.Execute()
           if rc is False:
             # ...

## Controls

Retorna:

- A lista dos controles contidos na caixa de diálogo

- Uma instância da classe DialogControl baseada em seu nome

### Sintaxe:

svc.Controls(): str[0..*]

svc.Controls(controlname: str): svc

### Parâmetros:

ControlName : String sensível à caixa com o nome válido de um controle. Se não for especificado, a lista de nomes de controles é retornada em um Array indexado em zero.

### Exemplo:

          Dim myDialog As Object, myList As Variant, myControl As Object
          Set myDialog = CreateScriptService("SFDialogs.Dialog", , "Standard", "Dialog1")
          myList = myDialog.Controls()
          Set myControl = myDialog.Controls("myTextBox")

         dlg = CreateScriptService('SFDialogs.Dialog','', 'Standard', 'Dialog1')
         ctrls = dlg.Controls()
         ctrl = dlg.Controls('myTextBox')

## EndExecute

Finaliza a apresentação de um diálogo modal e retorna o argumento como valor de retorno da ação Execute() atual.

EndExecute() está geralmente contido no processamento da macro disparada por uma caixa de diálogo ou evento de controle.

### Sintaxe:

svc.EndExecute(returnvalue: int)

### Parâmetros:

returnvalue: Valor passado para o método Execute() em execução.

### Exemplo:

Usando LibreOffice Basic:

          Sub OnEvent(poEvent As com.sun.star.lang.EventObject)
              Dim oDlg As Object
              Set oDlg = CreateScriptService("SFDialogs.DialogEvent", poEvent)
              oDlg.EndExecute(ReturnValue := 25)
          End Sub

Usando Python:

         from com.sun.star.lang import EventObject
         def on_event(event: EventObject):
             dlg = CreateScriptService("SFDialogs.DialogEvent", event)
             dlg.EndExecute(25)

As menções acima a com.sun.star.lang.EventObject são opcionais. Tais menções ajudam a identificar a API (Application Programming Interface) do LibreOffice.

## Execute

Mostra a caixa de diálogo, quando modal, e espera for sua finalização pelo usuário. O valor retornado é:

- 0 : Botão Cancelar pressionado

- 1 : Botão OK pressionado

- Caso contrário a caixa de diálogo foi finalizada com o comando EndExecute() lançado pelo diálogo ou um evento de controle.

Para caixas de diálogo não modais o método sempre retorna 0 e a execução da macro continua.

### Sintaxe:

svc.Execute(modal: bool = True): int

### Parâmetros:

modal: É False quando a caixa de diálogo for não modal. Padrão = True.

### Exemplo:

Neste exemplo em Basic myDialog é armazenado na biblioteca Standard do documento corrente.

          Dim oDlg As Object, lReturn As Long
          Set oDlg = CreateScriptService("SFDialogs.Dialog", , , "myDialog")
          lReturn = oDlg.Execute(Modal := False)
          Select Case lReturn
              ' ...
          End Select

Este código em Python mostra o diálogo modal DlgConvert da biblioteca Basic compartilhada Euro.

         dlg = CreateScriptService("SFDialogs.Dialog", 'GlobalScope', 'Euro', "DlgConvert")
         rc = dlg.Execute()
         if rc == dlg.CANCELBUTTON:
             # ...

## GetTextsFromL10N

Substitui todas as strings de texto fixas em uma caixa de diálogo por suas versões traduzidas com base em uma instância de serviço L10N. Este método traduz as seguintes strings:

- O título da caixa de diálogo.

- Os rótulos dos seguintes tipos de controle: botão, caixa de seleção, linha fixa, texto fixo, caixa de grupo e botão de rádio.

- Strings estáticas em caixas de listas (ListBoxes) e caixas de combinação (ComboBoxes).

- A dica de ferramenta ou texto de ajuda exibido ao passar o mouse sobre o controle.

O método retorna True se for bem-sucedido.

Para criar uma lista de textos a traduzir numa caixa de diálogo, utilize o método AddTextsFromDialog do serviço L10N.

### Sintaxe:

svc.GetTextsFromL10N(l10n: svc): bool

### Parâmetros:

l10n: uma instância do serviço L10N do qual serão extraídas as strings a traduzir.

### Exemplo:

O exemplo a seguir carrega strings traduzidas e as aplica à caixa de diálogo "MyDialog".

##### Em Basic

         oDlg = CreateScriptService("Dialog", "GlobalScope", "Standard", "MyDialog")
         myPO = CreateScriptService("L10N", "/home/user/po_files/")
         oDlg.GetTextsFromL10N(myPO)
         oDlg.Execute()

##### Em Python

         dlg = CreateScriptService("Dialog", "GlobalScope", "Standard", "MyDialog")
         myPO = CreateScriptService("L10N", "/home/user/po_files/")
         dlg.GetTextsFromL10N(myPO)
         dlg.Execute()

Acesse as páginas de ajuda do serviço L10N para saber mais sobre como os arquivos PO e POT são tratados.

## Resize

Move o canto superior esquerdo de uma caixa de diálogo às novas coordenadas especificadas e/ou modifica suas dimensões. Todas as distâncias são expressas usando 1/100 mm. Sem argumentos, o método redefine as dimensões iniciais. Retorna True se o redimensionamento for bem-sucedido.

### Sintaxe:

svc.Resize(opt Left: num, opt Top: num, opt Width: num, opt Height: num): bool

### Parâmetros:

Left: Distância horizontal do canto superior esquerdo.

Top: Distância vertical do canto superior esquerdo.

Width: Largura do retângulo que contém a caixa de diálogo.

Height: Altura do retângulo que contém a caixa de diálogo.

Argumentos ausentes ou com valores negativos não são alterados.

### Exemplo:

##### Em Basic

         oDialog.Resize(1000, 2000, Height := 6000) ' Largura não é modificada

##### Em Python

Com Python:

         oDialog.Resize(1000, 2000, Height = 6000)  # Largura não é modificada

## SetPageManager

Define quais controles em um diálogo são responsáveis por mudar de página, tornando mais fácil gerenciar a propriedade Page da caixa de diálogo e de seus controles.

Caixas de diálogo podem ter múltiplas páginas e a página visível é definida pela propriedade Page do diálogo. Se a propriedade Page não for modificada, a página visível padrão é igual a 0 (zero), o que significa que nenhuma página em particular está definida e todos os controles visíveis são mostrados independentemente de seus próprios valores da propriedade Page.

Quando a propriedade Page de um diálogo é modificada para um valor como 1, 2, 3 e assim por diante, então apenas os controles cujo valor Page forem iguais ao valor de página do diálogo serão mostrados.

Ao usar o método SetPageManager é possível definir quatro tipos de gerenciadores de página:

- Caixa de listagem ou caixa de combinação: neste caso, cada entrada na caixa de listagem ou caixa de combinação corresponde a uma página. O primeiro item refere-se à página 1, o segundo item refere-se à página 2 e assim por diante.

- Grupo de botões de opção: define um grupo de botões de opção que controlará qual página está visível.

- Sequence of buttons: define um conjunto de botões, cada um correspondendo a uma página de diálogo. Pode ser usado para emular uma interface com abas, colocando os botões lado a lado na caixa de diálogo.

- Botões Anterior/Próximo: define quais botões na caixa de diálogo serão usados para navegar para a página Anterior/Próxima na caixa de diálogo.

É possível usar mais de um mecanismo de gerenciamento de página ao mesmo tempo.

Este método deve ser chamado apenas uma vez antes de chamar o método Execute. As chamadas subsequentes são ignoradas.

Se for bem sucedido, este método retorna True.

### Sintaxe:

svc.SetPageManager(pilotcontrols: str = "", tabcontrols: str = "", wizardcontrols: str = "", opt lastpage: int): bool

### Parâmetros:

pilotcontrols: uma lista separada por vírgulas de nomes de controle ListBox, ComboBox ou RadioButton usados como gerenciadores de página. Para controles RadioButton, especifique o nome do primeiro controle no grupo a ser usado.

tabcontrols: uma lista separada por vírgulas de nomes de botões que serão usados como gerenciadores de página. A ordem em que são especificados neste argumento corresponde ao número da página a que estão associados.

wizardcontrols: uma lista separada por vírgulas com os nomes de dois botões que serão usados para os botões Anterior/Próximo.

lastpage: o número da última página disponível. Recomenda-se especificar esse valor ao usar o gerenciador de páginas Anterior/Próxima.

### Exemplo:

Considere um diálogo com três páginas. A caixa de diálogo possui um controle ListBox chamado "aPageList" que será usado para controlar a página visível. Além disso, há dois botões denominados "btnPrevious" e "btnNext" que serão usados como botões Anterior/Próximo na caixa de diálogo.

##### Em Basic

        oDialog.SetPageManager(PilotControls := "aPageList", _
                               WizardControls := "btnPrevious,btnNext", _
                               LastPage := 3)
        oDialog.Execute()

##### Em Python

        dlg.SetPageManager(pilotcontrols="aPageList",
                           wizardcontrols="btnPrevious,btnNext",
                           lastpage=3)
        dlg.Execute()

## Terminate

Finaliza o serviço Dialog para a instância atual. Retorna True se a finalização foi bem-sucedida.

### Sintaxe:

svc.Terminate(): bool

### Exemplo:

Os exemplos abaixo em Basic e Python abrem os diálogos não-modais DlgConsole e dlgTrace. Eles são armazenados, respectivamente, nas bibliotecas compartilhadas ScriptForge e Access2Base. Os botões de fechamento do diálogo são desabilitados e a terminação explícita é realizada ao final da execução do processo.

Neste exemplo um botão em DlgConsole está substituindo o fechamento inibido da janela:

##### Em Basic

         oDlg = CreateScriptService("SFDialogs.Dialog","GlobalScope","ScriptForge","DlgConsole")
         oDlg.Execute(modal:=False)
         Wait 5000
         oDlg.Terminate()

Com Python:

##### Em Python

         from time import sleep
         dlg = CreateScriptService('SFDialogs.Dialog',"GlobalScope",'Access2Base',"dlgTrace")
         dlg.Execute(modal=False)
         sleep 5
         dlg.Terminate()

Todas as rotinas ou identificadores do ScriptForge em Basic que possuem o caractere "_" como prefixo são reservadas para uso interno. Elas não devem ser usadas em macros escritas em Basic ou em Python.

Tópicos relacionados

Serviço SFDialogs.DialogControl

Serviço ScriptForge.UI