Contenuto

# Categoria database

### Panoramica

Le dodici funzioni nella categoria Database aiutano ad analizzare una semplice banca dati che occupa un'area rettangolare del foglio di lavoro comprendente colonne e righe, con i dati organizzati un record per riga. La cella di intestazione di ogni colonna mostra il nome della colonna, il quale normalmente esprime il contenuto di ciascuna cella in quella colonna.

Le funzioni nella categoria Database accettano i seguenti tre argomenti:

1. Database. L'intervallo di celle del database.

2. Campo database. La colonna che contiene i dati da utilizzare nei calcoli della funzione.

3. Criteri. L'intervallo di celle in un'area separata del foglio di calcolo contenete i criteri di ricerca.

Questi argomenti sono descritti più esaustivamente sotto.

Tutte le funzioni hanno la stessa logica operativa di base. Il primo passaggio è usare il parametro Criteri per identificare il sottoinsieme di record nel Database che debbano essere usati per i successivi calcoli. Il secondo passo è estrarre i dati e svolgere i calcoli associati alla funzione specifica (media, somma, prodotto, ecc...). I valori elaborati sono i record selezionati nella colonna Campo database.

Calc interpreta le date e i valori logici (VERO e FALSO) come numeri quando esegue calcoli con queste funzioni.

### Argomenti delle funzioni del database

Le seguenti definizioni di argomento si applicano a tutte le funzioni nella categoria Database:

1. Argomento Database

   Database specifica l'intervallo di celle occupato dalla tabella database. La prima riga dell'intervallo contiene i nomi dei campi e le righe seguenti sono i record con i relativi valori dei campi.

   Un modo per definire l'intervallo di celle è inserire il riferimento alla cella nell'angolo in alto a sinistra seguito dai due punti (:) e quindi il riferimento alla cella in basso in destra. Un esempio potrebbe essere A1:E10.

   L'argomento Database può essere specificato anche passando il nome di un intervallo denominato o di un intervallo database. Utilizzare un nome esplicativo per definire l'intervallo di celle può migliorare la leggibilità della formula e la manutenzione del documento. Qualora al nome non corrisponda alcun intervallo denominato, Calc riporta l'errore #NOME?.

   Altri errori che potrebbero essere restituiti a causa di un argomento Database non valido sono #VALORE! e Err:504 (errore nell'elenco parametri).

