Contenu

# Fonctions d'informations

Cette catégorie contient les fonctions d'informations.

Pour accéder à cette commande...

Insertion - Fonction - Catégorie Information

Les données du tableau suivant servent de référence pour certains exemples utilisés pour décrire les fonctions :

| C | D
2 | Valeur x | Valeur y
3 | -5 | -3
4 | -2 | 0
5 | -1 | 1
6 | 0 | 3
7 | 2 | 4
8 | 4 | 6
9 | 6 | 8

## ACTUELLE

Cette fonction renvoie le résultat au moment de l'évaluation de la formule dont elle est partie (en d'autres mots le résultat jusqu'à ce que cette évaluation ait lieu). Sa principale utilisation est avec la fonction STYLE() d'appliquer des styles sélectionnés à une cellule en fonction de son contenu.

#### Syntaxe

ACTUELLE()

#### Exemple

=1+2+ACTUELLE()

L'exemple renvoie 6. La formule est calculée de gauche à droite : 1 + 2 égal 3, donnant le résultat au moment où ACTUELLE() est rencontré ; ACTUELLE() rapporte donc 3, qui est ajouté au 3 d'origine, ce qui donne 6.

=A2+B2+STYLE(SI(ACTUELLE()>10;"Rouge";"Par défaut"))

L'exemple renvoie A2 + B2 (STYLE renvoie 0 ici). Si cette somme est supérieure à 10, le style Rouge est appliqué à la cellule. Voir la fonction STYLE pour des explications supplémentaires.

="chou"&ACTUELLE()

L'exemple renvoie chouchou.

#### Informations techniques

Cette fonction ne fait pas partie de Open Document Format for Office Applications (OpenDocument) Version 1.3. Partie 4 : Norme de format de formule recalculée (OpenFormula). L'espace de nom est

ORG.OPENOFFICE.CURRENT

## CELLULE

Renvoie des informations sur l'adresse, le formatage ou le contenu d'une cellule.

#### Syntaxe

CELLULE("typeinfo"[;référence])

InfoType est la chaîne de caractère qui spécifie le type d'information. La chaîne de caractère est toujours en anglais. Les majuscules et minuscules sont facultatives.

