XSLÅ.OPP-funksjonen

Innhald

# XSLÅ.OPP

Søkjer etter ein verdi i ei matrise og returnerer referansen til ei celle eller eit celleområde.

Funksjonen XSLÅ.OPP er ein nyare og fleksibel erstatning for eldre funksjonar som FINN.RAD, FINN.KOLONNE og SLÅ.OPP. XSLÅ.OPP har støtte for omtrentleg og eksakt samsvar, jokerteikn (* ?) eller regulære uttrykk for delvise treff og oppslag i loddrette eller vassrette område. XSLÅ.OPP kan utføra eit omvendt søk og tilbyr eit raskt binært søkealternativ når du arbeidar med store datasett.

### Syntaks

XSLÅ.OPP( [Søkjekriterium] ; Søkjematrise ; Resultatmatrise [ ; [ Resultat viss ikkje funne ] [ ; [Treffmodus] [ ; Søkjemodus ] ] ] )

Søkjekriterium: (valfri) Verdien av kva type som helst som skal søkjast etter i Matrise. Viss utelete, returnerer XSLÅ.OPP tomme celler det finn i Søkjematrise.

Søkjematrise: er referansen til matrisa det skal søkjast i. Matrisa må vera ei 1-dimensjonal matrise og må innehalda berre eitt ark.

Resultatmatrise: er referansen til matrisa eller området som skal returnerast.

Viss Resultatmatrise er eit celleområde, må XSLÅ.OPP-funksjonen skrivast inn som ein matriseformel.

Resultat viss ikkje funne: ein tekst eller eit celleinnhald som skal returnerast viss søkjekriterie-verdien ikkje vert funne. Viss det ikkje finst gyldige treff og Resultat viss ikkje funne er utelete, returnerer funksjonen #I/T-feilen.

Treffmodus: (valfri) spesifiserer trefftypen. Verdiar kan vera:

- 0: eksakt treff (standard). Viss Søkjekriterium-verdien ikkje vert funne og teksten i Resultat viss ikkje funne manglar, vert #I/T-feilen returnert.

- -1: forsøk på eksakt treff. Viss verdien for Søkjekriterium ikkje vert funne, vert det neste, mindre elementet returnert.

- 1: forsøk på eksakt treff. HViss verdien for Søkjekriterium ikkje vert funne, vert det neste, større element returnert.

- 2: eit jokerteikn treff der teiknet * (fleire teikn), ? (enkeltteikn) og ~ har spesielle tydingar.

- 3: eit treff i eit regulært uttrykk.

Søkjemodus: (valfri) spesifiserer søkjemodusen som skal brukast.

- 1: returnerer den første førekomsten frå det første elementet i Søkjematrisa (standard).

- -1: omvendt søk. Returnerer den første førekomsten frå det siste elementet i Søkjematrisa.

- 2: binært søk som er avhengig av at Matrise er sortert i stigande rekkjefølgje. Viss ikkje sortert, vert det returnert ugyldige resultat.

- -2: binært søk som er avhengig av at Matrise er sortert i synkande rekkjefølgje. Viss ikkje sortert, vert det returnert ugyldige resultat.

Verdiane 2 og 3 i Treffmodus kan ikkje kombinerast med binært søk (Søkjemodus verdi 2 eller -2).

Kva som helst av dei valfrie innstillingane kan sløydast. Ei valfri innstillinga krev at alle dei føregåande skiljeteikna er til stades.

### Eksempel

Gå ut frå at vi har laga ein liten databasetabell i celleområdet A1:DO4 som inneheld grunnopplysningar om 118 kjemiske element. Den første kolonnen inneheld radoverskriftene «Element», «Symbol», «Atomnummer» og «Relativ atommasse». Dei neste kolonnane inneheld dei relevante opplysningane for kvart element, ordna frå venstre mot høgre etter atomnummer. Cellene B1:B4 inneheld for eksempel «Hydrogen», «H», «1» og «1,008», medan cellene DO1:DO4 inneheld «Oganesson», «Og», «118» og «294».

| A | B | C | D | ... | DO
--- | --- | --- | --- | --- | --- | ---
1 | Element | Hydrogen | Helium | Lithium | ... | Oganesson
2 | Symbol | H | He | Li | ... | Og
3 | Atomnummer | 1 | 2 | 3 | ... | 118
4 | Relativ atommasse | 1.008 | 4.0026 | 6.94 | ... | 294

{=XSLÅ.OPP("Atomnummer";A2:A4;A2:DO4)} returnerer matrisa

Atomic Number | 1 | 2 | 3 | ... | 118

{=XSLÅ.OPP("Helium";B1:DO1;B1:DO4)} returnerer matrisa

Helium
He
2
4.0026

{=XSLÅ.OPP("Kryptonitt";B1:DO1;B1:DO4;"Ukjend element")} returnerer matrisa {"Ukjend element","Ukjend element","Ukjend element","Ukjend element"}.

#### Teknisk informasjon

Denne funksjonen har vore tilgjengeleg sidan LibreOffice 24.8.

Denne funksjonen er ikkje ein del av standarden Open Document Format for kontorprogram (OpenDocument) Versjon 1.3. del 4: Omrekna formel (OpenFormula)-format. Namnerommet er

COM.MICROSOFT.XLOOKUP

Liknande emne

XSAMSVAR

XSLÅ,OPP wikiside.