CheckTypeSize — CMake 4.0.0 Documentation

# CheckTypeSize

Check sizeof a type

check_type_size

      check_type_size(<type> <variable> [BUILTIN_TYPES_ONLY]
                                        [LANGUAGE <language>])

  Check if the type exists and determine its size. Results are reported in the following variables:

  `HAVE_<variable>`

    Holds a true or false value indicating whether the type exists.

  `<variable>`

    Holds one of the following values:

    `<size>`

      Type has non-zero size `<size>`.

    `0`

      Type has architecture-dependent size. This may occur when `CMAKE_OSX_ARCHITECTURES` has multiple architectures. In this case `<variable>_CODE` contains C preprocessor tests mapping from each architecture macro to the corresponding type size. The list of architecture macros is stored in `<variable>_KEYS`, and the value for each key is stored in `<variable>-<key>`.

    "" (empty string)

      Type does not exist.

  `<variable>_CODE`

    Holds C preprocessor code to define the macro `<variable>` to the size of the type, or to leave the macro undefined if the type does not exist.

  The options are:

  `BUILTIN_TYPES_ONLY`

  > Support only compiler-builtin types. If not given, the macro checks for headers `<sys/types.h>`, `<stdint.h>`, and `<stddef.h>`, and saves results in `HAVE_SYS_TYPES_H`, `HAVE_STDINT_H`, and `HAVE_STDDEF_H`. The type size check automatically includes the available headers, thus supporting checks of types defined in the headers.

  `LANGUAGE <language>`

    Use the `<language>` compiler to perform the check. Acceptable values are `C` and `CXX`. If not specified, it defaults to `C`.

Despite the name of the macro you may use it to check the size of more complex expressions, too. To check e.g. for the size of a struct member you can do something like this:

    check_type_size("((struct something*)0)->member" SIZEOF_MEMBER)

The following variables may be set before calling this macro to modify the way the check is run:

> `CMAKE_REQUIRED_FLAGS`

>   String of additional flags to pass to the compiler. The string must be space-delimited--a ;-list will not work. The contents of `CMAKE_<LANG>_FLAGS` and its associated configuration-specific variable are automatically added to the compiler command before the contents of `CMAKE_REQUIRED_FLAGS`.

> `CMAKE_REQUIRED_DEFINITIONS`

>   A ;-list of compiler definitions of the form `-DFOO` or `-DFOO=bar`. A definition for the name specified by `<resultVar>` will also be added automatically.

> `CMAKE_REQUIRED_INCLUDES`

>   A ;-list of header search paths to pass to the compiler. These will be the only header search paths used--the contents of the `INCLUDE_DIRECTORIES` directory property will be ignored.

> `CMAKE_REQUIRED_LINK_OPTIONS`

>   Added in version 3.14.

>   A ;-list of options to add to the link command (see `try_compile()` for further details).

> `CMAKE_REQUIRED_LIBRARIES`

>   A ;-list of libraries to add to the link command. These can be the name of system libraries or they can be Imported Targets (see `try_compile()` for further details).

> `CMAKE_REQUIRED_LINK_DIRECTORIES`

>   Added in version 3.31.

>   A ;-list of libraries search paths to pass to the linker (see `try_compile()` for further details).

> `CMAKE_REQUIRED_QUIET`

>   Added in version 3.1.

>   If this variable evaluates to a boolean true value, all status messages associated with the check will be suppressed.

`CMAKE_EXTRA_INCLUDE_FILES`

  list of extra headers to include.

## Examples

Consider the code:

    include(CheckTypeSize)

    # Check for size of long.
    check_type_size(long SIZEOF_LONG)
    message("HAVE_SIZEOF_LONG: ${HAVE_SIZEOF_LONG}")
    message("SIZEOF_LONG: ${SIZEOF_LONG}")
    message("SIZEOF_LONG_CODE: ${SIZEOF_LONG_CODE}")

On a 64-bit architecture, the output may look something like this:

    HAVE_SIZEOF_LONG: TRUE
    SIZEOF_LONG: 8
    SIZEOF_LONG_CODE: #define SIZEOF_LONG 8

On Apple platforms, when `CMAKE_OSX_ARCHITECTURES` has multiple architectures, types may have architecture-dependent sizes. For example, with the code

    include(CheckTypeSize)

    check_type_size(long SIZEOF_LONG)
    message("HAVE_SIZEOF_LONG: ${HAVE_SIZEOF_LONG}")
    message("SIZEOF_LONG: ${SIZEOF_LONG}")
    foreach(key IN LISTS SIZE_OF_LONG_KEYS)
      message("key: ${key}")
      message("value: ${SIZE_OF_LONG-${key}}")
    endforeach()
    message("SIZEOF_LONG_CODE:
    ${SIZEOF_LONG_CODE}")

the result may be:

    HAVE_SIZEOF_LONG: TRUE
    SIZEOF_LONG: 0
    key: __i386
    value: 4
    key: __x86_64
    value: 8
    SIZEOF_LONG_CODE:
    #if defined(__i386)
    # define SIZE_OF_LONG 4
    #elif defined(__x86_64)
    # define SIZE_OF_LONG 8
    #else
    # error SIZE_OF_LONG unknown
    #endif