InfoType | Signification
--- | ---
COL | Renvoie le numéro de la colonne référencée. =CELLULE("COL";D2) renvoie 4.
ROW | Renvoie le numéro de la ligne référencée. =CELLULE("LIGNE";D2) renvoie 2.
SHEET | Renvoie le numéro de la feuille référencée. =CELLULE("Feuille";Feuille3.D2) renvoie 3.
ADDRESS | Renvoie l'adresse absolue de la cellule référencée. =CELLULE("ADRESSE";D2) renvoie $D$2. =CELLULE("ADRESSE";Feuille3.D2) renvoie $Feuille3.$D$2. =CELLULE("ADRESSE";'X:\dr\test.ods'#$Feuille1.D2) renvoie 'file:///X:/dr/test.ods'#$Feuille1.$D$2.
FILENAME | Renvoie les noms du fichier et de la feuille pour la cellule référencée. =CELL("FILENAME";D2) renvoie 'file:///X:/dr/own.ods'#$Sheet1, si la formule dans le document actif X:\dr\own.ods est située en Feuille1. =CELL("FILENAME";'X:\dr\test.ods'#$Sheet1.D2) renvoie 'file:///X:/dr/test.ods'#$Feuille1.
COORD | Renvoie l'adresse complète de la cellule en syntaxe Lotus™. =CELLULE("COORD";D2) renvoie $A:$D$2. =CELLULE("COORD";Feuile3.D2) renvoie $C:$D$2.
CONTENTS | Renvoie le contenu de la cellule référencée, sans aucun formatage.
TYPE | Renvoie le type du contenu de la cellule. b = blank ; cellule vide l = label. Texte, résultat d'une formule sous forme de texte v = value. Valeur, résultat d'une formule sous forme de nombre
WIDTH | Renvoie la largeur de la colonne référencée. L'unité de mesure correspond au nombre de zéros (0) pouvant figurer dans la colonne, selon la police et la taille de police définies par défaut.
PREFIX | Renvoie l'alignement de la cellule référencée. ' = aligné à gauche ou justifié " = aligné à droite ^ = centré \ = itératif (actuellement inactif)
PROTECT | Renvoie le statut de la protection de la cellule. 1 = cellule protégée 0 = cellule non protégée
FORMAT | Renvoie une chaîne de caractères spécifiant le format numérique. , = nombre comportant un séparateur de milliers F = nombre sans séparateur de milliers C = format monétaire S = représentation scientifique, par exemple, 1.234+E56 P = pourcentage Dans les formats ci-dessus, le nombre de décimales après le séparateur de décimales est donné sous forme de nombre. Exemple : le format numérique # ##0,0 renvoie ,1 et le format numérique 00,000% renvoie P3 D1 = D-MMM-YY, D-MM-YY et formats similaires D2 = DD-MM D3 = MM-YY D4 = DD-MM-YYYY HH:MM:SS D5 = MM-DD D6 = HH:MM:SS AM/PM D7 = HH:MM AM/PM D8 = HH:MM:SS D9 = HH:MM G = tous les autres formats - (moins) à la fin = formatage en couleur pour les nombres négatifs () (parenthèses) à la fin = le code du format comporte une parenthèse ouvrante
COLOR | Renvoie 1 si les valeurs négatives sont formatées en couleur, sinon 0.
PARENTHESES | Renvoie 1 si le format du code comporte une parenthèse ouvrante (, sinon 0.

Référence (liste d'options) est la position de la cellule à examiner. Si Référence est une plage, c'est la cellule en haut à gauche de cette plage qui est à prendre en compte ; si Référence n'est pas renseigné, LibreOffice Calc applique la position de la cellule dans laquelle se trouve la formule. Microsoft Excel utilise la référence de la cellule dans laquelle se trouve le curseur.

## EST.IMPAIR

Renvoie VRAI si la valeur est impaire ou FAUX si le nombre est pair.

#### Syntaxe

EST.IMPAIR(valeur)

valeur est la valeur devant être vérifiée.

Si la valeur n'est pas un entier, tous les chiffres après le séparateur de décimales sont ignorés. Le signe de la valeur est également ignoré.

#### Exemple

=EST.IMPAIR(33) renvoie VRAI

=EST.IMPAIR(48) renvoie FAUX

=EST.IMPAIR(3,999) renvoie VRAI

=EST.IMPAIR(-3,1) renvoie VRAI

## EST.IMPAIR_ADD

Renvoie VRAI (1) si le résultat n'est pas un nombre entier, une fois le nombre divisé par 2.

Les fonctions dont les noms se terminent par _ADD ou _EXCEL2003 renvoient le même résultat que les fonctions correspondantes Microsoft Excel 2003 sans le suffixe. Utilisez les fonctions sans suffixe pour obtenir des résultats basés sur les standards internationaux.

#### Syntaxe

EST.IMPAIR_ADD(nombre)

nombre est le nombre à tester.

#### Exemple

=EST.IMPAIR_ADD(5) renvoie 1.

## EST.PAIR

Renvoie VRAI si la valeur est un nombre entier pair ou FAUX si la valeur est impaire.

#### Syntaxe

EST.PAIR(valeur)

valeur est la valeur devant être vérifiée.

Si la valeur n'est pas un entier, tous les chiffres après le séparateur de décimales sont ignorés. Le signe de la valeur est également ignoré.

#### Exemple

=EST.PAIR(48) renvoie VRAI

=EST.PAIR(33) renvoie FAUX

=EST.PAIR(0) renvoie VRAI

=EST.PAIR(-2,1) renvoie VRAI

=EST.PAIR(3,999) renvoie FAUX

## EST.PAIR_ADD

Recherche les nombres pairs. Renvoie 1 si, après une division par 2, le résultat est un nombre entier.

Les fonctions dont les noms se terminent par _ADD ou _EXCEL2003 renvoient le même résultat que les fonctions correspondantes Microsoft Excel 2003 sans le suffixe. Utilisez les fonctions sans suffixe pour obtenir des résultats basés sur les standards internationaux.

#### Syntaxe

EST.PAIR_ADD(nombre)

nombre est le nombre à tester.

#### Exemple

=EST.PAIR_ADD(5) renvoie 0.

=EST.PAIR_ADD(A1) renvoie 1 si la cellule A1 contient le chiffre 2.

## ESTERR

Détermine les conditions d'erreur, à l'exception de la valeur d'erreur #N/A, et renvoie VRAI ou FAUX.

En cas d'erreur, la fonction renvoie une valeur logique ou numérique.

#### Syntaxe

ESTERR(valeur)

valeur représente toute valeur ou expression dont le test permet de vérifier la présence d'une valeur d'erreur autre que #N/A.

#### Exemple

=ESTERR(C8) où la cellule C8 contient =1/0 renvoie VRAI parce que 1/0 est une erreur.

=ESTERR(C9) où la cellule C9 contient =NA() renvoie FAUX parce que ESTERR() ignore les erreurs #N/A.

## ESTERREUR

Détermine les conditions d'erreur, y compris la valeur d'erreur #N/A, et renvoie TRUE ou FALSE.

En cas d'erreur, la fonction renvoie une valeur logique ou numérique.

#### Syntaxe

ESTERREUR(valeur)

valeur est ou fait référence à la valeur à tester. ESTERREUR() renvoie VRAI en cas d'erreur, FAUX sinon.

#### Exemple

=ESTERREUR(C8) où la cellule C8 contient =1/0 renvoie VRAI parce que 1/0 est une erreur.

=ESTERREUR(C9) où la cellule C9 contient =NA() renvoie VRAI.

## ESTFORMULE

Renvoie VRAI si la cellule est une cellule de formule.

En cas d'erreur, la fonction renvoie une valeur logique ou numérique.

#### Syntaxe

ESTFORMULE(référence)

référence indique la référence d'une cellule à laquelle s'appliquera le test permettant de déterminer si elle contient une formule.

#### Exemple

=ESTFORMULE(C4) renvoie FAUX si la cellule C4 contient le chiffre 5.

## ESTLOGIQUE

Détermine une valeur logique (VRAI ou FAUX).

Si une erreur survient, la fonction renvoie FAUX.

#### Syntaxe

ESTLOGIQUE(valeur)

Renvoie VRAI si valeur est une valeur logique (VRAI ou FAUX). Sinon renvoie FAUX.

#### Exemple

=ESTLOGIQUE(99) renvoie FAUX parce que 99 est un nombre et non une valeur logique.

=ESTLOGIQUE(ESTNA(D4)) renvoie VRAI quel que soit le contenu de la cellule D4 parce que ESTNA() renvoie une valeur logique.

## ESTNA

Renvoie VRAI si la cellule contient la valeur d'erreur #N/A (valeur non disponible).

Si une erreur survient, la fonction renvoie FAUX.

#### Syntaxe

ESTNA(valeur)

valeur représente la valeur ou une expression à examiner.

#### Exemple

=ESTNA(D3) renvoie le résultat FAUX.

## ESTNONTEXTE

Vérifie si la cellule contient du texte ou des nombres et renvoie FAUX s'il s'agit de texte.

Si une erreur survient, la fonction renvoie VRAI.

#### Syntaxe

ESTNONTEXTE(valeur)

valeur représente une valeur ou une expression à examiner pour savoir s'il s'agit d'un texte ou d'un autre élément (nombre ou valeur logique).

#### Exemple

=ESTNONTEXTE(D2) renvoie FAUX si la cellule D2 contient le texte abcdef.

=ESTNONTEXTE(D9) renvoie VRAI si la cellule D9 contient le chiffre 8.

## ESTNUM

Renvoie VRAI si la valeur fait référence à un nombre.

En cas d'erreur, la fonction renvoie une valeur logique ou numérique.

#### Syntaxe

ESTNUM(valeur)

valeur est l'expression dont vous souhaitez déterminer s'il s'agit d'un nombre ou d'un texte.

#### Exemple

=ESTNUM(C3) renvoie VRAI si la cellule C3 contient le chiffre 4.

=ESTNUM(C2) renvoie FAUX si la cellule C2 contient le texte abcdef.

## ESTREF

Détermine si l'argument est une référence. Renvoie VRAI si l'argument est une référence, sinon renvoie FAUX. Lorsqu'une référence est donnée, cette fonction n'examine pas la valeur référencée.

En cas d'erreur, la fonction renvoie une valeur logique ou numérique.

#### Syntaxe

ESTREF(valeur)

valeur est la valeur à examiner pour déterminer s'il s'agit d'une référence.

#### Exemple

=ESTREF(C5) renvoie le résultat VRAI parce que C5 est une référence valide.

=ESTREF("abcdef") renvoie toujours FAUX parce qu'un texte ne peut jamais être une référence.

=ESTREF(4) renvoie FAUX.

=ESTREF(INDIRECT("A6")) renvoie VRAI parce que INDIRECT est une fonction qui renvoie une référence.

=ESTREF(ADRESSE(1;1;2;"feuille2")) renvoie FAUX parce que ADRESSE est une fonction qui renvoie un texte, même si cela a l'air d'être une référence.

## ESTTEXTE

Renvoie VRAI si le contenu de la cellule fait référence au texte.

Si une erreur survient, la fonction renvoie FAUX.

#### Syntaxe

ESTTEXTE(valeur)

valeur représente une valeur, un nombre, une valeur logique ou une valeur d'erreur à examiner pour savoir s'il s'agit d'un texte ou d'un nombre.

#### Exemple

=ESTTEXTE(D9) renvoie VRAI si la cellule D9 contient le texte abcdef.

=ESTTEXTE(C3) renvoie FAUX si la cellule C3 contient le chiffre 3.

## ESTVIDE

Renvoie VRAI si la référence à une cellule est vide. Cette fonction permet de déterminer si le contenu d'une cellule est vide. Une cellule contenant une formule n'est pas vide.

En cas d'erreur, la fonction renvoie une valeur logique ou numérique.

#### Syntaxe

ESTVIDE(valeur)

valeur est le contenu à examiner.

#### Exemple

=ESTVIDE(D2) renvoie le résultat FAUX.

## FORMULE

Affiche la formule d'une cellule de formule en tant que chaîne de texte.

Cette fonction est toujours recalculée à chaque fois qu'un recalcul se produit

#### Syntaxe

FORMULE(référence)

référence est une référence à une cellule contenant une formule.

Une référence non valide ou une référence à une cellule sans formule génère la valeur d'erreur #N/A.

#### Exemple

Si la cellule A8 contient la formule =SOMME(1;2;3) alors

=FORMULE(A8) renvoie le texte =SOMME(1;2;3).

## INFO

Renvoie des informations spécifiques sur l'environnement de travail actuel. La fonction reçoit un seul argument de texte et renvoie des données en fonction de ce paramètre.

Cette fonction est toujours recalculée à chaque fois qu'un recalcul se produit

#### Syntaxe

INFO("Type")

Le tableau suivant liste les valeurs pour le paramètre texte Type" et renvoie les valeurs de la fonction INFO.

Valeur pour "Type" | Valeur de retour
--- | ---
"osversion" | Toujours Windows 32 bits NT 5.01 (pour des raisons de compatibilité)
"system" | Le type de système d'exploitation : "ANDROID" pour le système d'exploitation mobile de Google "DRAGONFLY" pour le système d'exploitation DragonFly dérivé de FreeBSD "EMSCRIPTEN" pour le système WebAssembly du navigateur "FREEBSD ", "OPENBSD" ou "NETBSD" pour les systèmes d'exploitation basés sur Berkeley Software Distribution (BSD) "HAIKU" pour le système d'exploitation compatible BeOS "iOS" pour le système d'exploitation mobile Apple " LINUX" pour les systèmes d'exploitation basés sur GNU/Linux "MACOSX" pour Apple Mac OS X "SOLARIS" pour le système d'exploitation Oracle Solaris "WNT" pour Microsoft Windows
"release" | L'identificateur de la version du produit. Par exemple "300m25(Build:9876)"
"numfile" | Toujours 1 (pour des raisons de compatibilité)
"recalc" | Mode de recalcule de la formule active, "Automatique" ou "Manuel" (dans la langue de la version localisée de LibreOffice)

Les autres applications de classeur peuvent accepter des valeurs traduites pour le paramètre Type, mais LibreOffice Calc n'accepte que les valeurs en anglais.

#### Exemple

=INFO("release") renvoie la version de produit de LibreOffice utilisée.

=INFO(D5) avec la cellule D5 contenant une chaîne de texte system renvoie le type de système d'exploitation.

## N

Renvoie une valeur numérique du paramètre donné. Renvoie 0 si le paramètre est du texte ou FAUX.

S'il survient une erreur, la fonction renvoie la valeur d'erreur.

#### Syntaxe

N(valeur)

Valeur est le paramètre à convertir en un nombre. N() renvoie la valeur numérique si possible. Il renvoie les valeurs logiques VRAI et FAUX comme 1 et 0 respectivement. Il renvoie le texte comme 0.

#### Exemple

=N(123) renvoie 123

=N(VRAI()) renvoie 1

=N(FAUX()) renvoie 0

=N("abc") renvoie 0

=N(1/0) renvoie #DIV/0 !

## NA

Renvoie la valeur d'erreur #N/A.

#### Syntaxe

NA ()

#### Exemple

=NA() convertit le contenu de la cellule en #N/A.

## SIERREUR

Renvoie la valeur si la cellule ne contient pas une valeur d'erreur, ou la valeur alternative dans le cas contraire.

Cette fonction est disponible depuis la version 4.0 de LibreOffice.

#### Syntaxe

SIERREUR(valeur;valeur_alternative)

valeur est la valeur ou l'expression à retourner si elle n'est pas égale ou si elle résulte en une erreur.

valeur_alternative est la valeur ou l'expression à retourner si l'expression ou la valeur de valeur est égale ou résulte en une erreur.

#### Exemple

=SIERREUR(C8;C9) où la cellule C8 contient =1/0 renvoie la valeur de C9, parce que 1/0 est une erreur.

=SIERREUR(C8;C9) où la cellule C8 contient 13 renvoie 13, la valeur de C8, qui n'est pas une erreur.

## SINA

Renvoie la valeur si la cellule ne contient pas la valeur d'erreur #N/D (valeur non disponible) ou la valeur alternative dans le cas contraire.

Cette fonction est disponible depuis la version 4.0 de LibreOffice.

#### Syntaxe

SINA(valeur;valleur_alternative)

valeur est la valeur ou l'expression renvoyée si elle n'est pas égale ou le résultat est une erreur #N/A.

valeur_alternative est la valeur ou l'expression renvoyée si l'expression ou la valeur de valeur est égale ou résulte en une erreur #N/A.

#### Exemple

=SINA(D3;D4) renvoie la valeur de D3 si D3 ne résulte pas en une erreur #N/A, ou D4 si c'est le cas.

## TYPE

Renvoie le type de valeur, ou 1 = nombre, 2 = texte, 4 = valeur logique, 8 = formule, 16 = valeur d'erreur, 64 = matrice.

En cas d'erreur, la fonction renvoie une valeur logique ou numérique.

#### Syntaxe

TYPE(valeur)

valeur est une valeur spécifique pour laquelle le type de donnée est déterminé.

### Exemple (voir la table au début de cette section)

=TYPE(C2) renvoie le résultat 2.

=TYPE(D9) renvoie le résultat 1.

Rubriques connexes

Fonctions par catégories