Inhalte

# Mathematische Funktionen

Diese Kategorie enthält mathematische Funktionen für Calc. Um den Funktionsassistenten zu öffnen, wählen Sie Einfügen – Funktion….

## AGGREGAT

Diese Funktion ergibt die Gesamtheit einer Berechnung in einem Bereich. Sie können verschiedene unten aufgelistete Gesamtheiten verwenden. Die Funktion erlaubt es, ausgeblendete Zeilen, Fehlerwerte und die Ergebnisse der Funktionen TEILERGEBNIS und AGGREGAT bei der Berechnung nicht zu berücksichtigen.

## SUBTRAKTION

Subtrahiert mehrere Zahlen und gibt das Ergebnis zurück, ohne kleine Rundungsfehler zu beseitigen.

## SUMME

Addiert eine Anzahl von Zahlen.

## FARBE

Gibt einen numerischen Wert zurück, der aus der Kombination der Werte für die drei Farben (rot, grün und blau) und dem Alpha-Kanal des RGBA-Farbsystems berechnet wird. Das Ergebnis ist abhängig vom Farbsystem des verwendeten Computers.

## SUMMEWENNS

Ergibt die Summe der Werte der Zellen in einem Bereich, die mehrere Bedingungen in mehreren Bereichen erfüllen.

## ABRUNDEN

Kürzt eine Zahl unter Beibehaltung einer bestimmten Anzahl von Dezimalstellen.

## ABS

Ergibt den Betrag (Absolutwert) einer Zahl.

#### Syntax

ABS(Zahl)

Zahl ist die Zahl, von der der Betrag berechnet werden soll. Der Betrag einer Zahl ist ihr Wert ohne Vorzeichen.

#### Beispiel

=ABS(-56) ergibt 56.

=ABS(12) ergibt 12.

=ABS(0) ergibt 0.

## ARCCOS

Ergibt den Arkuskosinus (inversen Kosinus) einer Zahl.

#### Syntax

ARCCOS(Zahl)

Diese Funktion ergibt den Arkuskosinus von Zahl, das heißt den Winkel (im Bogenmaß), dessen Kosinus Zahl ergibt. Der zurückgegebene Winkel liegt zwischen 0 und Pi.

Um den Winkel in Grad zu erhalten, verwenden Sie die Funktion GRAD.

#### Beispiel

=ARCCOS(-1) ergibt 3,14159265358979 (Pi im Bogenmaß)

=GRAD(ARCCOS(0,5)) ergibt 60. Der Kosinus von 60 Grad ist 0,5.

## ARCCOSHYP

Ergibt den Arkuskosinus Hyperbolicus einer Zahl.

#### Syntax

ARCCOSHYP(Zahl)

Diese Funktion ergibt den Arkuskosinus Hyperbolicus von Zahl, das heißt die Zahl, deren Kosinus Hyperbolicus Zahl ist.

Zahl muss größer oder gleich 1 sein.

#### Beispiel

=ARCCOSHYP(1) ergibt 0.

=ARCCOSHYP(COSHYP(4)) ergibt 4.

## ARCCOT

Ergibt den Arkuskotangens (inversen Kotangens) der gegebenen Zahl.

#### Syntax

ARCCOT(Zahl)

Diese Funktion ergibt den Arkuskotangens von Zahl, das heißt den Winkel (im Bogenmaß), dessen Kotangens Zahl ist. Der zurückgegebene Winkel liegt zwischen 0 und Pi.

Um den Winkel in Grad zu erhalten, verwenden Sie die Funktion GRAD.

#### Beispiel

=ARCCOT(1) ergibt 0,785398163397448 (PI/4 Bogenmaß).

=GRAD(ARCCOT(1)) ergibt 45. Der Tangens von 45 Grad ist 1.

## ARCCOTHYP

Ergibt den Arkuskotangens Hyperbolicus einer Zahl.

#### Syntax

ARCCOTHYP(Zahl)

Diese Funktion ergibt den Arkuskotangens Hyperbolicus von Zahl, das heißt die Zahl, deren Kotangens Hyperbolicus Zahl ist.

Ein Fehler tritt auf, wenn Zahl zwischen -1 und 1 einschließlich liegt.

#### Beispiel

=ARCCOTHYP(1,1) ergibt den Arkuskotangens Hyperbolicus von 1,1, also etwa 1,52226.

## ARCSIN

Ergibt den Arkussinus (inversen Sinus) einer Zahl.

#### Syntax

ARCSIN(Zahl)

Diese Funktion ergibt den Arkussinus von Zahl, das heißt den Winkel (im Bogenmaß), dessen Sinus Zahl ist. Der zurückgegebene Winkel liegt zwischen -Pi/2 und +Pi/2.

Um den Winkel in Grad zu erhalten, verwenden Sie die Funktion GRAD.

#### Beispiel

=ARCSIN(0) ergibt 0.

=ARCSIN(1) ergibt 1,5707963267949 (Pi/2 Bogenmaß).

=GRAD(ARCSIN(0,5)) ergibt 30. Der Sinus von 30 Grad ist 0,5.

## ARCSINHYP

Ergibt den Arkussinus Hyperbolicus einer Zahl.

#### Syntax

ARCSINHYP(Zahl)

Diese Funktion ergibt den Arkussinus Hyperbolicus von Zahl, das heißt die Zahl, deren Sinus Hyperbolicus Zahl ist.

#### Beispiel

=ARCSINHYP(-90) ergibt etwa -5,1929877.

=ARCSINHYP(SINHYP(4)) ergibt 4.

## ARCTAN

Ergibt den Arkustangens (inversen Tangens) einer Zahl.

#### Syntax

ARCTAN(Zahl)

Diese Funktion ergibt den Arkustangens von Zahl, das heißt den Winkel (im Bogenmaß), dessen Tangens Zahl ist. Der zurückgegebene Winkel liegt zwischen -Pi/2 und Pi/2.

Um den Winkel in Grad zu erhalten, verwenden Sie die Funktion GRAD.

#### Beispiel

=ARCTAN(1) ergibt 0,785398163397448 (PI/4 Bogenmaß).

