Funktion XVERWEIS

Inhalte

# XVERWEIS

Sucht nach einem Wert in einer Matrix und gibt einen Verweis auf eine Zelle oder einen Zellbereich zurück.

Die Funktion XVERWEIS ist ein moderner und flexibler Ersatz für ältere Funktionen wie SVERWEIS, WVERWEIS und VERWEIS. XVERWEIS unterstützt ungefähre und genaue Übereinstimmungen, Platzhalter (* ?) oder reguläre Ausdrücke für teilweise Übereinstimmungen sowie Verweise in vertikalen oder horizontalen Bereichen. XVERWEIS kann eine umgekehrte Suche durchführen und bietet eine schnelle binäre Suchoption bei der Arbeit mit großen Datensätzen.

### Syntax

XVERWEIS( [Suchkriterium] ; Suchmatrix ; Ergebnismatrix [ ; [ Ergebnis, falls nicht gefunden ] [ ; [Übereinstimmungsmodus] [ ; Suchmodus ] ] ] )

Suchkriterium (optional): Der Wert beliebigen Typs, nach dem in Suchmatrix gesucht werden soll. Wenn dieses Kriterium weggelassen wird, gibt XVERWEIS leere Zellen zurück, die in Suchmatrix gefunden werden.

Suchmatrix: Ist der Verweis auf die zu durchsuchende Matrix. Die Matrix muss eine eindimensionale Matrix sein und darf nur auf eine einzige Tabelle verweisen.

Ergebnismatrix: Ist der Verweis auf die zurückzugebende Matrix oder den zurückzugebenden Bereich.

Wenn die Ergebnismatrix ein Zellbereich ist, muss die Funktion XVERWEIS als Matrixformel eingegeben werden.

Ergebnis, falls nicht gefunden: Ein Text oder Zelleninhalt, der zurückgegeben wird, wenn Suchkriterium nicht gefunden wird. Wenn keine gültige Übereinstimmung gefunden wird und Ergebnis, falls nicht gefunden weggelassen wird, gibt die Funktion den Fehler #NV zurück.

Übereinstimmungsmodus (optional): gibt den Übereinstimmungstyp an. Mögliche Werte:

- 0: genaue Übereinstimmung (Standard). Wenn der Wert für Suchkriterium nicht gefunden wird und der Text für das Ergebnis, falls nicht gefunden weggelassen wird, wird der Fehler #NV zurückgegeben.

- -1: Versucht eine exakte Übereinstimmung. Wenn der Wert für Suchkriterium nicht gefunden wird, wird das nächstkleinere Element zurückgegeben.

- 1: Versucht eine exakte Übereinstimmung. Wenn der Wert für Suchkriterium nicht gefunden wird, wird das nächstgrößere Element zurückgegeben.

- 2: Eine Übereinstimmung mit Platzhalter, bei der die Zeichen * (mehrere Zeichen), ? (einzelnes Zeichen) und ~ besondere Bedeutungen haben.

- 3: Eine Übereinstimmung mit regulären Ausdrücken.

Suchmodus (optional): Gibt den zu verwendenden Suchmodus an.

- 1: gibt das erste Vorkommen beginnend mit dem ersten Element der Suchmatrix zurück (Standard).

- -1: Rückwärtssuche. Gibt das erste Vorkommen beginnend mit dem letzten Element der Suchmatrix zurück.

- 2: Binäre Suche, die darauf basiert, dass das Suchmatrix in aufsteigender Reihenfolge sortiert ist. Wenn sie nicht sortiert, werden ungültige Ergebnisse zurückgegeben.

- -2: Binäre Suche, die darauf basiert, dass Suchmatrix in absteigender Reihenfolge sortiert ist. Wenn sie nicht sortiert, werden ungültige Ergebnisse zurückgegeben.

Die Werte 2 und 3 des Übereinstimmungsmodus können nicht mit der binären Suche kombiniert werden (Wert 2 oder -2 im Suchmodus).

Alle optionalen Argumente können weggelassen werden. Ein optionales Argument erfordert, dass alle vorangehenden Trennzeichen vorhanden sind.

### Beispiele

Angenommen, wir haben eine kleine Datenbanktabelle erstellt, die den Zellbereich A1:DO4 einnimmt und grundlegende Informationen über 118 chemische Elemente enthält. Die erste Spalte enthält die Zeilenüberschriften „Element“, „Symbol“, „Atomzahl“ und „Relative Atommasse“. Nachfolgende Spalten enthalten die relevanten Informationen für jedes der Elemente, von links nach rechts nach der Ordnungszahl geordnet. Zum Beispiel enthalten die Zellen B1:B4 „Wasserstoff“, „H“, „1“ und „1,008“, während die Zellen DO1:DO4 „Oganesson“, „Og“, „118“ und „294“ enthalten.

| A | B | C | D | ... | DO
--- | --- | --- | --- | --- | --- | ---
1 | Element | Wasserstoff | Helium | Lithium | ... | Oganesson
2 | Symbol | H | He | Li | ... | Og
3 | Ordnungszahl | 1 | 2 | 3 | ... | 118
4 | Relative Atommasse | 1.008 | 4.0026 | 6.94 | ... | 294

{=XVERWEIS("Ordnungszahl";A2:A4;A2:DO4)} gibt folgende Matrix zurück:

Ordnungszahl | 1 | 2 | 3 | ... | 118

{=XVERWEIS("Helium";B1:DO1;B1:DO4)} gibt folgende Matrix zurück:

Helium
He
2
4.0026

{=XVERWEIS("Kryptonit";B1:DO1;B1:DO4;"Unbekanntes Element")} gibt die Matrix {"Unbekanntes Element","Unbekanntes Element","Unbekanntes Element","Unbekanntes Element"} zurück.

#### Technische Information

Diese Funktion ist seit LibreOffice 24.8 verfügbar.

Diese Funktion ist nicht Bestandteil des Standards Open Document Format für Office-Anwendungen (OpenDocument) Version 1.3. Teil 4: Format für neu berechnete Formeln (OpenFormula). Der Namensraum ist

COM.MICROSOFT.XLOOKUP

Verwandte Themen

XVERGLEICH

Wikiseite zu XVERWEIS.