Contenuto

# CONTA.PIÙ.SE

Restituisce il conteggio delle celle che soddisfano i criteri in più intervalli.

La funzione è disponibile da LibreOffice 4.0.

### Sintassi

CONTA.PIÙ.SE(Intervallo; Criterio[; Intervallo2; Criterio2][; ... ; [Intervallo127; Criterio127]])

Intervallo1: argomento obbligatorio. È un intervallo di celle, il nome di un'area indicata, la dicitura di una colonna o di una riga a cui deve essere applicato il criterio corrispondente.

Criterio: è un riferimento, un numero o un testo di una singola cella. Viene utilizzato nei confronti col contenuto delle celle.

Un riferimento a una cella vuota viene interpretato come valore numerico 0.

Un'espressione che corrisponde può essere:

- Un numero o un valore logico. Un contenuto di cella individuato è uguale al numero o al valore logico.

- Un valore preceduto da un segno di comparazione (<, <=, =, >, >=, <>).

  L'=, se il valore è vuoto individua le celle vuote.

  Nel caso di <>, se il valore è vuoto individua le celle non vuote.

  Nel caso di <>, se il valore non è vuoto, individua qualsiasi contenuto delle celle ad eccezione del valore, incluse le celle vuote.

  Nota: "=0" non individua celle vuote.

  Nel caso di = e <>, se il valore non è vuoto e non può essere interpretato come di tipo Numero o uno dei suoi sottotipi e la proprietà I criteri di ricerca = e <> devono riferirsi a celle intere è attivata, il confronto viene eseguito con l'intero contenuto delle celle; mentre se è disattivata il confronto viene eseguito con qualsiasi sottoparte del campo che corrisponde ai criteri di ricerca. Nel caso di = e <> si applica se il valore non è vuoto e non può essere interpretato come di tipo Numero o uno dei suoi sottotipi.

- Valore Altro testo. Se la proprietà I criteri di ricerca = e <> devono riferirsi a celle intere è vera, il confronto è eseguito con l'intero contenuto delle celle; se è falsa il confronto viene eseguito con qualsiasi sottoparte del campo che corrisponde ai criteri. L'espressione può contenere testo, numeri, espressioni regolari o caratteri jolly, se questi ultimi sono abilitati nelle opzioni di calcolo.

Intervallo2 – opzionale. Intervallo2 e tutto ciò che segue hanno lo stesso significato di Intervallo1.

Criterio2 – opzionale. Criterio2 e tutto ciò che segue hanno lo stesso significato di Criterio.

La ricerca supporta i caratteri jolly o le espressioni regolari. Se queste ultime sono attivate, è possibile inserire "all.*" per trovare, ad esempio, la prima posizione di "all" seguito da qualsiasi carattere. Se si intende ricercare un testo che sia anche un'espressione regolare, è necessario far precedere sempre il metacarattere o l'operatore dell'espressione dal carattere "\", oppure racchiudere il testo tra \Q...\E. È possibile attivare o disattivare l'analisi dei caratteri jolly o delle espressioni regolari in LibreOffice - Preferenze Strumenti - Opzioni - LibreOffice Calc - Calcola.

Quando si utilizzano funzioni in cui uno o più argomenti sono stringhe di criteri di ricerca che rappresentano un'espressione regolare, innanzitutto si cerca di convertire i criteri della stringa in numeri. Per esempio, ".0" sarà convertito in 0.0 e così via. In caso di esito positivo, la corrispondenza non sarà quella di un'espressione regolare ma una corrispondenza numerica. Tuttavia, quando si passa a un'impostazione regionale in cui il separatore decimale non è il punto, tale passaggio fa funzionare la conversione in espressione regolare. Per forzare la valutazione dell'espressione regolare, anziché di quella numerica, utilizzare un'espressione che non possa essere erroneamente interpretata come numerica, per es., ".[0]", ".\0" oppure "(?i).0".

