Περιεχόμενα

# Λογικές συναρτήσεις

Αυτή η κατηγορία περιέχει τις συναρτήσεις Λογικές.

### Χειρισμός μη λογικών ορισμάτων σε λογικές συναρτήσεις

- Το μηδέν (0) είναι ισοδύναμο με το FALSE και όλοι οι άλλοι αριθμοί είναι ισοδύναμοι με TRUE.

- Τα κενά κελιά και το κείμενο σε κελιά αγνοούνται.

- Εμφανίζεται το σφάλμα #ΤΙΜΗ, εάν όλα τα ορίσματα αγνοούνται.

- Εμφανίζει σφάλμα #ΤΙΜΗ, εάν ένα όρισμα είναι άμεσο κείμενο (όχι κείμενο σε κελί).

- Σφάλμα ως όρισμα οδηγεί σε σφάλμα.

Για να έχετε πρόσβαση σε αυτήν τη λειτουργία...

Εισαγωγή - Συνάρτηση - Κατηγορία Λογική

### ISNA

Επιστρέφει την τιμή TRUE εάν ένα κελί περιέχει την τιμή σφάλματος #N/A (δεν υπάρχει).

Αν υπάρξει κάποιο σφάλμα, η συνάρτηση επιστρέφει την τιμή FALSE.

#### Σύνταξη

ISNA(Τιμή)

Τιμή είναι η τιμή ή η παράσταση που θα ελεγχθεί.

#### Παράδειγμα

Η =ISNA(D3) επιστρέφει ως αποτέλεσμα την τιμή FALSE.

### IFERROR

Επιστρέφει την τιμή εάν το κελί δεν περιέχει τιμή σφάλματος ή την εναλλακτική τιμή εάν περιέχει.

Αυτή η συνάρτηση είναι διαθέσιμη από το LibreOffice 4.0.

#### Σύνταξη

IFERROR(Τιμή; εναλλακτική_τιμή)

Τιμή είναι η τιμή ή η παράσταση που επιστρέφεται αν δεν είναι ίση ή καταλήγει σε σφάλμα.

Εναλλακτική_τιμή είναι η τιμή ή παράσταση που επιστρέφεται, εάν η παράσταση ή η τιμή της Τιμής είναι ίση ή καταλήγει σε σφάλμα.

#### Παράδειγμα

Το =IFERROR(C8;C9) όπου το κελί C8 περιέχει το =1/0 επιστρέφει την τιμή του C9, επειδή το 1/0 είναι λάθος.

Το =IFERROR(C8;C9) όπου το κελί C8 περιέχει το =13 επιστρέφει 13, την τιμή του C8, που δεν είναι σφάλμα.

## IFS

IFS είναι μια πολλαπλή συνάρτηση IF.

## SWITCH

Η SWITCH συγκρίνει την παράσταση με την τιμή1 με τιμές και επιστρέφει το αποτέλεσμα που ανήκει στην πρώτη τιμή της παράστασης ισούται. Εάν δεν υπάρχει συμφωνία και η προεπιλεγμένη_τιμή δίνεται, αυτό θα επιστραφεί.

## AND

Επιστρέφει TRUE αν όλα τα ορίσματα είναι TRUE. Αν ένα από τα στοιχεία είναι FALSE, η συνάρτηση επιστρέφει την τιμή FALSE.

Τα ορίσματα είναι είτε λογικές εκφράσεις από μόνες τους (TRUE, 1<5, 2+3=7, B8<10) που επιστρέφουν λογικές τιμές, είτε πίνακες (A1:C3) που περιέχουν λογικές τιμές.

#### Σύνταξη

AND(Λογική 1 [; Λογική 2 [; … [; Λογική 255]]])

Logical 1; Logical 2; … ; Logical 255 are boolean values, references to cells or to cell ranges of logical values.