=GRAD(ARCTAN(1)) ergibt 45. Der Tangens von 45 Grad ist 1.

## ARCTAN2

Gibt den Winkel (im Bogenmaß) zwischen der X-Achse und einer Linie vom Ursprung zum Punkt (Zahl_X|Zahl_Y) zurück.

Diese Funktion ist Teil des OpenDocument-Standards (Open Document Format for Office Applications) Version 1.2. (ISO/IEC 26300:2-2015)

#### Syntax

ARCTAN2(Zahl_X; Zahl_Y)

Zahl_X ist der Wert der X-Koordinate.

Zahl_Y ist der Wert der Y-Koordinate.

Programmiersprachen verwenden für die Funktion atan2() typischerweise die umgekehrte Reihenfolge der Argumente.

ARCTAN2 gibt den Winkel (im Bogenmaß) zwischen der X-Achse und einer Linie vom Ursprung zum Punkt (Zahl_X|Zahl_Y) zurück.

#### Beispiel

=ARCTAN2(-5;9) gibt 2,07789 zurück.

Um den Winkel im Gradmaß zu erhalten, wenden Sie die Funktion GRAD auf das Ergebnis an.

=GRAD(ARCTAN2(12,3;12,3)) ergibt 45. Der Tangens von 45 Grad ist 1.

LibreOffice gibt 0 für ARCTAN2(0;0) zurück.

Diese Funktion kann verwendet werden, um kartesische Koordinaten in Polarkoordinaten umzuwandeln.

=GRAD(ATAN2(-8;5)) ergibt φ = 147.9 Grad

## ARCTANHYP

Ergibt den Arkustangens Hyperbolicus einer Zahl.

#### Syntax

ARCTANHYP(Zahl)

Diese Funktion ergibt den Arkustangens Hyperbolicus von Zahl, das heißt die Zahl, deren Tangens Hyperbolicus Zahl ist.

Zahl muss die Bedingung -1 < Zahl < 1 erfüllen.

#### Beispiel

=ARCTANHYP(0) ergibt 0.

## AUFRUNDEN

Rundet eine von Null verschiedene Zahl mit einer festgelegten Genauigkeit auf.

#### Syntax

AUFRUNDEN(Zahl [; Stellen])

Ergibt Zahl, aufgerundet (weg von Null) auf die durch Stellen definierten Dezimalstellen. Wenn Stellen weggelassen wird oder Null ist, rundet die Funktion auf eine ganze Zahl auf. Wenn Stellen negativ ist, rundet die Funktion auf die nächsten 10, 100, 1000 und so weiter auf.

Diese Funktion rundet von Null weg. Für Alternativen siehe ABRUNDEN und RUNDEN.

#### Beispiel

=AUFRUNDEN(1,1111;2) ergibt 1,12.

=AUFRUNDEN(1,2345;1) ergibt 1,3.

=AUFRUNDEN(45,67;0) ergibt 46.

=AUFRUNDEN(-45,67) ergibt -46.

=AUFRUNDEN(987,65;-2) ergibt 1000.

## BOGENMASS

Aus der im Textfeld eingegebenen Gradzahl wird das Bogenmaß berechnet.

#### Syntax

BOGENMASS(Zahl)

Zahl ist der Winkel in Grad, der in Bogenmaß umgewandelt werden soll.

#### Beispiel

=BOGENMASS(90) ergibt 1,5707963267949, das heißt Pi/2 für die Genauigkeit von Calc.

## COS

Ergibt den Konsinus des gegebenen Winkels (im Bogenmaß).

#### Syntax

COS(Zahl)

Ergibt den Kosinus von Zahl, dem Winkel im Bogenmaß.

Um den Kosinus eines in Grad angegebenen Winkels zu erhalten, verwenden Sie die Funktion RAD.

#### Beispiel

=COS(PI()*2) ergibt 1, den Kosinus von 2*Pi im Bogenmaß.

=COS(BOGENMASS(60)) ergibt 0,5, den Kosinus von 60 Grad.

## COSEC

Ergibt den Kosekans eines vorgegebenen Winkels (im Bogenmaß). Der Kosekans eines Winkels ist gleich 1 geteilt durch den Sinus dieses Winkels.

Diese Funktion ist seit LibreOffice 3.5 verfügbar.

#### Syntax

COSEC(Zahl)

Ergibt den Kosekans von Zahl, dem Winkel im Bogenmaß.

Um den Kosekans eines in Grad angegebenen Winkels zu erhalten, verwenden Sie die Funktion BOGENMASS.

#### Beispiel

=COSEC(PI()/4) ergibt etwa 1,4142135624, das Inverse des Sinus von Pi/4 Bogenmaß.

=COSEC(BOGENMASS(30)) ergibt 2, den Kosekans von 30 Grad.

## COSECHYP

Ergibt den Kosekans Hyperbolicus einer Zahl.

Diese Funktion ist seit LibreOffice 3.5 verfügbar.

#### Syntax

COSECHYP(Zahl)

Ergibt den Kosekans Hyperbolicus von Zahl.

#### Beispiel

=COSECHYP(1) ergibt etwas 0,8509181282, den Kosekans Hyperbolicus von 1.

## COSHYP

Ergibt den Kosinus Hyperbolicus einer Zahl.

#### Syntax

COSHYP(Zahl)

Ergibt den Kosinus Hyperbolicus von Zahl.

#### Beispiel

=COSHYP(0) ergibt 1, den Kosinus Hyperbolicus von 0.

## COT

Ergibt den Kotangens des angegebenen Winkels (im Bogenmaß).

#### Syntax

COT(Zahl)

Ergibt den Kotangens von Zahl, dem Winkel im Bogenmaß.

Um den Kotangens eines in Grad angegebenen Winkels zu erhalten, verwenden Sie die Funktion BOGENMASS.

Der Kotangens eines Winkels ist gleich 1 dividiert durch den Tangens desselben Winkels.

### Beispiele:

=COT(PI()/4) ergibt 1, den Kotangens von Pi/4 Bogenmaß.

=COT(BOGENMASS(45)) ergibt 1, den Kotangens von 45 Grad.

