Inhalte
Index 🔎︎

# Matrixfunktionen

Diese Kategorie enthält Matrixfunktionen.

## Was ist eine Matrix?

Eine Matrix ist ein verknüpfter Bereich von Zellen in einer Tabelle mit Werten. Bei einem Bereich, der drei Zeilen und drei Spalten abdeckt, spricht man von einer 3x3-Matrix:

| A | B | C | D | E
1 | 7 | 31 | 33
2 | 95 | 17 | 2
3 | 5 | 10 | 50
4

Die kleinste denkbare Matrix ist eine 1x2- oder 2x1-Matrix mit zwei benachbarten Zellen.

## Was ist eine Matrixformel?

Eine Formel, die mit den verschiedenen Einzelwerten eines Zellbereichs Berechnungen anstellt, nennt man eine Matrixformel. Von anderen Formeln unterscheidet sich eine Matrixformel dadurch, dass sie mit mehreren Werten gleichzeitig operiert.

Matrixformeln verarbeiten aber nicht nur mehrere Werte, sie können auch mehrere Werte ausgeben. Das Ergebnis einer Matrixformel ist ebenso eine Matrix.

Um in der obigen Matrix die Werte in den einzelnen Zellen mit 10 zu multiplizieren, ist es nicht nötig, eine Formel auf jede einzelne Zelle oder jeden einzelnen Wert anzuwenden. Es muss nur eine einzelne Matrixformel verwendet werden. Wählen Sie in einem anderen Teil des Tabellendokuments einen Bereich von 3 x 3 Zellen aus, geben Sie die Formel =10*A1:C3 ein, und bestätigen Sie diesen Eintrag mit [Umschalt+Befehl[Umschalt+Strg+Eingabetaste]. Das Ergebnis ist eine 3x3-Matrix, in der die einzelnen Werte im Zellbereich (A1:C3) mit dem Faktor 10 multipliziert werden.

Außer der Multiplikation können verschiedene andere Operatoren auf den Bezugsbereich (die Matrix) angewendet werden. In LibreOffice Calc können Sie Werte addieren (+), subtrahieren (-), multiplizieren (*), dividieren (/) und Exponenten (^), Verkettungen (&) sowie Vergleiche (=, <>, <, >, <=, >=) einsetzen. Die Operatoren können auf jeden Einzelwert im Zellbereich angewendet werden und liefern das Ergebnis als Matrix, sofern die Matrixformel eingegeben wurde.

Vergleichsoperatoren in einer Matrixformel behandeln leere Zellen auf die gleiche Weise wie in einer normalen Formel, das heißt entweder als Null oder als leere Zeichenfolge. Wenn beispielsweise die Zellen A1 und A2 leer sind, geben die Matrixformeln {=A1:A2=""} und {=A1:A2=0} eine Matrix von Zellen zurück, deren Bereich aus 1 Spalte und 2 Zeilen besteht und deren Inhalt WAHR ist.

### Wann empfiehlt es sich, mit Matrixformeln zu arbeiten?

Verwenden Sie Matrixformeln, wenn Sie eine Berechnung mit unterschiedlichen Werten häufig wiederholen müssen. Um die Berechnungsmethode zu einem späteren Zeitpunkt zu ändern, müssen Sie nur eine einzige Formel, nämlich die Matrixformel, aktualisieren. Zum Hinzufügen einer Matrixformel wählen Sie den gesamten Matrixbereich aus und nehmen die erforderlichen Änderungen an der Matrixformel vor.

Da Matrixformeln den Arbeitsspeicher nicht sonderlich belasten, können sie auch als platzsparende Alternative eingesetzt werden, wenn mehrere Werte zu berechnen sind. Darüber hinaus stellen Matrizen ein unverzichtbares Hilfsmittel für komplexe Berechnungen dar, denn sie erlauben es, mehrere Zellbereiche einzubeziehen. LibreOffice bietet verschiedene mathematische Funktionen für Matrizen wie beispielsweise MMULT zur Multiplikation zweier Matrizen oder SUMMENPRODUKT zur Ermittlung des skalaren Produkts zweier Matrizen.

## Arbeiten mit Matrixformeln in LibreOffice-Calc

### Impliziter Schnittpunkt von Matrixformeln

Sie können auch eine "normale" Formel erstellen, in der der Referenzbereich, beispielsweise die Parameter, eine Matrixformel angibt. Diese Formel wird auch als "implizite Schnittpunkt" der Matrixformel bezeichnet. Das Ergebnis ergibt sich aus dem Schnittpunkt des Referenzbereichs und der Zeilen oder Spalten, in denen sich die Formel befindet. Wenn es keinen Schnittpunkt gibt oder wenn der Bereich am Schnittpunkt mehrere Zeilen oder Spalten umfasst, wird der Fehler #WERT! angezeigt. Das folgende Beispiel veranschaulicht dieses Konzept:

In der oben stehenden Tabelle geben Sie die folgende Matrixformel in D1 ein:

{=A1:A3 + 100}

Die Zellen D1, D2 und D3 haben jeweils die Werte 107, 195 und 105.

Geben Sie die folgende Formel in E2 ein (Nicht als Matrixformel).

=A1:A3 + 100

Die Zellen E1 und E3 sind leer, Zelle E2 enthält den Wert 195. Dies ist der implizite Schnittpunkt von Matrixformeln.

Geben Sie die folgende Formel wie in E2 in E4 ein.

=A1:A3 + 100

Die Zelle E4 zeigt den Fehlerwert #WERT! an. Zeile 4 ist außerhalb des Bereichs A1:A3 von der Formel.

### Matrixformeln erstellen

Beim Erstellen von Matrixformeln im Fenster Funktionsassistent müssen Sie jedes Mal das Markierfeld Matrix aktivieren, damit die Ergebnisse in einer Matrix ausgegeben werden. Anderenfalls wird nur der Wert der oberen linken Zelle der zu berechnenden Matrix geliefert.

Wenn Sie die Matrixformel direkt in eine Zelle eingeben, müssen Sie [Umschalt+BefehlStrg+Eingabetaste] anstatt [Eingabetaste] verwenden. Nur dann wird die Formel zu einer Matrixformel.

LibreOffice Calc stellt Matrixformeln in geschweiften Klammern dar. Es ist nicht möglich, durch manuelle Eingabe der geschweiften Klammern Matrixformeln zu erzeugen.

Die Zellen einer Ergebnismatrix werden automatisch vor Änderungen geschützt. Sie können die Matrixformel jedoch bearbeiten, löschen oder kopieren, indem Sie den gesamten Matrix-Zellenbereich auswählen.

### Verwendung von eingebetteten Matrizen mit Konstanten in Formeln

Calc unterstützt eingebettete Matrizen/Vektoren in Formeln. Eine eingebettete Matrix wird in geschwungenen Klammern '{' und '}' eingeschlossen. Elemente können entweder eine Zahl (einschließlich negativer Zahlen), eine logische Konstante (WAHR, FALSCH) oder eine Zeichenfolge sein. Variablen sind nicht erlaubt. Matrizen können eine oder mehrere Zeilen und eine oder mehrere Spalten enthalten. Alle Zeilen müssen dieselbe Anzahl von Elementen enthalten.

Das Spaltentrennzeichen (trennt Elemente in Spalten) und das Zeilentrennzeichen sind abhängig von der Sprache und dem Gebietsschema. In dieser Hilfe werden jeweils das Semikolon ';' und der senkrechte Strich '|' verwendet, um Spalten und Zeilen zu verdeutlichen. Beispielsweise wird bei deutscher Gebietseinstellungen der Punkt '.' als Spalten- und das Semikolon ';' als Zeilentrennzeichen verwendet.

Um die Zeilen- und Spaltentrennzeichen nachzusehen und zu ändern, wählen Sie LibreOffice – EinstellungenExtras – Optionen… – Calc – Formeln – Trennzeichen.

Matrizen dürfen nicht verschachtelt sein.

Beispiele:

={1;2;3}

Eine Matrix mit einer Zeile bestehend aus den 3 Zahlen 1, 2, und 3.

Um diese Matrixkonstante einzugeben, markieren Sie drei Zellen nebeneinander, geben die Formel ={1;2;3} in geschweiften Klammern und mit Semikolons ein und drücken dann [Umschalt+Befehl[Umschalt+Strg+Eingabetaste].

={1;2;3|4;5;6}

Eine Matrix mit 2 Spalten und 3 Werten in jeder Spalte.

={0;1;2|FALSCH;WAHR;"zwei"}

Eine gemischte Matrix.

=SIN({1;2;3})

Eingegeben als eine Matrixformel, liefert das Ergebnis den Sinus der 3 Werte von 1, 2 und 3.

### Matrixformeln bearbeiten

1. Wählen Sie den Zellbereich oder die Matrix aus, welche/r die Matrixformel enthält. Um die gesamte Matrix auszuwählen, positionieren Sie den Cursor innerhalb des Matrixbereichs und drücken dann [Befehl[Strg+/], wobei [/] die Taste Division auf dem Ziffernblock ist.

2. Drücken Sie entweder [F2] oder setzen Sie den Cursor in die Eingabezeile der Rechenleiste. Beides hat den gleichen Effekt: Sie können die Formel jetzt bearbeiten.

3. Wenn Sie Änderungen vorgenommen haben, drücken Sie [Umschalt+Befehl[Umschalt+Strg+Eingabetaste].

Die einzelnen Zellen eines Matrixbereichs lassen sich separat formatieren. Sie können beispielsweise die Schriftfarbe ändern. Wählen Sie einen Zellbereich aus, und ändern Sie dann das gewünschte Attribut.

### Matrixformeln löschen

1. Wählen Sie den Zellbereich oder die Matrix aus, welche/r die Matrixformel enthält. Um die gesamte Matrix auszuwählen, positionieren Sie den Cursor innerhalb des Matrixbereichs und drücken dann [Befehl[Strg+/], wobei [/] die Taste Division auf dem Ziffernblock ist.

2. Drücken Sie Entf, um den Inhalt der Matrix zu löschen, einschließlich der Matrixformel. Oder Sie drücken Rückschritt, um den Dialog Inhalte löschen anzuzeigen. Dort wählen Sie Formeln oder Alles löschen und klicken auf OK.

### Matrixformeln kopieren

1. Wählen Sie den Zellbereich oder die Matrix mit der Matrixformel aus.

2. Drücken Sie entweder [F2] oder setzen Sie den Cursor in die Eingabezeile.

3. Kopieren Sie die Formel mittels [Befehl[Strg+C] in die Eingabezeile.

4. Wählen Sie den Zellbereich aus, in dem die Matrixformel eingefügt werden soll. Drücken Sie dann entweder [F2] oder setzen Sie den Cursor in die Eingabezeile.

5. Kopieren Sie die Formel mittels [Befehl[Strg+V] in den ausgewählten Bereich und bestätigen Sie diese mit [Umschalt+Befehl[Umschalt+Strg+Eingabetaste]. Der markierte Bereich enthält nun die Matrixformel.

### Matrixbereiche anpassen

Gehen Sie wie folgt vor, um die Ausgabematrix zu bearbeiten:

1. Wählen Sie den Zellbereich oder die Matrix mit der Matrixformel aus.

2. Rechts unten an der Auswahl befindet sich eine kleine Markierung, an der Sie den Bereich mit der Maus größer oder kleiner ziehen können.

Durch die Anpassung des Matrixbereichs wird nicht auch automatisch die Matrixformel angepasst. Sie ändern damit lediglich den Bereich, in dem das Ergebnis angezeigt wird.

Halten Sie [Befehl][Strg] gedrückt, um eine Kopie der Matrixformel in den vorgegebenen Dimensionen zu erstellen.

### Bedingte Matrixberechnungen

Eine bedingte Matrixberechnung ist eine Matrixformel, in der die Funktionen WENN() oder WAHL() enthalten sind. Das bedingende Argument in der Formel ist ein Referenzbereich oder eine Ergebnismatrix.

In dem folgenden Beispiel wird der Test auf >0 mit der Formel {=WENN(A1:A3>0;"Ja";"Nein")} für jede Zelle im Bereich A1:A3 angewendet und das Ergebnis in die entsprechende Zelle kopiert.

| A | B (Formel) | B (Ergebnis)
1 | 1 | {=WENN(A1:A3>0;"Ja";"Nein"} | Ja
2 | 0 | {=WENN(A1:A3>0;"Ja";"Nein"} | Nein
3 | 1 | {=WENN(A1:A3>0;"Ja";"Nein"} | Ja

Die folgenden Funktionen erfordern die Verwendung von Matrizen: KORREL, KOVARIANZ, SCHÄTZER, FTEST, ACHSENABSCHNITT, MDET, MINV, MMULT, MODALWERT, PEARSON, WAHRSCHBEREICH, BESTIMMTHEITSMASS, STEIGUNG, STFEHLERYX, SUMMENPRODUKT, SUMMEX2MY2, SUMMEX2PY2, SUMMEXMY2, TTEST. Wenn Sie Bereiche als Argumente beim Aufruf einer dieser Funktionen verwenden, verhalten sich die Funktionen wie Matrixfunktionen. Die folgende Tabelle bietet ein Beispiel für die erforderliche Verwendung einer Matrix:

| A | B (Formel) | B (Ergebnis) | C (erforderliche Matrixformel) | C (Ergebnis)
1 | 1 | =A1:A2+1 | 2 | =SUMMENPRODUKT(A1:A2+1) | 5
2 | 2 | =A1:A2+1 | 3 | =SUMMENPRODUKT(A1:A2+1) | 5
3 |  | =A1:A2+1 | #WERT! | =SUMMENPRODUKT(A1:A2+1) | 5

## EINHEITSMATRIX

Ergibt die quadratische Einheitsmatrix einer bestimmten Größe. Bei der Einheitsmatrix handelt es sich um eine quadratische Matrix, in der die Elemente auf der Hauptdiagonalen 1 und alle anderen Matrixelemente 0 ergeben.

#### Syntax

EINHEITSMATRIX(Dimension)

Dimension ist die Größe der Matrixeinheit.

Oben auf dieser Seite finden Sie eine allgemeine Einführung in die Verwendung der Matrixfunktionen.

#### Beispiel

Ziehen Sie in der Tabelle einen quadratischen Bereich auf, beispielsweise von A1 bis E5.

Wählen Sie die Funktion EINHEITSMATRIX, ohne den Bereich zu deaktivieren. Aktivieren Sie das Markierfeld Matrix. Geben Sie die gewünschten Dimensionen für die Matrixeinheit ein, in diesem Fall 5, und klicken Sie auf OK.

Sie können auch die Formel =EINHEITSMATRIX(5) in die letzte Zelle des ausgewählten Bereich (E5) eingeben und [Umschalt+Befehl+Eingabetaste][Umschalt+Strg+Eingabetaste] drücken.

Es wird nun eine Einheitsmatrix mit dem Bereich A1:E5 angezeigt.

Weitere Erklärungen finden Sie oben auf dieser Seite.

## HÄUFIGKEIT

Gibt die Häufigkeitsverteilung in einer einspaltigen Matrix an. Die Funktion zählt die Anzahl der Werte in der Matrix Daten, die innerhalb der von der Matrix Klassen vorgegebenen Werte liegen.

#### Syntax

HÄUFIGKEIT(Daten; Klassen)

Daten stellt den Bezug auf die zu zählenden Werte dar.

Klassen stellt das Array der Grenzwerte dar.

Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werthervorhebung.

Oben auf dieser Seite finden Sie eine allgemeine Einführung in die Verwendung der Matrixfunktionen.

#### Beispiel

In Spalte A der folgenden Tabelle sind unsortierte Messwerte aufgeführt. Spalte B enthält die von Ihnen angegebenen oberen Grenzen für die Klassen, in die Sie die Daten aus Spalte A verteilen möchten. Gemäß der in B1 eingegebenen Grenze ergibt die Funktion HÄUFIGKEIT die Anzahl der Messwerte kleiner oder gleich 5. Gemäß der Grenze von 10 in B2 ergibt HÄUFIGKEIT als zweites Ergebnis die Anzahl der Messwerte größer als 5 und kleiner oder gleich 10. Der in B6 eingegebene Text ">25" dient lediglich zu Referenzzwecken.

| A | B | C
1 | 12 | 5 | 1
2 | 8 | 10 | 3
3 | 24 | 15 | 2
4 | 11 | 20 | 3
5 | 5 | 25 | 1
6 | 20 | >25 | 1
7 | 16 |  |
8 | 9 |  |
9 | 7 |  |
10 | 16 |  |
11 | 33 |  |

Wählen Sie einen einspaltigen Bereich aus, in dem die Häufigkeit der Werte gemäß der Klassengrenzen eingetragen werden soll. Sie müssen eine Zelle über die oberste Klasse hinaus auswählen. Für dieses Beispiel wählen Sie den Bereich C1:C6. Rufen Sie die Funktion HÄUFIGKEIT im Funktionsassistenten auf. Wählen Sie den Bereich Daten als (A1:A11) und den Bereich Klassen, in dem Sie die Klassengrenzen eingegeben haben als (B1:B6). Aktivieren Sie das Markierfeld Matrix und klicken Sie auf OK. Die Häufigkeitszählung erscheint im Bereich C1:C6.

Weitere Erklärungen finden Sie oben auf dieser Seite.

## MDET

Ergibt die Determinante einer Matrix. Diese Funktion gibt als Ergebnis einen Wert in der aktuellen Zelle zurück. Sie müssen keinen Bereich für die Ausgabe des Ergebnisses definieren.

#### Syntax

MDET(Matrix)

Matrix stellt die quadratische Matrix dar, deren Determinanten bestimmt werden.

Oben auf dieser Seite finden Sie allgemeine Informationen zur Verwendung der Matrixfunktionen.

Weitere Erklärungen finden Sie oben auf dieser Seite.

## MINV

Ergibt die inverse Matrix.

#### Syntax

MINV(Matrix)

Matrix stellt die quadratische Matrix dar, die invertiert wird.

Weitere Erklärungen finden Sie oben auf dieser Seite.

#### Beispiel

Wählen Sie einen quadratischen Bereich aus, und rufen Sie MINV auf. Wählen Sie die Ausgabematrix aus, markieren Sie das Feld Matrix, und klicken Sie auf OK.

## MMULT

Bildet das Produkt zweier Matrizen. Die Spaltenanzahl in Matrix 1 muss mit der Zeilenanzahl in Matrix 2 übereinstimmen. Quadratische Matrizen weisen gleich viele Spalten wie Zeilen auf.

#### Syntax

MMULT(Matrix 1; Matrix 2)

Matrix 1 stellt die erste Matrix für die Bildung des Matrixprodukts dar.

Matrix 2 stellt die zweite Matrix mit derselben Zeilenanzahl dar.

Weitere Erklärungen finden Sie oben auf dieser Seite.

#### Beispiel

Wählen Sie einen quadratischen Bereich aus. Rufen Sie die Funktion MMULT auf. Wählen Sie Matrix 1 und anschließend Matrix 2 aus. Bei Verwendung des Funktionsassistenten aktivieren Sie das Markierfeld Matrix. Klicken Sie auf die Schaltfläche OK. Die Ausgabematrix wird im ersten ausgewählten Bereich angezeigt.

## MTRANS

Tauscht die Zeilen und Spalten einer Matrix gegeneinander aus.

#### Syntax

MTRANS(Matrix)

Matrix steht für die Matrix im Tabellendokument, deren Zeilen und Spalten gegeneinander ausgetauscht werden sollen.

Oben auf dieser Seite finden Sie allgemeine Informationen zur Verwendung der Matrixfunktionen.

#### Beispiel

Wählen Sie im Tabellendokument einen Bereich aus, in dem die transponierte Matrix angezeigt werden kann. Der ausgewählte Bereich muss dabei mindestens die gleiche Zeilen- und Spaltenanzahl aufweisen wie die Originalmatrix. Geben Sie dann die Formel direkt ein, wählen Sie die Originalmatrix aus und drücken Sie [Umschalt+Befehl+Eingabetaste][Umschalt+Strg+Eingabetaste]. Anderenfalls, wenn Sie mit dem Funktionsassistenten arbeiten, aktivieren Sie das Markierfeld Matrix. Die transponierte Matrix erscheint im ausgewählten Zielbereich und ist automatisch vor Änderungen geschützt.

| A | B | C | D
1 | 2 | 3 | 4 | 5
2 | 6 | 7 | 8 | 9

Die obige Tabelle ist 2 Zeilen und 4 Spalten groß. Um sie zu transponieren, wählen Sie 4 Zeilen und 2 Spalten aus. Angenommen, Sie möchten obige Tabelle in den Bereich B7:B19 (4 Zeilen, 2 Spalten) transponieren, dann wählen Sie den gesamten Bereich aus und geben dann das Folgende ein:

MTRANS(A1:D2)

Abschließend stellen Sie sicher, dass Sie sie als Matrixformel mittels [Umschalt+Befehl+Eingabetaste][Umschalt+Strg+Eingabetaste] abschließen. Das Ergebnis sieht folgendermaßen aus:

| A | B
7 | 2 | 6
8 | 3 | 7
9 | 4 | 8
10 | 5 | 9

## RGP

Ergibt eine Tabelle mit Statistikwerten für eine gerade Linie, die am besten zu einer Datenmenge passen.

#### Syntax

RGP(DatenY[;DatenX[;LinearerTyp[;Kenngrößen]]])

DatenY ist ein einfacher Zeilen- oder Spaltenbereich, der die Y-Koordinaten in einer Menge von Punkten festlegt.

DatenX ist eine Zeile oder Spalte, welche die X-Koordinaten festlegt. Wenn DatenX fehlt, ist es standardmäßig 1, 2, 3, …, n. Wenn es mehr als eine Menge von Variablen gibt, kann DatenX ein Bereich von mehreren Zeilen oder Spalten sein.

RGP findet die Gerade y = a + bx, die am besten die Daten annähert. Es wird eine lineare Regression (Methode "der kleinsten Quadrate") verwendet. Werden mehr als eine Menge von Variablen verwendet, ist die Gerade von der Form y = a + b1x1 + b2x2 + … + bnxn.

Wenn LinearerType FALSCH ist, wird eine Gerade durch den Ursprung erzwungen (die Konstante a = 0; y = bx). LinearerTyp ist standardmäßig WAHR (die Gerade geht nicht durch den Ursprung).

Wenn Kenngrößen fehlt oder FALSCH ist, wird nur die erste Zeile der Statistiktabelle zurückgegeben. Wenn sie WAHR ist, wird die ganze Tabelle zurückgegeben.

RGP ergibt eine Tabelle (Matrix) mit Statistikwerten wie unten und muss als Matrixformel eingegeben werden (beispielsweise mit [Umschalt+Befehl[Umschalt+Strg+Eingabetaste] anstatt einfach mit [Eingabetaste]).

In LibreOffice Calc-Funktionen dürfen Parameter, die als „optional“ gekennzeichnet sind, nur dann ausgelassen werden, wenn ihnen kein weiterer Parameter mehr folgt. So können Sie beispielsweise in einer Funktion mit vier Parametern, von denen die letzten beiden als „optional“ gekennzeichnet sind, den Parameter 4 oder die Parameter 3 und 4 auslassen, jedoch nicht den Parameter 3 allein.

Weitere Erklärungen finden Sie oben auf dieser Seite.

#### Beispiel

Diese Funktion ergibt eine Matrix und wird in gleicher Weise behandelt wie andere Matrixfunktionen. Wählen Sie einen Bereich für die Ergebnisse aus und dann die Funktion. Wählen Sie Daten Y. Sie können auch andere Parameter eingeben. Wählen Sie Matrix und klicken Sie auf OK.

Die vom System zurückgegebenen Ergebnisse (wenn Kenngrößen = 0) zeigen mindestens die Steigung der Regressionslinie und ihren Schnittpunkt mit der Y-Achse. Wenn Kenngrößen ungleich 0 ist, werden weitere Ergebnisse angezeigt.

### Weitere Ergebnisse der RGP-Funktion:

Betrachten Sie das folgende Beispiel:

| A | B | C | D | E | F | G
1 | x1 | x2 | y |  | RGP-Wert |  |
2 | 4 | 7 | 100 |  | 4,17 | -3,48 | 82,33
3 | 5 | 9 | 105 |  | 5,46 | 10,96 | 9,35
4 | 6 | 11 | 104 |  | 0,87 | 5,06 | #NV
5 | 7 | 12 | 108 |  | 13,21 | 4 | #NV
6 | 8 | 15 | 111 |  | 675,45 | 102,26 | #NV
7 | 9 | 17 | 120 |  |  |  |
8 | 10 | 19 | 133 |  |  |  |

Spalte A enthält mehrere X1-Werte, Spalte B mehrere X2-Werte und Spalte C die Y-Werte. Diese Werte haben Sie bereits in das Tabellendokument eingefügt. Sie haben nun E2:G6 im Tabellendokument eingerichtet und den Funktionsassistenten aktiviert. Damit RGP funktioniert, müssen Sie außerdem das Markierfeld Matrix im Fenster Funktionsassistent aktivieren. Nun wählen Sie die folgenden Werte im Tabellendokument aus (oder geben sie über die Tastatur ein):

DatenY ist C2:C8

DatenX ist A2:B8

LinearerTyp und Kenngrößen werden auf 1 gesetzt.

Sobald Sie auf OK klicken, füllt LibreOffice Calc die Matrix, wie im Beispiel gezeigt, mit den RGP-Werten aus.

Die Formel in der Rechenleiste entspricht jeder Zelle der RGP-Matrix {=RGP(C2:C8;A2:B8;1;1)}

Dies sind die Bedeutungen der errechneten RGP-Werte:

E2 und F2: Steigung m der Regressionslinie y=b+m*x für die Werte x1 und x2. Die Werte werden in umgekehrter Reihenfolge angegeben; das heißt die Steigung für x2 in E2 und die Steigung für x1 in F2.

G2: Der Schnittpunkt b mit der y-Achse.

E3 und F3: Der Standardfehler des Steigungswerts.

G3: Der Standardschätzfehler des Achsenabschnitts

E4: BESTIMMTHEITSMASS

F4: Der Standardschätzfehler der aus der Regression berechneten y-Werte.

E5: Der F-Wert aus der Varianzanalyse.

F5: Die Freiheitsgrade aus der Varianzanalyse.

E6: Die Summe der quadratischen Abweichungen der geschätzten y-Werte von ihrem arithmetischen Mittel.

F6: Die Summe der quadratischen Abweichungen der geschätzten y-Werte von den gegebenen y-Werten.

Weitere Erklärungen finden Sie oben auf dieser Seite.

## RKP

Diese Funktion berechnet eine Anpassung der angegebenen Daten als Exponentialkurve (exponentielle Regression, y=b*m^x).

#### Syntax

RKP(DatenY [; DatenX [; Funktionstyp [; Kenngrößen]]])

DatenY stellt die Y-Datenmatrix dar.

DatenX (optional) stellt die X-Datenmatrix dar.

Funktionstyp (optional). Wenn Funktionstyp = 0, werden Funktionen in der Form y = m^x berechnet. Anderenfalls werden Funktionen in der Form y = b*m^x berechnet.

Kenngrößen (optional). Ist Kenngrößen = 0, so werden nur die Regressionskoeffizienten berechnet.

In LibreOffice Calc-Funktionen dürfen Parameter, die als „optional“ gekennzeichnet sind, nur dann ausgelassen werden, wenn ihnen kein weiterer Parameter mehr folgt. So können Sie beispielsweise in einer Funktion mit vier Parametern, von denen die letzten beiden als „optional“ gekennzeichnet sind, den Parameter 4 oder die Parameter 3 und 4 auslassen, jedoch nicht den Parameter 3 allein.

Weitere Erklärungen finden Sie oben auf dieser Seite.

#### Beispiel

Siehe RGP. Als Ergebnis werden jedoch keine Quadratsummen ausgegeben.

## SUMMENPRODUKT

Die Produkte der Elemente von Matrizen werden addiert und ergeben die Summe dieser Produkte.

#### Syntax

SUMMENPRODUKT(Matrix 1 [; Matrix 2 [; … [; Matrix 255]]])

Matrix 1[;Matrix 2][;…[;Matrix 255]] stellen Matrizen dar, deren entsprechende Elemente multipliziert werden sollen.

Mindestens eine Matrix muss Teil der Argumentliste sein. Wenn nur eine Matrix angegeben wird, werden alle Matrixelemente summiert. Wenn mehr als eine Matrix angegeben ist, müssen alle dieselbe Größe haben.

#### Beispiel

| A | B | C | D
1 | 2 | 3 | 4 | 5
2 | 6 | 7 | 8 | 9
3 | 10 | 11 | 12 | 13

=SUMMENPRODUKT(A1:B3;C1:D3) ergibt 397.

Berechnung: A1*C1 + B1*D1 + A2*C2 + B2*D2 + A3*C3 + B3*D3

Sie können die Funktion SUMMENPRODUKT zum Berechnen des skalaren Produkts zweier Vektoren verwenden.

SUMMENPRODUKT ergibt eine einzelne Zahl. Es ist nicht erforderlich, die Funktion als eine Matrixfunktion einzugeben.

Weitere Erklärungen finden Sie oben auf dieser Seite.

## SUMMEX2MY2

Ergibt die Summe der Unterschiede der Quadrate der entsprechenden Werte von zwei Matrizen.

#### Syntax

SUMMEX2MY2(MatrixX; MatrixY)

MatrixX stellt die erste Matrix dar, deren Elemente quadriert und addiert werden sollen.

MatrixY stellt die zweite Matrix dar, deren Elemente quadriert und subtrahiert werden sollen.

Weitere Erklärungen finden Sie oben auf dieser Seite.

## SUMMEX2PY2

Ergibt die Summe der Quadratsummen der entsprechenden Werte in zwei Matrizen.

#### Syntax

SUMMEX2PY2(MatrixX; MatrixY)

MatrixX stellt die erste Matrix dar, deren Elemente quadriert und addiert werden sollen.

MatrixY stellt die zweite Matrix dar, deren Elemente quadriert und addiert werden sollen.

Weitere Erklärungen finden Sie oben auf dieser Seite.

## SUMMEXMY2

Die Quadrate der Differenzen von zwei Matrizen werden summiert.

#### Syntax

SUMMEXMY2(MatrixX; MatrixY)

MatrixX stellt die erste Matrix dar, deren Elemente subtrahiert und quadriert werden sollen.

MatrixY stellt die zweite Matrix dar, deren Elemente subtrahiert und quadriert werden sollen.

Weitere Erklärungen finden Sie oben auf dieser Seite.

## TREND

Ergibt Werte entlang eines linearen Trends.

#### Syntax

TREND(DatenY [; DatenX [; NeueDatenX [; LinearerTyp]]])

DatenY stellt die Y-Datenmatrix dar.

DatenX (optional) stellt die X-Datenmatrix dar.

NeueDatenX (optional) stellt die Matrix der X-Daten dar, die zur Neuberechnung von Werten verwendet werden.

LinearerTyp (optional). Ist LinearerTyp = 0, werden die Linien über den Nullpunkt berechnet. Anderenfalls werden Verschiebungslinien ebenfalls berechnet. Die Standardeinstellung ist LinearerTyp <> 0.

In LibreOffice Calc-Funktionen dürfen Parameter, die als „optional“ gekennzeichnet sind, nur dann ausgelassen werden, wenn ihnen kein weiterer Parameter mehr folgt. So können Sie beispielsweise in einer Funktion mit vier Parametern, von denen die letzten beiden als „optional“ gekennzeichnet sind, den Parameter 4 oder die Parameter 3 und 4 auslassen, jedoch nicht den Parameter 3 allein.

Weitere Erklärungen finden Sie oben auf dieser Seite.

#### Beispiel

Wählen Sie im Tabellendokument einen Bereich aus, in dem die Trenddaten angezeigt werden sollen. Rufen Sie die Funktion auf. Geben Sie die Ausgabedaten ein oder wählen Sie sie mit der Maus aus. Markieren Sie die Option Matrix und klicken Sie auf OK. Es werden die aus den Ausgangsdaten berechneten Trenddaten angezeigt.

## VARIATION

Berechnet die Punkte eines exponentiellen Trends in einer Matrix.

#### Syntax

VARIATION(Daten Y [; [ Daten X] [; [ Neue Daten X ] [; Art der Funktion ] ] ])

DatenY stellt die Y-Datenmatrix dar.

DatenX (optional) stellt die X-Datenmatrix dar.

NeueDatenX (optional) stellt die X-Datenmatrix dar, in der die Werte neu berechnet werden.

Funktionstyp (optional). Wenn Funktionstyp = 0, werden Funktionen in der Form y = m^x berechnet. Anderenfalls werden Funktionen in der Form y = b*m^x berechnet.

In LibreOffice Calc-Funktionen dürfen Parameter, die als „optional“ gekennzeichnet sind, nur dann ausgelassen werden, wenn ihnen kein weiterer Parameter mehr folgt. So können Sie beispielsweise in einer Funktion mit vier Parametern, von denen die letzten beiden als „optional“ gekennzeichnet sind, den Parameter 4 oder die Parameter 3 und 4 auslassen, jedoch nicht den Parameter 3 allein.

Weitere Erklärungen finden Sie oben auf dieser Seite.

#### Beispiel

Diese Funktion gibt eine Matrix zurück und wird in gleicher Weise behandelt wie andere Matrixfunktionen. Wählen Sie einen Bereich aus, in dem die Ergebnisse angezeigt werden sollen, und wählen Sie und dann die Funktion aus. Wählen Sie DatenY. Geben Sie weitere Parameter ein, markieren Sie die Matrix und klicken Sie auf OK.

Verwandte Themen

Funktionen nach Kategorie