Αυτή η συνάρτηση αγνοεί οποιοδήποτε κείμενο ή κενό κελί στην περιοχή των δεδομένων. Εάν υποψιάζεστε εσφαλμένα αποτελέσματα από αυτήν τη συνάρτηση, ψάξτε για κείμενο στις περιοχές δεδομένων. Για να επισημάνετε περιεχόμενα κειμένου σε περιοχή δεδομένων, χρησιμοποιήστε το γνώρισμα Επισήμανση τιμής.

#### Παράδειγμα

Θα ελεγχθούν οι λογικές τιμές των καταχωρήσεων 12<13; 14>12, και 7<6:

=AND(12<13;14>12;7<6) επιστρέφει FALSE.

Το =AND(FALSE();TRUE()) επιστρέφει FALSE.

Ο τύπος πίνακα {=AND(B10;C1:C10)} αποδίδει μια μονοδιάστατη τιμή TRUE όταν όλα τα στοιχεία του B1:B10 και C1:C10 είναι TRUE. Η παραπάνω παράσταση πίνακα δεν παράγει το λογικό AND ανά στοιχείο και επομένως δεν παράγει έναν πίνακα λογικών τιμών. Για να υπολογίσετε ένα λογικό AND των πινάκων ανά στοιχείο χρησιμοποιήστε τον τελεστή * σε περιβάλλον πίνακα. Στο παράδειγμα, πληκτρολογήστε {=B1:B10*C1:C10}.

## FALSE

Επιστρέφει τη λογική τιμή FALSE. Η συνάρτηση FALSE() δεν απαιτεί καθόλου ορίσματα, και πάντα επιστρέφει τη λογική τιμή FALSE.

#### Σύνταξη

FALSE()

#### Παράδειγμα

=FALSE() επιστρέφει FALSE

=NOT(FALSE()) επιστρέφει TRUE

## IF

Καθορίζει τον λογικό έλεγχο που θα εφαρμοστεί.

#### Σύνταξη

IF(Έλεγχος [; [ΤότεΤιμή] [; [ΑλλιώςΤιμή]]])

Έλεγχος είναι οποιαδήποτε τιμή ή έκφραση που μπορεί να είναι TRUE ή FALSE.

ThenValue (προαιρετική) είναι η τιμή που επιστρέφεται αν ο λογικός έλεγχος είναι TRUE.

OtherwiseValue (προαιρετική) είναι η τιμή που επιστρέφεται αν ο λογικός έλεγχος είναι FALSE.

Στις συναρτήσεις του LibreOffice Calc, οι παράμετροι που σημειώνονται ως "προαιρετικές" μπορούν να παραληφθούν μόνο όταν δεν ακολουθεί καμιά παράμετρος. Παραδείγματος χάρη, σε μια συνάρτηση με τέσσερις παραμέτρους, όπου οι δύο τελευταίες παράμετροι είναι σημειωμένες ως "προαιρετικές", μπορείτε να αφήσετε έξω την παράμετρο 4 ή τις παραμέτρους 3 και 4, αλλά δεν μπορείτε να παραλείψετε μόνο την παράμετρο 3.

#### Παράδειγμα

=IF(A1>5;100;"υπερβολικά μικρή") Εάν η τιμή στο A1 είναι μεγαλύτερη από 5, τότε επιστρέφεται η τιμή 100· αλλιώς, επιστρέφεται το κείμενο υπερβολικά μικρή.

=IF(A1>5;;"υπερβολικά μικρή") Εάν η τιμή στο A1 είναι μεγαλύτερη από 5, επιστρέφεται η τιμή0 επειδή οι κενές παράμετροι θεωρούνται ότι είναι 0· αλλιώς, επιστρέφεται το κείμενο υπερβολικά μικρή.

=IF(A1>5;100;) Εάν η τιμή στο A1 είναι μικρότερη από 5, επιστρέφεται η τιμή 0 επειδή η κενή ΑλλιώςΤιμή ερμηνεύεται ως 0· αλλιώς επιστρέφεται 100.

## NOT

Συμπληρώνει (αντιστρέφει) μια λογική τιμή.

#### Σύνταξη

NOT(Λογική-τιμή)

LogicalValue είναι οποιαδήποτε τιμή προς συμπλήρωση.