## COTHYP

Ergibt den Kotangens Hyperbolicus einer Zahl (Winkel).

#### Syntax

COTHYP(Zahl)

Ergibt den Kotangens Hyperbolicus von Zahl.

#### Beispiel

=COTHYP(1) ergibt den Kotangens Hyperbolicus von 1, also etwa 1,3130.

## EUROUMRECHNEN

Rechnet ehemalige europäische nationale Währungen von und nach Euro um.

#### Syntax

EUROUMRECHNEN(Wert; Ausgangswährung; Zielwährung [;Volle Genauigkeit [;Zwischenergebnis Genauigkeit]])

Wert ist der Betrag der umzurechnenden Währung.

Ausgangswährung und Zielwährung sind die Währungseinheiten, aus denen beziehungsweise in die umgerechnet werden soll. Diese müssen aus einem Text bestehen, der eine offizielle Abkürzung der Währung ist (zum Beispiel "EUR"). Die (pro Euro zugrunde gelegten) Währungskurse wurden von der Europäischen Kommission festgelegt.

Volle Genauigkeit ist ein optionaler Parameter. Wenn er fehlt oder FALSCH ist, wird das Ergebnis auf die der Zielwährung entsprechenden Stellenanzahl gerundet. Wenn "Volle Genauigkeit" WAHR ist, wird das Ergebnis nicht gerundet.

Zwischenergebnis Genauigkeit ist ein optionaler Parameter. Wenn "Zwischenergebnis Genauigkeit" angeben und >= 3 ist, wird das Zwischenergebnis der Umwandlung (Währung 1, EUR, Währung 2) auf diese Genauigkeit gerundet. Wenn "Zwischenergebnis Genauigkeit" fehlt, wird das Zwischenergebnis nicht gerundet. Auch wenn die Zielwährung "EUR" ist, wird "Zwischenergebnis Genauigkeit" verwendet, als wenn ein Zwischenergebnis berechnet würde und auf die Umwandlung EUR zu EUR angewandt.

### Beispiele

=EUROUMRECHNEN(100;"ATS";"EUR") rechnet 100 Schilling in Euro um.

=EUROUMRECHNEN(100;"EUR";"DEM") rechnet 100 Euro in Deutsche Mark um.

## EXP

Ergibt die Potenz von e mit der eingegebenen Zahl. Die Konstante e hat etwa den Wert 2,71828182845904.

#### Syntax

EXP(Zahl)

Zahl ist der Exponent, mit dem e potenziert wird.

#### Beispiel

=EXP(1) ergibt 2,71828182845904, die mathematische Konstante e mit der Genauigkeit von Calc.

## FAKULTÄT

Ergibt die Fakultät einer Zahl.

#### Syntax

FAKULTÄT(Zahl)

Ergibt Zahl!, die Fakultät von Zahl, berechnet als 1*2*3*4* … *Zahl.

=FAKULTÄT(0) ergibt per Definition 1.

Die Fakultät einer negativen Zahl ergibt den Fehler "Ungültiges Argument".

#### Beispiel

=FAKULTÄT(3) ergibt 6.

=FAKULTÄT(0) ergibt 1.

## GANZZAHL

Die im Textfeld eingegebenen Zahl wird auf die nächstkleinere ganze Zahl abgerundet.

#### Syntax

GANZZAHL(Zahl)

Ergibt Zahl, gerundet auf die nächstkleinere ganze Zahl.

Negative Zahlen werden zur nächstkleineren ganzen Zahl gerundet.

#### Beispiel

=GANZZAHL(5,7) ergibt 5.

=GANZZAHL(-1,3) ergibt -2.

## GERADE

Rundet eine positive Zahl auf die nächste gerade ganze Zahl auf und eine negative Zahl auf die nächste gerade ganze Zahl ab.

#### Syntax

GERADE(Zahl)

Ergibt Zahl gerundet auf die nächste gerade ganze Zahl, weg von Null.

#### Beispiel

=GERADE(2,3) ergibt 4.

=GERADE(2) ergibt 2.

=GERADE(0) ergibt 0.

=GERADE(-0,5) ergibt -2.

## GGT

Ergibt den größten gemeinsamen Teiler von zwei oder mehr ganzen Zahlen.

Der größte gemeinsame Teiler ist die größte positive ganze Zahl, die durch die sich jede der angegebenen ganzen Zahlen ohne einen Rest teilen lassen.

#### Syntax

GGT(Ganze Zahl 1 [; Ganze Zahl 2 [; … [; Ganze Zahl 255]]])

Ganze Zahl 1, Ganze Zahl 2, …, Ganze Zahl 255 sind ganze Zahlen oder Verweise auf Zellen oder Zellbereiche mit ganzen Zahlen.

Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werthervorhebung.

#### Beispiel

=GGT(16;32;24) ergibt 8, weil 8 die größte Zahl ist, durch die 16, 24 und 32 ohne Rest geteilt werden können.

=GGT(B1:B3) ergibt 3, wenn die Zellen B1, B2 und B3 die Werte 9, 12 und 9 enthalten.

## GGT_EXCEL2003

Das Ergebnis ist der größte gemeinsame Teiler einer Liste von Zahlen.

Die Funktionen, deren Namen mit _ADD oder _EXCEL2003 enden, geben dieselben Ergebnisse zurück wie die entsprechenden Funktionen in Microsoft Excel ohne Endung. Verwenden Sie die Funktionen ohne Endung, um Ergebnisse zu erhalten, die auf internationalen Standards basieren.

#### Syntax