Intervallo, Intervallo2, ... e Criterio, Criterio2, ... devono possedere la stessa dimensione, in caso contrario la funzione restituisce err:502 - Argomento non valido.

La relazione logica tra i criteri definibili come E logico (congiunzione). In altre parole, se, e solo se, tutti i criteri sono soddisfatti, viene inserito nel calcolo un valore derivante dalla cella corrispondente del Intervallo_Func specificato.

La funzione può possedere fino a 255 argomenti, nel senso che potete specificare 127 intervalli di criteri e i criteri a essi relativi.

Se una cella contenesse VERO, sarebbe considerata 1; se contenesse FALSO, sarebbe considerata 0 (zero).

Questa funzione appartiene all'Open Document Format for Office Applications (OpenDocument), versione standard 1.2 (ISO/IEC 26300:2-2015).

### Esempi

Considerate la tabella seguente

| A | B | C
1 | Nome prodotto | Sales | Revenue
2 | matita | 20 | 65
3 | penna | 35 | 85
4 | notebook | 20 | 190
5 | libro | 17 | 180
6 | astuccio | non | non

In tutti gli esempi riportati sotto, gli intervalli per il calcolo contengono la riga #6, che viene ignorata poiché contiene testo.

#### Uso semplice

=CONTA.PIÙ.SE(B2:B6;">=20")

Conta la quantità di righe dell'intervallo B2:B6 con valori maggiori o uguali a 20. Restituisce 3, perché la quinta e la sesta riga non soddisfano il criterio.

=CONTA.PIÙ.SE(B2:B6;">=20";C2:C6;">70")

Conta la quantità di righe che contengono contemporaneamente valori maggiori di 70 nell'intervallo C2:C6 e valori maggiori o uguali a 20 nell'intervallo B2:B6. Restituisce 2, perché la seconda, la quinta e la sesta riga non soddisfano almeno un criterio.

#### Uso delle espressioni regolari e delle funzioni annidate

Affinché gli esempi funzionino come descritto, sinceratevi che sia selezionata l'opzione Permetti espressioni regolari nelle formule in LibreOffice - Preferenze Strumenti - Opzioni - LibreOffice Calc - Calcola.

=CONTA.PIÙ.SE(B2:B6;"[:alpha:]*")

Conta la quantità di righe dell'intervallo B2:B6 che contengono solo simboli alfabetici. Restituisce 1, perché solo la sesta riga soddisfa il criterio.

=CONTA.PIÙ.SE(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Conta la quantità di righe dell'intervallo B2:B6 escludendo le righe con valori minimi e massimi dello stesso intervallo. Restituisce 2, perché la terza, la quinta e la sesta riga non soddisfano almeno un criterio.

=CONTA.PIÙ.SE(A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Conta la quantità di righe che corrispondono a tutte le celle dell'intervallo A2:A6 che iniziano con "pen" e a tutte le celle dell'intervallo B2:B6, eccetto il suo massimo. Restituisce 1, perché solo la seconda riga soddisfa tutti i criteri.

#### Fare riferimento a una cella come criterio

Per cambiare in modo facile un criterio, potete specificarlo in una cella separata, utilizzando un riferimento alla cella all'interno della condizione della funzione CONTA.PIÙ.SE. Per esempio, la funzione sopra citata può essere riscritta nel modo seguente:

=CONTA.PIÙ.SE(A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Se E2 = pen, la funzione restituisce 1, perché il collegamento alla cella è sostituito dal suo contenuto e agisce come la funzione sopra citata.

Argomenti correlati

Pagina wiki relativa a CONTA.PIÙ.SE (in inglese).

CONTA.NUMERI, CONTA.SE, CONTA.VUOTE, CONTA.VALORI

CONTA.PIÙ.SE, MIN.PIÙ.SE, MAX.PIÙ.SE, MEDIA.PIÙ.SE, SOMMA.PIÙ.SE

Elenco delle espressioni regolari