2. Argomento Campo database

   Campo database specifica la colonna che la funzione userà per i calcoli dopo che i criteri di ricerca sono stati applicati e le righe di dati selezionate. Non è collegato ai criteri di ricerca.

   Specificate l'argomento Campo database in uno dei seguenti modi:

   - Inserendo un riferimento a una cella di intestazione all'interno dell'area Database. In alternativa, se alla cella è stato assegnato un nome identificativo come un intervallo database o un intervallo denominato, inserite tale nome. Se il nome non appartiene ad alcun intervallo definito, Calc restituisce l'errore #NOME?. Se il nome è valido, ma non è proprio solo di un'unica cella, Calc restituisce Err:504 (errore nell'elenco parametri).

   - Inserendo un numero che specifica la colonna all'interno dell'area Database, partendo da 1. Ad esempio, se il Database occupa l'intervallo di celle D6:H123, inserite 3 per indicare la cella di intestazione alla posizione F6. Calc si aspetta un valore intero compreso fra 1 e il numero di colonne comprese all'interno del Database e ignora qualsiasi cifra dopo la virgola decimale. Se il valore è inferiore a 1, Calc restituisce Err:504 (errore nell'elenco parametri). Se il valore è maggiore del numero di colonne contenute nel Database, Calc restituisce l'errore #VALORE!

   - Inserendo, tra virgolette, il nome letterale dell'intestazione della colonna dalla prima riga dell'intervallo Database. Ad esempio, "Distanza da scuola". Se il testo non corrisponde a alcuna delle intestazioni di colonna nell'area Database Calc restituisce Err:504 (errore nell'elenco parametri). Potete anche indicare un riferimento a una cella arbitraria (non all'interno delle aree Database e Criteri) che contiene la stringa desiderata.

   L'argomento Campo database è opzionale per le funzioni DB.CONTA.NUMERI e DB.CONTA.VALORI, ma è richiesto per le dieci altre funzioni Database.

3. Argomento Criteri

   Criteri specifica l'intervallo di celle contenenti i criteri di ricerca. Come per Database, la prima riga è quella con i nomi dei campi e le righe successive sono condizioni per i campi relativi. Le aree Database e Criteri non devono essere adiacenti, né sullo stesso foglio.

   Un modo per definire un intervallo di celle è inserire il riferimento della cella in alto a sinistra seguito dai due punti (:) e quindi dal riferimento alla cella in basso a destra. Ad esempio, A13:B14. Potete specificare l'intervallo di celle anche fornendo il nome di un intervallo definito o di un intervallo database. Se il nome non corrisponde ad alcuna area definita con nome, Calc restituisce l'errore #NOME?

   Err:504 (errore nell'elenco parametri) può essere restituito anche come risultato di un argomento Criteri non valido.

   I contenuti dell'area Criteri vengono descritti in maniera più dettagliata nella sezione che segue.

### Definire i Criteri di ricerca

Il numero di colonne occupate dall'area Criteri non deve essere lo stesso della larghezza dell'area Database. Tutte le intestazioni che compaiono nella prima riga di Criteri devono essere identiche alle intestazioni nella prima riga di Database. Tuttavia, non tutte le intestazioni di Database devono apparire nella prima riga di Criteri, mentre un'intestazione di Database può comparire più volte nella prima riga di Criteri.

I criteri di ricerca sono inseriti nelle celle della seconda riga e di quelle successive dell'area Criteri, sotto la riga che contiene le intestazioni. Le celle vuote all'interno dell'area Criteri vengono ignorate.

Utilizzate gli operatori di confronto <, <=, <>, >= e > per create dei criteri nelle celle dell'area Criteri. Si presume l'operatore = se una cella non è vuota, ma non inizia con un operatore di confronto.

Se scrivete più criteri in una riga, essi vengono collegati da E (logico). Se scrivete i criteri in righe diverse, vengono collegati da O (logico).

Potete creare i criteri facendo uso dei caratteri jolly, a patto che siano stati abilitati spuntando l'opzione Permetti caratteri jolly nelle formule nella finestra di dialogo LibreOffice - PreferenzeStrumenti - >Opzioni- LibreOffice Calc - Calcola. Se per voi è importante l'interoperabilità con Microsoft Excel, questa opzione dovrebbe essere abilitata.

È possibile costruire criteri ancora più sofisticati utilizzando le espressioni regolari, sempre che sia stata attivata l'opzione Permetti espressioni regolari nelle formule nella finestra di dialogo LibreOffice - PreferenzeStrumenti - Opzioni - LibreOffice Calc - Calcola.

Quando si utilizzano funzioni in cui uno o più argomenti sono stringhe di criteri di ricerca che rappresentano un'espressione regolare, innanzitutto si cerca di convertire i criteri della stringa in numeri. Per esempio, ".0" sarà convertito in 0.0 e così via. In caso di esito positivo, la corrispondenza non sarà quella di un'espressione regolare ma una corrispondenza numerica. Tuttavia, quando si passa a un'impostazione regionale in cui il separatore decimale non è il punto, tale passaggio fa funzionare la conversione in espressione regolare. Per forzare la valutazione dell'espressione regolare, anziché di quella numerica, utilizzare un'espressione che non possa essere erroneamente interpretata come numerica, per es., ".[0]", ".\0" oppure "(?i).0".

Un'altra impostazione che influisce sulla gestione dei criteri di ricerca siano gestiti è l'opzione I criteri di ricerca = e <> devono riferirsi a celle intere che si trova nella finestra di dialogo LibreOffice - PreferenzeStrumenti - Opzioni - LibreOffice Calc - Calcola. Essa determina se i criteri di ricerca che impostate per le funzioni Database debbano corrispondere esattamente all'intera cella. Se per voi è importante l'interoperabilità con Microsoft Excel, questa opzione deve essere abilitata.

### Esempi di utilizzo delle funzioni Database

La seguente tabella fornisce un esempio di database dimostrativo su come utilizzare le funzioni nella categoria Database. L'intervallo di celle A1:E10 elenca informazioni di fantasia riguardanti i bambini invitati alla festa di compleanno di Luca. Per ciascuna voce vengono fornite le informazioni seguenti: nome del partecipante, classe scolastica, età in anni, la distanza dalla scuola in metri e il peso in chili.

| A | B | C | D | E
1 | Nome | Classe | Età | Distanza | Peso
2 | Andrea | 3 | 9 | 150 | 40
3 | Elisabetta | 4 | 10 | 1000 | 42
4 | Carlo | 3 | 10 | 300 | 51
5 | Daniele | 5 | 11 | 1200 | 48
6 | Eva | 2 | 8 | 650 | 33
7 | Franco | 2 | 7 | 300 | 42
8 | Greta | 1 | 7 | 200 | 36
9 | Enrico | 3 | 9 | 1200 | 44
10 | Irene | 2 | 8 | 1000 | 42
11 |  |  |  |  |

I sei esempi che seguono usano la tabella di database sopra indicata, combinata con diverse aree di criteri di ricerca.

#### Esempio 1

| A | B | C | D | E
12 | Nome | Classe | Età | Distanza | Peso
13 |  |  |  | >600 |
14 |  |  |  |  |

Come in questo semplice esempio, a volte è conveniente (ma non necessario) posizionare l'area dei criteri di ricerca direttamente sotto la tabella database, con le colonne delle due aree allineate verticalmente. Le celle vuote all'interno dell'area di criteri vengono ignorate. Considerando la tabella database sopra e quest'area di criteri, inserite la formula =DB.CONTA.NUMERI(A1:E10;;A12:E14) in una cella vuota in qualunque altra posizione del foglio per contare quanti degli invitati di Luca sono distanti da scuola più di 600 metri. Viene restituito il valore 5 (conteggiando Elisabetta, Daniele, Eva, Enrico e Irene).

Si noti che lo stesso risultato è ottenibile anche con la formula =DB.CONTA.NUMERI(A1:E10;;D12:D13), e ciò dimostra che basta solamente che l'area dei criteri di ricerca contenga le intestazioni di colonna pertinenti.

#### Esempio 2

| A | B | C | D | E
12 |  | Età | Classe |  |
13 |  | >7 | 2 |  |
14 |  |  |  |  |

In questo esempio l'area dei criteri di ricerca contiene solo due intestazioni e queste non sono allineate verticalmente con le corrispondenti intestazioni nella tabella database di esempio. Poiché vi sono due condizioni nella stessa riga, queste sono legate dall'E logico. Considerando la tabella database di esempio sopra riportata e quest'area di criteri di ricerca, inserite la formula =DB.CONTA.NUMERI(A1:E10;;B12:C13) in una cella vuota in un'altra posizione del foglio per calcolare quanti degli invitati di Luca sono in seconda classe e maggiori di 7 anni. Il risultato è 2 (contando Eva e Irene).

#### Esempio 3

| A | B | C | D | E
12 |  | Età |  |  |
13 |  | 9 |  |  |
14 |  | 10 |  |  |

In questo esempio l'area dei criteri di ricerca contiene una sola intestazione. Poiché vi sono due condizioni in due righe consecutive, queste sono legate dall'O logico. Considerando la tabella database di esempio sopra riportata e quest'area di criteri di ricerca, inserite la formula =DB.CONTA.NUMERI(A1:E10;;B12:B14) in una cella vuota in un'altra posizione del foglio per contare quanti degli invitati di Luca abbiano 9 o 10 anni. Il risultato è 4 (conteggiando Andrea, Elisabetta, Carlo ed Enrico).

#### Esempio 4

| A | B | C | D | E
12 |  | Età | Età |  |
13 |  | >=8 | <=10 |  |
14 |  |  |  |  |

In questo esempio l'area dei criteri di ricerca contiene due ricorrenze della medesima intestazione. Poiché vi sono due condizioni in nella stessa riga queste sono relazionate dall'E logico. Considerando la tabella database di esempio sopra riportata e quest'area di criteri di ricerca, inserite la formula =DB.CONTA.NUMERI(A1:E10;;B12:C13) in una cella vuota in un'altra posizione del foglio per contare quanti degli invitati di Luca abbiano un età compresa fra 8 e 10 anni (inclusi). Il risultato è 6 (conteggiando Andrea, Elisabetta, Carlo, Eva, Enrico e Irene).

#### Esempio 5

| A | B | C | D | E
12 | Nome |  |  |  |
13 | F* |  |  |  |
14 |  |  |  |  |

Questo semplice esempio mostra l'uso dei caratteri jolly. Affinché l'esempio funzioni come voluto, abilitate i caratteri jolly nella finestra di dialogo LibreOffice - PreferenzeStrumenti - Opzioni - LibreOffice Calc - Calcola. Considerando la tabella database di esempio sopra riportata e quest'area di criteri di ricerca, inserite la formula =DB.CONTA.NUMERI(A1:E10;;A12:A13) in una cella vuota in un'altra posizione del foglio per contare quanti degli invitati di Luca abbiano un nome che inizia con la lettera "F". Il valore restituito è 1 (conteggiando Franco).

#### Esempio 6

| A | B | C | D | E
12 | Nome |  |  |  |
13 | [ABC].* |  |  |  |
14 |  |  |  |  |

Questo semplice esempio mostra l'utilizzo delle espressioni regolati. Affinché il risultato sia quello voluto, abilitate le espressioni regolari nella finestra di dialogo LibreOffice - PreferenzeStrumenti - Opzioni - LibreOffice Calc - Calcola. Considerando la tabella database di esempio sopra e quest'area di criteri di ricerca, inserite la formula =DB.CONTA.NUMERI(A1:E10;;A12:A13) in una cella vuota in un'altra posizione del foglio per contare quanti degli invitati di Luca abbiano un nome che inizia con le lettere "A", "B" o "C". Il risultato è 2 (conteggiando Andrea e Carlo).

## DB.CONTA.NUMERI

DB.CONTA.NUMERI conteggia il numero di celle (campi) della colonna specificata che contengono valori numerici per tutte le righe (record di dati) che corrispondono ai criteri di ricerca specificati. Se, tuttavia, non è specificata alcuna colonna, DB.CONTA.NUMERI restituisce il conteggio di tutti i record che corrispondono ai criteri di ricerca, a prescindere dal loro contenuto.

#### Sintassi

DB.CONTA.NUMERI(Database; [Campo_database]; Criteri_di_ricerca)

#### Esempio

La tabella del database di esempio con le informazioni sugli ospiti invitati al compleanno di Luca (descritta sopra) deve occupare le celle A1:E10. Il contenuto delle celle A12:E12 deve essere identico alle intestazioni della tabella database nelle celle A1:E1. Accertatevi che le celle A13:E13 siano vuote, ad eccezione della cella D13 che deve contenere ">600" (questo criterio di ricerca individuerà i record del database che hanno un valore maggiore di 600 nella colonna Distanza).

Inserite la formula =DB.CONTA.NUMERI(A1:E10;; A12:E13) in una cella vuota in un'altra posizione del foglio per calcolare quanti degli invitati di Luca percorrono oltre 600 metri per recarsi a scuola. Il valore restituito è 5.

Lo stesso risultato si ottiene utilizzando la formula =DB.CONTA.NUMERI(A1:E10; "Distanza"; A12:E13), poiché tutti i dati nella colonna distanza sono numerici. Se invece venisse utilizzata la formula =DB.CONTA.NUMERI(A1:E10; "Nome"; A12:E13), verrebbe restituito il valore 0 poiché la colonna Nome contiene dati non numerici.

## DB.CONTA.VALORI

DB.CONTA.VALORI conta il numero di celle (campi) non vuote di una specifica colonna, per tutte le righe (record del database) che corrispondono ai criteri di ricerca specificati. Le celle vuote della colonna specificata non vengono considerate. Se, tuttavia, non viene specificata alcuna colonna, DB.CONTA.VALORI restituisce il conteggio di tutti i record che corrispondono ai criteri di ricerca specificati, a prescindere dal loro contenuto.

#### Sintassi

DB.CONTA.VALORI(Database; [Campo_database]; Criteri_di_ricerca)

#### Esempio

La tabella del database di esempio con le informazioni sugli ospiti invitati al compleanno di Luca (descritta sopra) deve occupare le celle A1:E10. Il contenuto delle celle A12:E12 deve essere identico alle intestazioni della tabella database nelle celle A1:E1. Accertatevi che le celle A13:E13 siano vuote, ad eccezione della cella D13 che deve contenere ">600" (questo criterio di ricerca individuerà i record del database che hanno un valore maggiore di 600 nella colonna Distanza).

Inserite la formula =DB.CONTA.VALORI(A1:E10;; A12:E13) in una cella vuota in un'altra posizione del foglio per calcolare quanti degli invitati di Luca percorrono oltre 600 metri per recarsi a scuola. Il valore restituito è 5.

Lo stesso risultato lo otterreste se usaste la formula =DB.CONTA.VALORI(A1:E10; "Distanza"; A12:E13) o la formula =DB.CONTA.NUMERI(A1:E10; "Nome"; A12:E13). Il secondo caso mostra la differenza rispetto a DB.CONTA.NUMERI, DB.CONTA.VALORI conteggia sia i valori numerici che quelli alfanumerici nella colonna indicata dal parametro Campo database.

## DB.DEV.ST

DB.DEV.ST calcola la deviazione standard del campione basata sui valori numerici nelle celle (campi) della colonna specificata, per tutte le righe (record di database) che corrispondono ai criteri di ricerca specificati. I valori non numerici vengono ignorati.

Restituisce l'errore #NUM! se un record corrisponde esattamente ai criteri di ricerca specificati o se è presente solamente un valore numerico nelle celle della colonna specificata per i record corrispondenti.

Restituisce 0 se non viene trovata alcuna corrispondenza o se non sono presenti valori numerici nelle celle della colonna specificata per i record corrispondenti.

#### Sintassi

DB.DEV.ST(Database; Campo database; Criteri di ricerca)

#### Esempio

La tabella del database di esempio con le informazioni sugli ospiti invitati al compleanno di Luca (descritta sopra) deve occupare le celle A1:E10. Il contenuto delle celle A12:E12 deve essere identico alle intestazioni della tabella del database nelle celle A1:E1. Assicuratevi che le celle A13:E13 siano vuote, ad eccezione della cella E13 che deve contenere ">0" (questo criterio di ricerca serve per individuare tutti i record nella tabella).

Inserite la formula =DB.DEV.ST(A1:E10;"Peso"; A12:E13) in una cella vuota in un'altra posizione del foglio per calcolare la deviazione standard del campione del peso (in chilogrammi) degli invitati di Luca. Il valore restituito è 5,5.

## DB.DEV.ST.POP

DB.DEV.ST.POP calcola la deviazione standard della popolazione basata sui valori numerici nelle celle (campi) della colonna specificata, per tutte le righe (record del database) che corrispondono ai criteri di ricerca specificati. I valori non numerici vengono ignorati.

Restituisce l'errore #NUM! se non corrisponde alcun record ai criteri di ricerca o se non sono presenti valori numerici nelle celle della colonna specificata per i record corrispondenti.

#### Sintassi

DB.DEV.ST.POP(Database; Campo database; Criteri di ricerca)

#### Esempio

La tabella del database di esempio con le informazioni sugli ospiti invitati al compleanno di Luca (descritta sopra) deve occupare le celle A1:E10. Il contenuto delle celle A12:E12 deve essere identico alle intestazioni della tabella del database nelle celle A1:E1. Assicuratevi che le celle A13:E13 siano vuote, ad eccezione della cella E13 che deve contenere ">0" (questo criterio di ricerca serve per individuare tutti i record nella tabella).

Inserite la formula =DB.DEV.ST.POP(A1:E10;"Peso"; A12:E13) in una cella vuota in un'altra posizione del foglio per calcolare la deviazione standard della popolazione dei pesi in chilogrammi degli invitati di Luca. Il valore restituito è 5,18545.

## DB.MAX

DB.MAX calcola il valore massimo fra le celle (campi) della colonna specificata che contengono valori numerici, per tutte le righe (record del database) che corrispondono ai criteri di ricerca specificati. Le celle vuote o che contengono caratteri non numerici vengono escluse.

Restituisce 0 se non viene trovata alcuna corrispondenza o se nei record corrispondenti non sono presenti valori numerici diversi da 0 nelle celle della colonna specificata.

#### Sintassi

DB.MAX(Database; Campo database; Criteri di ricerca)

#### Esempio

La tabella del database di esempio con le informazioni sugli ospiti invitati al compleanno di Luca (descritta sopra) deve occupare le celle A1:E10. Il contenuto delle celle A12:E12 deve essere identico alle intestazioni della tabella del database nelle celle A1:E1. Assicuratevi che le celle A13:E13 siano vuote, ad eccezione della cella D13 che deve contenere ">0" (questo criterio di ricerca serve per individuare tutti i record nella tabella del database).

Inserite la formula =DB.MAX(A1:E10;"Distanza"; A12:E13) in una cella vuota in un'altra posizione del foglio per calcolare la distanza massima percorsa da uno degli invitati di Luca per recarsi a scuola. Il valore restituito è 1200.

## DB.MEDIA

DB.MEDIA calcola la media dei valori numerici nelle celle (campi) della colonna specificata, per tutte le righe (record del database) che corrispondono ai criteri di ricerca specificati. I valori non numerici all'interno di tali celle vengono ignorati.

Restituisce l'errore #DIV/0! se non corrisponde alcun record ai criteri di ricerca specificati o se non sono presenti valori numerici nelle celle della colonna specificata per i record corrispondenti.

#### Sintassi

DB.MEDIA(Database; Campo database; Criteri di ricerca)

#### Esempio

La tabella del database di esempio con le informazioni sugli ospiti invitati al compleanno di Luca (descritta sopra) deve occupare le celle A1:E10. Il contenuto delle celle A12:E12 deve essere identico alle intestazioni della tabella del database nelle celle A1:E1. Assicuratevi che le celle A13:E13 siano vuote, ad eccezione della cella D13 che deve contenere ">0" (questo criterio di ricerca serve per individuare tutti i record nella tabella del database).

Inserite la formula =DB.MEDIA(A1:E10;"Distanza"; A12:E13) in una cella vuota in un'altra posizione del foglio per calcolare la distanza media percorsa dagli invitati di Luca per recarsi a scuola. Il valore restituito è 666,67.

## DB.MIN

DB.MIN calcola il valore minimo fra le celle (campi) della colonna specificata che contengono valori numerici, per tutte le righe (record del database) che corrispondono ai criteri di ricerca specificati. Le celle vuote o che contengono caratteri non numerici vengono escluse.

Restituisce 0 se non viene trovata alcuna corrispondenza o se nei record corrispondenti non sono presenti valori numerici diversi da 0 nelle celle della colonna specificata.

#### Sintassi

DB.MIN(Database; Campo database; Criteri di ricerca)

#### Esempio

La tabella del database di esempio con le informazioni sugli ospiti invitati al compleanno di Luca (descritta sopra) deve occupare le celle A1:E10. Il contenuto delle celle A12:E12 deve essere identico alle intestazioni della tabella del database nelle celle A1:E1. Assicuratevi che le celle A13:E13 siano vuote, ad eccezione della cella D13 che deve contenere ">0" (questo criterio di ricerca serve per individuare tutti i record nella tabella del database).

Inserite la formula =DB.MIN(A1:E10;"Distanza"; A12:E13) in una cella vuota in un'altra posizione del foglio per calcolare la distanza minima percorsa da uno degli invitati di Luca per recarsi a scuola. Il valore restituito è 150.

## DB.PRODOTTO

DB.PRODOTTO calcola il prodotto di tutti i valori numerici nelle celle (campi) della colonna specificata, per tutte le righe (record del database) che corrispondono ai criteri di ricerca specificati. Le celle vuote o che contengono caratteri non numerici vengono escluse.

Restituisce 0 se non viene trovata alcuna corrispondenza o se non sono presenti valori numerici nelle celle della colonna specificata per i record corrispondenti.

#### Sintassi

DB.PRODOTTO(Database; Campo database; Criteri di ricerca)

#### Esempio

La tabella del database di esempio con le informazioni sugli ospiti invitati al compleanno di Luca (descritta sopra) deve occupare le celle A1:E10. Il contenuto delle celle A12:E12 deve essere identico alle intestazioni della tabella del database nelle celle A1:E1. Assicuratevi che le celle A13:E13 siano vuote, ad eccezione della cella C13 che deve contenere ">0" (questo criterio di ricerca serve per individuare tutti i record nella tabella).

Inserite la formula =DB.PRODOTTO(A1:E10;"Età"; A12:E13) in una cella vuota in un'altra posizione del foglio per calcolare il prodotto delle età (in anni) degli invitati al compleanno di Luca. Il valore restituito è 279417600.

## DB.SOMMA

DB.SOMMA calcola la somma di tutti i valori numerici nelle celle (campi) della colonna specificata, per tutte le righe (record del database) che corrispondono ai criteri di ricerca specificati. Le celle vuote o che contengono caratteri non numerici vengono escluse.

Restituisce 0 se non viene trovata alcuna corrispondenza o se non sono presenti valori numerici nelle celle della colonna specificata per i record corrispondenti.

#### Sintassi

DB.SOMMA(Database; Campo database; Criteri di ricerca)

#### Esempio

La tabella del database di esempio con le informazioni sugli ospiti invitati al compleanno di Luca (descritta sopra) deve occupare le celle A1:E10. Il contenuto delle celle A12:E12 deve essere identico alle intestazioni della tabella del database nelle celle A1:E1. Assicuratevi che le celle A13:E13 siano vuote, ad eccezione della cella D13 che deve contenere ">0" (questo criterio di ricerca serve per individuare tutti i record nella tabella del database).

Inserite la formula =DB.SOMMA(A1:E10;"Distanza"; A12:E13) in una cella vuota in un'altra posizione del foglio per calcolare la somma di tutte le distanze che gli invitati al compleanno di Luca percorrono per recarsi a scuola. Il valore restituito è 6000.

## DB.VALORI

DB.VALORI restituisce il contenuto della cella (campo) della colonna specificata, per la singola riga (record del database) che corrisponde ai criteri di ricerca specificati.

Calc restituisce Err:502 (argomento non valido) se viene riscontrata più di una corrispondenza, o un errore #VALORE! (tipo dati errato) se non esiste alcuna corrispondenza. L'errore #VALORE! viene restituito anche quando vi trovata una singola corrispondenza ma la relativa cella è vuota.

#### Sintassi

DB.VALORI(Database; Campo database; Criteri di ricerca)

#### Esempio

La tabella del database di esempio con le informazioni sugli ospiti invitati al compleanno di Luca (descritta sopra) deve occupare le celle A1:E10. Il contenuto delle celle A12:E12 deve essere identico alle intestazioni della tabella database nelle celle A1:E1. Assicuratevi che le celle A13:E13 siano vuote, ad eccezione della cella C13 che deve contenere "11" (questo criterio di ricerca individuerà i record del database che contengono il valore 11 nella colonna dell'età).

Inserite la formula =DB.VALORI(A1:E10;"Nome"; A12:E13) in una cella vuota in un'altra posizione del foglio per trovare il nome dell'invitato di Luca che ha 11 anni. Il valore restituito è Daniele.

Se cambiate il valore nella cella C13 in "10", allora la formula =DB.VALORI(A1:E10;"Nome";A12:E13) restituisce un errore di argomento non valido (Err:502). Questo perché sono presenti più record che corrispondono al criterio di ricerca specificato (Elisabetta e Carlo hanno entrambi 10 anni).

## DB.VAR

DB.VAR calcola la varianza del campione basata sui valori numerici nelle celle (campi) della colonna specificata, per tutte le righe (record del database) che corrispondono ai criteri di ricerca specificati. I valori non numerici vengono ignorati.

Restituisce l'errore #NUM! se un record corrisponde esattamente ai criteri di ricerca specificati o se è presente solamente un valore numerico nelle celle della colonna specificata per i record corrispondenti.

Restituisce 0 se non viene trovata alcuna corrispondenza o se non sono presenti valori numerici nelle celle della colonna specificata per i record corrispondenti.

#### Sintassi

DB.VAR(Database; Campo database; Criteri di ricerca)

#### Esempio

La tabella del database di esempio con le informazioni sugli ospiti invitati al compleanno di Luca (descritta sopra) deve occupare le celle A1:E10. Il contenuto delle celle A12:E12 deve essere identico alle intestazioni della tabella del database nelle celle A1:E1. Assicuratevi che le celle A13:E13 siano vuote, ad eccezione della cella D13 che deve contenere ">0" (questo criterio di ricerca serve per individuare tutti i record nella tabella del database).

Inserite la formula =DB.VAR(A1:E10;"Distanza"; A12:E13) in una cella vuota in un'altra posizione del foglio per calcolare la varianza del campione delle distanze (in metri) che gli invitati di Luca percorrono per recarsi a scuola. Il valore restituito è 193125.

## DB.VAR.POP

DB.VAR.POP calcola la varianza di popolazione basata sui valori numerici nelle celle (campi) della colonna specificata, per tutte le righe (record del databasei) che corrispondono ai criteri di ricerca specificati. I valori non numerici vengono ignorati.

Restituisce l'errore #NUM! se non corrisponde alcun record ai criteri di ricerca o se non sono presenti valori numerici nelle celle della colonna specificata per i record corrispondenti.

#### Sintassi

DB.VAR.POP(Database; Campo database; Criteri di ricerca)

#### Esempio

La tabella del database di esempio con le informazioni sugli ospiti invitati al compleanno di Luca (descritta sopra) deve occupare le celle A1:E10. Il contenuto delle celle A12:E12 deve essere identico alle intestazioni della tabella del database nelle celle A1:E1. Assicuratevi che le celle A13:E13 siano vuote, ad eccezione della cella D13 che deve contenere ">0" (questo criterio di ricerca serve per individuare tutti i record nella tabella del database).

Inserite la formula =DB.VAR.POP(A1:E10;"Distanza"; A12:E13) in una cella vuota in un'altra posizione del foglio per calcolare la varianza di popolazione delle distanze (in metri) che gli invitati di Luca percorrono per recarsi a scuola. Il valore restituito è 171666,67.

Argomenti correlati

Funzioni per categoria