GGT_EXCEL2003(Zahl 1 [; Zahl 2 [; … [; Zahl 255]]]

Zahl 1, Zahl 2, …, Zahl 255 sind Zahlen oder Verweise auf Zellen oder Zellbereiche mit Zahlen.

#### Beispiel

=GGT_EXCEL2003(5;15;25) ergibt 5.

## GRAD

Rechnet Bogenmaß in Grad um.

#### Syntax

GRAD(Zahl)

Zahl ist der Winkel im Bogenmaß, der in Grad umgewandelt werden soll.

#### Beispiel

=GRAD(PI()) ergibt 180 Grad.

## KGV

Ergibt das kleinste gemeinsame Vielfache von zwei oder mehr ganzen Zahlen.

#### Syntax

KGV(Ganze Zahl 1 [; Ganze Zahl 2 [; … [; Ganze Zahl 255]]])

Ganze Zahl 1, Ganze Zahl 2, …, Ganze Zahl 255 sind ganze Zahlen oder Verweise auf Zellen oder Zellbereiche mit ganzen Zahlen.

Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werthervorhebung.

#### Beispiel

Wenn Sie die Zahlen 512, 1024 und 2000 in die Textfelder Ganze Zahl 1, 2 und 3 eingeben, wird 128000 als Ergebnis zurückgegeben.

## KGV_EXCEL2003

Das Ergebnis ist das kleinste gemeinsame Vielfache einer Liste von Zahlen.

Die Funktionen, deren Namen mit _ADD oder _EXCEL2003 enden, geben dieselben Ergebnisse zurück wie die entsprechenden Funktionen in Microsoft Excel ohne Endung. Verwenden Sie die Funktionen ohne Endung, um Ergebnisse zu erhalten, die auf internationalen Standards basieren.

#### Syntax

KGV_EXCEL2003(Zahl 1 [; Zahl 2 [; … [; Zahl 255]]])

Zahl 1, Zahl 2, …, Zahl 255 sind Zahlen oder Verweise auf Zellen oder Zellbereiche mit Zahlen.

#### Beispiel

=KGV_EXCEL2003(5;15;25) ergibt 75.

## KOMBINATIONEN

Ergibt die Anzahl von Kombinationen für Elemente ohne Wiederholung.

#### Syntax

KOMBINATIONEN(Anzahl_1; Anzahl_2)

Anzahl_1 ist die Anzahl von Elementen in der Gruppe.

Anzahl_2 ist die Anzahl von Elementen, die aus der Gruppe ausgewählt werden.

KOMBINATIONEN ergibt die Anzahl geordneten Wege zur Auswahl dieser Elemente. Wenn beispielsweise 3 Elemente A, B und C in einer Gruppe zusammengefasst sind, haben Sie 3 verschiedene Möglichkeiten, um 2 Elemente auszuwählen, nämlich AB, AC und BC.

KOMBINATIONEN führt folgende Formel aus: Anzahl_1!/(Anzahl_2!*(Anzahl_1-Anzahl_2)!)

#### Beispiel

=KOMBINATIONEN(3;2) ergibt 3.

## KOMBINATIONEN2

Ergibt die Anzahl von Kombinationen einer Teilmenge von Elementen einschließlich Wiederholung.

#### Syntax

KOMBINATIONEN2(Anzahl_1; Anzahl_2)

Anzahl_1 ist die Anzahl von Elementen in der Gruppe.

Anzahl_2 ist die Anzahl von Elementen, die aus der Gruppe ausgewählt werden.

KOMBINATIONEN2 ergibt die Anzahl von eindeutigen Wegen zur Auswahl dieser Elemente, wobei die Reihenfolge der Auswahl irrelevant ist. Wenn beispielsweise 3 Elemente A,B und C in einer Gruppe zusammengefasst sind, haben Sie 6 Möglichkeiten, um 2 Elemente auszuwählen, nämlich AA, AB, AC, BB, BC und CC.

KOMBINATIONEN2 führt folgende Formel aus: (Anzahl_1+Anzahl_2-1)! / (Anzahl_2!*(Anzahl_1-1)!)

#### Beispiel

=KOMBINATIONEN(3;2) ergibt 6.

## KÜRZEN

Kürzt eine Zahl unter Beibehaltung einer bestimmten Anzahl von Dezimalstellen.

## LN

Ergibt den natürlichen Logarithmus einer Zahl, basierend auf der Konstante e. Die Konstante e hat etwa Wert 2,71828182845904.

#### Syntax

LN(Zahl)

Zahl ist der Wert, dessen natürlicher Logarithmus berechnet werden soll.

#### Beispiel

=LN(3) ergibt den natürlichen Logarithmus von 3 (etwa 1,0986).

=LN(EXP(321)) ergibt 321.

## LOG

Ergibt den Logarithmus zu der angegebenen Basis.

#### Syntax

LOG(Zahl [; Basis])

Zahl ist der Wert, dessen Logarithmus berechnet werden soll.

Basis (optional) ist die Basis des zu berechnenden Logarithmus. Wenn dieser Parameter fehlt, wird als Basis 10 genommen.

#### Beispiel

=LOG(10;3) ergibt den Logarithmus von 10 zur Basis 3 (etwa 2,0959).

=LOG(7^4;7) ergibt 4.

## LOG10

Ergibt den Logarithmus einer Zahl zur Basis 10.

#### Syntax

LOG10(Zahl)

Ergibt den Logarithmus von Zahl zur Basis 10.

#### Beispiel

=LOG10(5) ergibt den Logarithmus von 5 zur Basis 10 (etwa 0,69897).

## PI

Ergibt 3,14159265358979, der Wert der mathematischen Konstanten Pi auf 14 Dezimalstellen.

#### Syntax

PI()

#### Beispiel

=PI() ergibt 3,14159265358979.

## POLYNOMIAL

Ergibt die Fakultät der Summe der Argumente geteilt durch das Produkt der Fakultäten der Argumente.

#### Syntax

POLYNOMIAL(Zahl 1 [; Zahl 2 [; … [; Zahl 255]]])

Zahl 1, Zahl 2, …, Zahl 255 sind Zahlen oder Verweise auf Zellen oder Zellbereiche mit Zahlen.

Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werthervorhebung.

#### Beispiel

=POLYNOMIAL(F11:H11) ergibt 1260, wenn in F11 bis H11 die Werte 2, 3 und 4 enthalten sind. Dies entspricht der Formel =(2+3+4)! / (2!*3!*4!)

## POTENZ

Ergibt eine Zahl hoch eine andere Zahl.

#### Syntax

POTENZ(Basis; Exponent)

Ergibt Basis hoch Exponent.

Das gleiche Resultat wird erzielt, wenn man den Exponentialoperator ^ verwendet:

Basis^Exponent

=POTENZ(0;0) ergibt 1.

#### Beispiel

=POTENZ(4;3) ergibt 64, also 4 hoch 3.

=4^3 ergibt auch 64, das Ergebnis von 4 hoch 3.

## POTENZREIHE

Summiert die ersten Glieder einer Potenzreihe.

POTENZREIHE(x;n;m;k)=k1xn + k2xn+m + k3xn+2m + … + kixn + (i-1)m.

#### Syntax

POTENZREIHE(X; N; M; Koeffizient(en))

X ist der Basiswert für die Potenzenreihe.

N ist der Anfangsexponent

M ist die Schrittweite der Erhöhung von N

Koeffizient(en) ist eine Folge von Koeffizienten. Für jeden Koeffizienten wird die Reihen um einen Summanden erweitert.

#### Beispiel

=POTENZREIHE(A1; 0; 1; {1; 2; 3}) berechnet den Wert von 1+2x+3x2, wobei x der Wert in Zelle A1 ist. Wenn A1 eine 1 enthält, ergibt die Formel 6; wenn A1 eine 2 enthält, ergibt die Formel 17; wenn A1 eine 3 enthält, ergibt die Formel 34; und so weiter.

Lesen Sie für weitere Details über diese Funktion die Wikipedia-Seite POTENZREIHE.

## PRODUKT

Multipliziert alle gegebenen Zahlen als Argumente und ergibt das Produkt.

#### Syntax

PRODUKT(Zahl 1 [; Zahl 2 [; … [; Zahl 255]]])

Zahl 1, Zahl 2, …, Zahl 255 sind Zahlen oder Verweise auf Zellen oder Zellbereiche mit Zahlen.

Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werthervorhebung.

#### Beispiel

=PRODUKT(2;3;4) ergibt 24.

## QUADRATESUMME

Berechnet die Summe der Quadrate einer Zahlenreihe.

#### Syntax

QUADRATSUMME(Zahl 1 [; Zahl 2 [; … [; Zahl 255]]])

Zahl 1, Zahl 2, …, Zahl 255 sind Zahlen oder Verweise auf Zellen oder Zellbereiche mit Zahlen.

Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werthervorhebung.

#### Beispiel

Wenn Sie die Zahlen 2, 3 und 4 als Argumente für Zahl 1, 2 und 3 eingeben, wird 29 als Ergebnis zurückgegeben.

## QUOTIENT

Ergibt den ganzzahligen Teil einer Division.

#### Syntax

QUOTIENT(Dividend; Divisor)

Ergibt den ganzzahligen Teil der Division von Dividend durch Divisor.

QUOTIENT ist gleichwertig mit GANZZAHL(Zähler/Nenner) für Zähler und Nenner mit gleichem Vorzeichen, bis auf dass unterschiedliche Fehlercodes zurückgegeben werden. Allgemeiner ist es gleichwertig mit GANZZAHL(Zähler/Nenner/VORZEICHEN(Zähler/Nenner))*VORZEICHEN(Zähler/Nenner).

#### Beispiel

=QUOTIENT(11;3) ergibt 3. Der Rest 2 geht verloren.

## REST

Ergibt den Rest bei der Division einer ganzen Zahl durch eine andere.

#### Syntax

REST(Divident; Divisor)

Bei ganzzahligen Argumenten ergibt diese Funktion Dividend Modulo Divisor, das heißt den Rest, wenn der Dividend durch Divisor geteilt wird.

Diese Funktion wird als Dividend-Divisor*GANZZAHL(Dividend/Divisor) ausgeführt und berechnet auch ein Ergebnis, wenn die Argumente keine ganzen Zahlen sind.

#### Beispiel

=REST(22;3) ergibt 1, den Rest der Division von 22 durch 3.

=REST(11,25;2,5) ergibt 1,25.

## RUNDEN

Rundet eine Zahl auf eine festgelegte Anzahl von Nachkommastellen.

#### Syntax

RUNDEN(Zahl [; Stellen])

Ergibt Zahl, gerundet auf die durch Stellen definierten Dezimalstellen. Wenn Stellen weggelassen wird oder null ist, rundet die Funktion auf die nächste ganze Zahl. Wenn Stellen negativ ist, rundet die Funktion auf die nächsten 10, 100, 1000 und so weiter.

Diese Funktion rundet auf die nächstgelegene Zahl. Für Alternativen siehe ABRUNDEN und AUFRUNDEN.

#### Beispiel

=RUNDEN(2,348;2) ergibt 2,35

=RUNDEN(-32,4834;3) ergibt -32,483. Ändern Sie das Zellenformat, um alle Dezimalstellen anzuzeigen.

=RUNDEN(2,348;0) ergibt 2.

=RUNDEN(2,5) ergibt 3.

=RUNDEN(987,65;-2) ergibt 1000.

## SEC

Ergibt den Sekans des vorgegebenen Winkels (im Bogenmaß). Der Sekans eines Winkels entspricht 1 geteilt durch den Kosinus des Winkels.

Diese Funktion ist seit LibreOffice 3.5 verfügbar.

#### Syntax

SEC(Zahl)

Ergibt den Sekans von Zahl, den Winkel im Bogenmaß.

Um den Sekans eines in Grad angegebenen Winkels zu berechnen, verwenden Sie die Funktion BOGENMASS.

#### Beispiel

=SEC(PI()/4) ergibt näherungsweise 1,4142135624, den Arkuskosinus von Pi/4 Bogenmaß.

=SEC(BOGENMASS(60)) ergibt 2, den Sekans von 60 Grad.

## SECHYP

Ergibt den Sekans Hyperbolicus einer Zahl.

Diese Funktion ist seit LibreOffice 3.5 verfügbar.

#### Syntax

SECHYP(Zahl)

Ergibt den Sekans Hyperbolicus von Zahl.

#### Beispiel

=SECHYP(0) ergibt 1, den Sekans Hyperbolicus von 0.

## SIN

Ergibt den Sinus eines gegebenen Winkels (im Bogenmaß).

#### Syntax

SIN(Zahl)

Ergibt den (trigonometrischen) Sinus von Zahl, den Winkel im Bogenmaß.

Um den Sinus eines in Grad angegebenen Winkels zu berechnen, verwenden Sie die Funktion BOGENMASS.

#### Beispiel

=SIN(PI()/2) ergibt 1, den Sinus von Pi/2 Bogenmaß.

=SIN(BOGENMASS(30)) ergibt 0,5, den Sinus von 30 Grad.

## SINHYP

Ergibt den Sinus Hyperbolicus einer Zahl.

#### Syntax

SINHYP(Zahl)

Ergibt den Sinus Hyperbolicus von Zahl.

#### Beispiel

=SINHYP(0) ergibt 0, den Sinus Hyperbolicus von 0.

## SUMMEWENN

Addiert die durch ein bestimmtes Kriterium festgelegten Zellen. Diese Funktion wird verwendet, um einen Bereich zu summieren, in dem Sie nach einem bestimmten Wert suchen.

Die Suche unterstützt Platzhalter oder reguläre Ausdrücke. Wenn reguläre Ausdrücke aktiviert sind, können Sie "all.*" eingeben, um beispielsweise das erste Vorkommen von "all", gefolgt von beliebigen Zeichen, zu finden. Wenn Sie nach einem Text suchen möchten, der auch ein regulärer Ausdruck ist, müssen Sie entweder jedem Metazeichen oder Operator eines regulären Ausdrucks ein "\" voranstellen oder den Text in \Q…\E einschließen. Die automatische Auswertung von Platzhaltern oder regulären Ausdrücken können Sie unter LibreOffice – EinstellungenExtras – Optionen… – LibreOffice Calc – Berechnen umschalten.

Wenn Sie Funktionen verwenden, bei denen ein oder mehrere Argumente Suchkriterien-Zeichenfolgen sind, die einen regulären Ausdruck darstellen, besteht der erste Versuch darin, die Zeichenfolgen-Kriterien in Zahlen umzuwandeln. Zum Beispiel wird in bestimmten Gebietsschemen ".0" in "0.0" konvertiert und so weiter. Bei Erfolg handelt es sich bei der Übereinstimmung nicht um eine Übereinstimmung mit regulären Ausdrücken, sondern um eine numerische Übereinstimmung. Wenn Sie jedoch zu einem Gebietsschema wechseln, in dem das Dezimaltrennzeichen nicht der Punkt ist, funktioniert die Konvertierung regulärer Ausdrücke. Um die Auswertung des regulären Ausdrucks anstelle eines numerischen Ausdrucks zu erzwingen, verwenden Sie einen Ausdruck, der nicht als numerisch falsch verstanden werden kann, beispielsweise ".[0]" oder ".\0" oder "(?i).0".

#### Syntax

SUMMEWENN(Bereich; Bedingung [; Summenbereich])

Bereich ist der Bereich, auf den das Kriterium angewendet werden soll.

Kriterium: Ein Kriterium ist ein einzelner Zellbezug, eine Zahl oder ein Text. Es wird für Vergleiche mit Zellinhalten verwendet.

Ein Verweis auf eine leere Zelle wird als Zahlenwert 0 interpretiert.

Ein passender Ausdruck kann sein:

- Eine Zahl oder ein logischer Wert. Ein übereinstimmender Zelleninhalt entspricht dem Zahlenwert oder dem logischen Wert.

- Ein Wert, der mit einem Vergleichsoperator beginnt (<, <=, =, >, >=, <>).

  Wenn der Wert für = leer ist, entspricht er leeren Zellen.

  Wenn der Wert für <> leer ist, entspricht er nicht leeren Zellen.

  Wenn der Wert für <> nicht leer ist, entspricht er jedem Zellinhalt außer dem Wert, einschließlich leerer Zellen.

  Hinweis: "=0" stimmt nicht mit leeren Zellen überein.

  Wenn der Wert für = und <> nicht leer ist und nicht als Zahlentyp oder einer seiner Untertypen interpretiert werden kann und die Eigenschaft Suchkriterien = und <> muss auf ganze Zellen zutreffen markiert ist, erfolgt der Vergleich mit dem gesamten Zellinhalt. Wenn sie nicht markiert ist, wird mit jedem Teil des Felds verglichen, der den Kriterien entspricht. Wenn der Wert für = und <> nicht leer ist und nicht als Zahlentyp oder einer seiner Untertypen interpretiert werden kann.

- Anderer Textwert. Wenn die Eigenschaft Suchkriterien = und <> muss für ganze Zellen gelten wahr ist, erfolgt der Vergleich mit dem gesamten Zelleninhalt , wenn falsch, wird mit jedem Unterteil des Felds verglichen, der den Kriterien entspricht. Der Ausdruck kann Text, Zahlen, reguläre Ausdrücke oder Platzhalter enthalten (sofern in den Berechnungsoptionen aktiviert).

Summenbereich ist der Bereich, aus dem die Werte summiert werden sollen. Wenn dieser Parameter nicht angegeben ist, werden die in Bereich gefundenen Werte summiert.

SUMMEWENN unterstützt den Bezugsverkettungsoperator (~) nur im Parameter „Bereich“ und dies auch nur, wenn der optionale Parameter „Summenbereich“ nicht angegeben ist.

#### Beispiel

Summieren ausschließlich negativer Zahlen im Bereich A1:A10: =SUMMEWENN(A1:A10;"<0")

=SUMMEWENN(A1:A10;">0";B1:B10) – summiert nur Werte aus dem Bereich B1:B10, wenn die entsprechenden Werte im Bereich A1:A10 >0 sind.

Weitere Syntaxbeispiele für die Funktion SUMMEWENN() finden Sie bei der Funktion ZÄHLENWENN().

## TAN

Ergibt den Tangens des gegebenen Winkels (im Bogenmaß).

#### Syntax

TAN(Zahl)

Ergibt den (trigonometrischen) Tangens von Zahl, den Winkel im Bogenmaß.

Um den Tangens eines in Grad angegebenen Winkels zu berechnen, verwenden Sie die Funktion BOGENMASS.

#### Beispiel

=TAN(PI()/4) ergibt 1, den Tangens von Pi/4 Bogenmaß.

=TAN(BOGENMASS(45)) ergibt 1, den Tangens von 45 Grad.

## TANHYP

Ergibt den Tangens Hyperbolicus einer Zahl.

#### Syntax

TANHYP(Zahl)

Ergibt den Tangens Hyperbolicus von Zahl.

#### Beispiel

=TANHYP(0) ergibt 0, den Tangens Hyperbolicus von 0.

## TEILERGEBNIS

Berechnet Teilergebnisse. Sollte ein Bereich bereits Teilergebnisse enthalten, werden diese nicht in die weitere Berechnung einbezogen. Verwenden Sie diese Funktion gemeinsam mit AutoFiltern, damit nur die gefilterten Datensätze berücksichtigt werden.

#### Syntax

TEILERGEBNIS(Funktion; Bereich)

Funktion ist eine Zahl, die für eine der folgenden Funktionen steht:

Funktionsindex (einschließlich versteckter Werte) | Funktionsindex (versteckte Werte werden ignoriert) | Funktion
--- | --- | ---
1 | 101 | MITTELWERT
2 | 102 | ANZAHL
3 | 103 | ANZAHL2
4 | 104 | MAX
5 | 105 | MIN
6 | 106 | PRODUKT
7 | 107 | STABW
8 | 108 | STABWN
9 | 109 | SUMME
10 | 110 | VARIANZ
11 | 111 | VARIANZEN

Verwenden Sie die Zahlen 1-11, um manuell ausgeblendete Zeilen zu berücksichtigen, oder 101-111, um sie nicht zu berücksichtigen; herausgefilterte Zellen werden nie berücksichtigt.

Bereich ist der Bereich, dessen Zellen berücksichtigt werden.

Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werthervorhebung.

#### Beispiel

Sie haben eine Tabelle im Zellbereich A1:B6 mit einer Stückliste für 10 Schüler. Zeile 2 (Füller) ist manuell ausgeblendet. Sie möchten die Summe der angezeigten Stückzahlen sehen; das heißt die Zwischensumme der eingeblendeten Zeilen. In diesem Fall ist die Formel:

| A | B
--- | --- | ---
1 | ARTIKEL | ANZAHL
2 | Füller | 10
3 | Stift | 10
4 | Notizbuch | 10
5 | Radiergummi | 10
6 | Anspitzer | 10

=TEILERGEBNIS(9;B2:B6) ergibt 50.

=TEILERGEBNIS(109;B2:B6) ergibt 40.

## UMRECHNEN_OOO

Rechnet einen Währungswert in Euro um, der in einer der alten Währungen von 19 Mitgliedstaaten der Eurozone angegeben wird, und umgekehrt. Die Umrechnung verwendet die festen Wechselkurse, zu denen die alten Währungen durch den Euro ersetzt wurden.

Es ist empfohlen, die flexiblere Funktion EUROUMRECHNEN für die Umrechnung zwischen diesen Währungen zu verwenden. UMRECHNEN_OOO ist keine standardisierte Funktion und nicht in andere Office-Programme übertragbar.

#### Syntax

UMRECHNEN_OOO(Wert; "Text 1"; "Text 2")

Wert ist der Betrag der umzurechnenden Währung.

Text 1 ist eine dreistellige Zeichenfolge, welche die Währung festlegt, aus der umgerechnet werden soll.

Text 2 ist eine dreistellige Zeichenfolge, welche die Währung festlegt, in die umgerechnet werden soll.

Text 1 und Text 2 müssen jeweils einen der folgenden Werte verwenden: "ATS", "BEF", "CYP", "DEM", "EEK", "ESP", "EUR", "FIM", "FRF", "GRD", "IEP", "ITL", "LTL", "LUF", "LVL", "MTL", "NLG", "PTE", "SIT" und "SKK".

Nur eine von beiden Zeichenfolgen Text 1 oder Text 2 darf "EUR" enthalten.

#### Beispiel

=UMRECHNEN_OOO(100;"ATS";"EUR") ergibt den Euro-Wert von 100 Österreichischen Schilling.

=UMRECHNEN_OOO(100;"EUR";"DEM") rechnet 100 Euro in Deutsche Mark um.

Lesen Sie für weitere Details über diese Funktion die Wikipedia-Seite UMRECHNEN_OOO.

## UNGERADE

Rundet eine positive Zahl auf die nächste ungerade ganze Zahl auf und eine negative Zahl auf die nächste ungerade ganze Zahl ab.

#### Syntax

UNGERADE(Zahl)

Ergibt Zahl gerundet auf die nächste ungerade ganze Zahl, weg von Null.

#### Beispiel

=UNGERADE(1,2) ergibt 3.

=UNGERADE(1) ergibt 1.

=UNGERADE(0) ergibt 1.

=UNGERADE(-3,1) ergibt -5.

## VORZEICHEN

Ergibt das Vorzeichen einer Zahl. Ergibt 1, wenn die Zahl positiv ist, -1 wenn sie negativ ist, und 0, wenn sie Null ist.

#### Syntax

VORZEICHEN(Zahl)

Zahl ist die Zahl, deren Vorzeichen bestimmt werden soll.

#### Beispiel

=VORZEICHEN(3,4) ergibt 1.

=VORZEICHEN(-4,5) ergibt -1.

## VRUNDEN

Ergibt eine Zahl auf das nächste ganzzahlige Vielfache einer anderen Zahl gerundet.

#### Syntax

VRUNDEN(Zahl; Vielfaches)

Ergibt Zahl auf das nächste Vielfache von Vielfaches gerundet.

Eine alternative Umsetzung ist Vielfaches*RUNDEN(Zahl/Vielfaches).

#### Beispiel

=VRUNDEN(15,5;3) ergibt 15, da 15,5 dichter an 15 (= 3*5) liegt als an 18 (= 3*6).

=VRUNDEN(1,4;0,5) ergibt 1,5 (= 0,5 * 3).

## WURZEL

Ergibt die positive Quadratwurzel einer Zahl.

#### Syntax

WURZEL(Zahl)

Ergibt die positive Quadratwurzel von Zahl.

Zahl muss positiv sein.

#### Beispiel

=WURZEL(16) ergibt 4.

=WURZEL(-16) ergibt den Fehler Ungültiges Argument.

## WURZELPI

Ergibt Quadratwurzel aus (Pi mal Zahl).

#### Syntax

WURZELPI(Zahl)

Ergibt die positive Quadratwurzel aus (PI mal Zahl).

Dies entspricht WURZEL(PI()*Zahl).

#### Beispiel

=WURZELPI(2) ergibt die Quadratwurzel von (2*Pi), etwa 2,506628.

## ZUFALLSBEREICH

Ergibt eine ganze Zufallszahl aus einem festgelegten Bereich.

Diese Funktion wird immer neu berechnet, wenn eine Neuberechnung erfolgt.

#### Syntax

ZUFALLSBEREICH(Kleinste_Zahl; Größte_Zahl)

Ergibt eine ganze Zufallszahl zwischen den ganzen Zahlen Kleinste_Zahl und Größte_Zahl (einschließlich beider).

Diese Funktion erzeugt jedes Mal, wenn Calc neu berechnet, eine neue Zufallszahl. Um die Neuberechnung in Calc zu erzwingen, drücken Sie F9.

Um Zufallszahlen zu generieren, die nicht wieder neu berechnet werden, kopieren Sie die Zellen, in denen diese Funktion enthalten ist, und wählen Bearbeiten – Inhalte einfügen… (wobei im sich öffnenden Dialog Alles einfügen und Formeln nicht aktiviert sein darf und Zahlen aktiviert sein muss).

#### Beispiel

=ZUFALLSBEREICH(20;30) ergibt eine ganze Zahl zwischen 20 und 30.

## ZUFALLSZAHL

Ergibt eine Zufallszahl zwischen 0 bis 1.

Diese Funktion wird immer neu berechnet, wenn eine Neuberechnung erfolgt.

#### Syntax

ZUFALLSZAHL()

Diese Funktion erzeugt jedes Mal, wenn Calc neu berechnet, eine neue Zufallszahl. Um die Neuberechnung in Calc zu erzwingen, drücken Sie F9.

Um Zufallszahlen zu generieren, die nicht neu berechnet werden sollen:

- Kopieren Sie Zellen, in denen =ZUFALLSZAHL() enthalten ist, und verwenden Bearbeiten – Inhalte einfügen… (wobei im sich öffnenden Dialog Alles einfügen und Formeln nicht aktiviert sein dürfen und Zahlen aktiviert sein muss).

- Verwenden Sie den Befehl Zelle mit Zufallszahlen ausfüllen (wählen Sie Tabelle – Zellen ausfüllen – Mit Zufallszahlen…).

- Verwenden Sie die Funktion ZUFALLSZAHL.NF() für nichtflüchtige Zufallszahlen.

#### Beispiel

=ZUFALLSZAHL() ergibt eine Zufallszahl zwischen 0 und 1.

## ZUFALLSZAHL.NF

Ergibt eine nichtflüchtige Zufallszahl zwischen 0 bis 1.

#### Syntax

ZUFALLSZAHL.NF()

Diese Funktion erzeugt bei der Eingabe eine nichtflüchtige Zufallszahl. Eine nichtflüchtige Funktion wird bei neuen Eingabeereignissen nicht neu berechnet. Die Funktion wird nicht neu berechnet, wenn F9 gedrückt wird, außer wenn sich der Cursor auf der Zelle befindet, welche die Funktion enthält, oder wenn der Befehl Unbedingte Neuberechnung (Shift+BefehlStrg+F9) verwendet wird. Beim Öffnen der Datei wird die Funktion neu berechnet.

#### Beispiel

ZUFALLSZAHL.NV() gibt eine nichtflüchtige ganze Zufallszahl zwischen 0 und 1 zurück.

#### Technische Information

Diese Funktion ist seit LibreOffice 7.0 verfügbar.

Diese Funktion ist nicht Bestandteil des Standards Open Document Format für Office-Anwendungen (OpenDocument) Version 1.3. Teil 4: Format für neu berechnete Formeln (OpenFormula). Der Namensraum ist

ORG.LIBREOFFICE.RAND.NV

## ZUFALLSZAHLBEREICH.NF

Ergibt eine nichtflüchtige ganze Zufallszahl aus einem festgelegten Bereich.

#### Syntax

ZUFALLSZAHLBEREICH.NF(Kleinste_Zahl; Größte_Zahl)

Gibt eine nichtflüchtige ganzzahlige Zufallszahl zwischen den ganzen Zahlen Kleinste_Zahl und Größte_Zahl (beide einschließlich) zurück. Eine nichtflüchtige Funktion wird bei neuen Eingabeereignissen oder Drücken von F9 nicht neu berechnet. Die Funktion wird jedoch neu berechnet, wenn F9 mit dem Cursor auf der Zelle, welche die Funktion enthält, beim Öffnen der Datei gedrückt wird, wenn der Befehl Unbedingte Neuberechnung (Umschalt+BefehlStrg+F9) verwendet wird und wenn Größe_Zahl oder Kleinste_Zahl neu berechnet werden.

#### Beispiel

=ZUFALLSBEREICH.NF(20;30) ergibt eine nichtflüchtige ganze Zahl zwischen 20 und 30.

=ZUFALLSZAHLBEREICH.NF(A1;30) gibt eine nichtflüchtige ganze Zahl zwischen dem Wert von Zelle A1 und 30 zurück. Die Funktion wird neu berechnet, wenn sich der Inhalt von Zelle A1 ändert.

#### Technische Information

Diese Funktion ist seit LibreOffice 7.0 verfügbar.

Diese Funktion ist nicht Bestandteil des Standards Open Document Format für Office-Anwendungen (OpenDocument) Version 1.3. Teil 4: Format für neu berechnete Formeln (OpenFormula). Der Namensraum ist

ORG.LIBREOFFICE.RANDBETWEEN.NV

Verwandte Themen

Funktionen nach Kategorie