#### Παράδειγμα

=NOT(A). Αν A=TRUE τότε το NOT(A) θα εκτιμήσει FALSE.

## OR

Επσιτρέφει TRUE αν τουλάχιστον ένα όρισμα είναι TRUE. Αυτή η συνάρτηση πειστρέφει την τιμή FALSE, αν όλα τα ορίσματα έχουν τη λογική τιμή FALSE.

Τα ορίσματα είναι είτε λογικές εκφράσεις από μόνες τους (TRUE, 1<5, 2+3=7, B8<10) που επιστρέφουν λογικές τιμές, είτε πίνακες (A1:C3) που περιέχουν λογικές τιμές.

#### Σύνταξη

OR(Λογική 1 [; Λογική 2 [; … [; Λογική 255]]])

Logical 1; Logical 2; … ; Logical 255 are boolean values, references to cells or to cell ranges of logical values.

Αυτή η συνάρτηση αγνοεί οποιοδήποτε κείμενο ή κενό κελί στην περιοχή των δεδομένων. Εάν υποψιάζεστε εσφαλμένα αποτελέσματα από αυτήν τη συνάρτηση, ψάξτε για κείμενο στις περιοχές δεδομένων. Για να επισημάνετε περιεχόμενα κειμένου σε περιοχή δεδομένων, χρησιμοποιήστε το γνώρισμα Επισήμανση τιμής.

#### Παράδειγμα

Θα ελεγχθούν οι λογικές τιμές των καταχωρήσεων 12<11; 13>22 και 45=45.

=OR(12<11;13>22;45=45) επιστρέφει TRUE.

Το =OR(FALSE();TRUE()) επιστρέφει TRUE.

Ο τύπος πίνακα {=OR(B1:B10;C1:C10)} αποδίδει μια μονοδιάστατη τιμή FALSE όταν όλα τα στοιχεία του B1: B10 και C1:C10 είναι FALSE. Η παραπάνω παράσταση πίνακα δεν παράγει το λογικό OR ανά στοιχείο και επομένως δεν παράγει έναν πίνακα λογικών τιμών. Για να υπολογίσετε ένα λογικό OR πινάκων ανά στοιχείο χρησιμοποιήστε τον τελεστή + σε περιβάλλον πίνακα. Στο παράδειγμα, πληκτρολογήστε {=B1:B10+C1:C10}.

## TRUE

Η λογική τιμή ορίζεται TRUE. Η συνάρτηση TRUE() δεν χρειάζεται ορίσματα και πάντα επιστρέφει τη λογική τιμή TRUE.

#### Σύνταξη

TRUE()

#### Παράδειγμα

Αν A=TRUE και B=FALSE εμφανίζονται τα ακόλουθα παραδείγματα:

=AND(A;B) επιστρέφει FALSE

=OR(A;B) επιστρέφει TRUE

=NOT(AND(A;B)) επιστρέφει TRUE

## XOR

επιστρέφει αληθές αν ένας περιττός αριθμός ορισμάτων υπολογίζει σε ΑΛΗΘΗ.

Τα ορίσματα είναι είτε λογικές παραστάσεις από μόνες τους (TRUE, 1<5, 2+3=7, B8<10) που επιστρέφουν λογικές τιμές, είτε πίνακες (A1:C3) που περιέχουν λογικές τιμές.

Αυτή η συνάρτηση είναι διαθέσιμη από το LibreOffice 4.0.

#### Σύνταξη

XOR(Λογική 1 [; Λογική 2 [; … [; Λογική 255]]])

Logical 1; Logical 2; … ; Logical 255 are boolean values, references to cells or to cell ranges of logical values.

#### Παράδειγμα

Το =XOR(TRUE();TRUE()) επιστρέφει FALSE

Το =XOR(TRUE();TRUE();TRUE()) επιστρέφει TRUE

Το =XOR(FALSE();TRUE()) επιστρέφει TRUE

Σχετικά θέματα

Συναρτήσεις ανά κατηγορία